Jak renderować 2D skierowany do góry kafelkowy, ukierunkowany przepływ wody?

Pracuję nad odgórną, dość graficzną grą 2D inspirowaną Dwarf Fortress. Jestem na etapie wdrażania rzeki w świecie gry, która obejmuje wiele płytek, i obliczyłem kierunek przepływu dla każdej płytki, jak pokazano poniżej czerwoną linią na każdej płytce.

Dla odniesienia do stylu graficznego, oto jak obecnie wygląda moja gra:

Potrzebuję jakiejś techniki animacji wody przepływającej w każdym z kafelków rzeki, aby przepływ wtapiał się w otaczające kafelki, tak że krawędzie kafelków nie są widoczne.

Najbliższy przykład, jaki znalazłem, do czego dążę, został opisany na stronie http://www.rug.nl/society-business/centre-for-information-technology/research/hpcv/publications/watershader/, ale nie jestem całkiem w momencie, gdy rozumiem, co się w nim dzieje? Mam wystarczającą wiedzę na temat programowania shaderów, aby zaimplementować własne dynamiczne oświetlenie, ale nie mogę się skupić na podejściu zastosowanym w powiązanym artykule.

Czy ktoś mógłby wyjaśnić, w jaki sposób osiąga się powyższy efekt lub zasugerować inne podejście do uzyskania pożądanego rezultatu? Myślę, że część powyższego rozwiązania pokrywa się z kafelkami (choć nie jestem pewien, w których kombinacjach) i obraca normalną mapę użytą do zniekształcenia (znowu nie mam pojęcia o szczegółach) i przeszłość, że jestem trochę zagubiony, dzięki za jakaś pomoc!

Nie miałem pod ręką żadnych kafelków, które wyglądałyby dobrze przy zniekształceniach, więc oto wersja efektu, z którego wyśmiewałem te kafelki Kenneya :

Korzystam z takiej mapy przepływów, gdzie czerwony = przepływ w prawo i zielony = w górę, żółty to oba. Każdy piksel odpowiada jednemu kafelkowi, przy czym lewy dolny piksel jest kafelkiem o (0, 0) w moim światowym układzie współrzędnych.

I taka tekstura wzoru fali:

Najbardziej znam składnię Unlsa w stylu hlsl / CG, więc musisz nieco dostosować ten moduł cieniujący do kontekstu glsl, ale powinno to być proste.

// Colour texture / atlas for my tileset.
sampler2D _Tile;
// Flowmap texture.
sampler2D _Flow;
// Wave surface texture.
sampler2D _Wave;

// Tiling of the wave pattern texture.
float _WaveDensity = 0.5f;
// Scrolling speed for the wave flow.
float _WaveSpeed  = 5.0f;

// Scaling from my world size of 8x8 tiles 
// to the 0...1
float2 inverseFlowmapSize = (float2)(1.0f/8.0f);

struct v2f
{
    // Projected position of tile vertex.
    float4 vertex   : SV_POSITION;
    // Tint colour (not used in this effect, but handy to have.
    fixed4 color    : COLOR;
    // UV coordinates of the tile in the tile atlas.
    float2 texcoord : TEXCOORD0;
    // Worldspace coordinates, used to look up into the flow map.
    float2 flowPos  : TEXCOORD1;
};

v2f vert(appdata_t IN)
{
    v2f OUT;

    // Save xy world position into flow UV channel.
    OUT.flowPos = mul(ObjectToWorldMatrix, IN.vertex).xy;

    // Conventional projection & pass-throughs...
    OUT.vertex = mul(MVPMatrix, IN.vertex);
    OUT.texcoord = IN.texcoord;
    OUT.color = IN.color;

    return OUT;
}

// I use this function to sample the wave contribution
// from each of the 4 closest flow map pixels.
// uv = my uv in world space
// sample site = world space        
float2 WaveAmount(float2 uv, float2 sampleSite) {
    // Sample from the flow map texture without any mipmapping/filtering.
    // Convert to a vector in the -1...1 range.
    float2 flowVector = tex2Dgrad(_Flow, sampleSite * inverseFlowmapSize, 0, 0).xy 
                        * 2.0f - 1.0f;
    // Optionally, you can skip this step, and actually encode
    // a flow speed into the flow map texture too.
    // I just enforce a 1.0 length for consistency without getting fussy.
    flowVector = normalize(flowVector);

    // I displace the UVs a little for each sample, so that adjacent
    // tiles flowing the same direction don't repeat exactly.
    float2 waveUV = uv * _WaveDensity + sin((3.3f * sampleSite.xy + sampleSite.yx) * 1.0f);

    // Subtract the flow direction scaled by time
    // to make the wave pattern scroll this way.
    waveUV -= flowVector * _Time * _WaveSpeed;

    // I use tex2DGrad here to avoid mipping down
    // undesireably near tile boundaries.
    float wave = tex2Dgrad(_Wave, waveUV, 
                           ddx(uv) * _WaveDensity, ddy(uv) * _WaveDensity);

    // Calculate the squared distance of this flowmap pixel center
    // from our drawn position, and use it to fade the flow
    // influence smoothly toward 0 as we get further away.
    float2 offset = uv - sampleSite;
    float fade = 1.0 - saturate(dot(offset, offset));

    return float2(wave * fade, fade);
}

fixed4 Frag(v2f IN) : SV_Target
{
    // Sample the tilemap texture.
    fixed4 c = tex2D(_MainTex, IN.texcoord);

    // In my case, I just select the water areas based on
    // how blue they are. A more robust method would be
    // to encode this into an alpha mask or similar.
    float waveBlend = saturate(3.0f * (c.b - 0.4f));

    // Skip the water effect if we're not in water.
    if(waveBlend == 0.0f)
        return c * IN.color;

    float2 flowUV = IN.flowPos;
    // Clamp to the bottom-left flowmap pixel
    // that influences this location.
    float2 bottomLeft = floor(flowUV);

    // Sum up the wave contributions from the four
    // closest flow map pixels.     
    float2 wave = WaveAmount(flowUV, bottomLeft);
    wave += WaveAmount(flowUV, bottomLeft + float2(1, 0));
    wave += WaveAmount(flowUV, bottomLeft + float2(1, 1));
    wave += WaveAmount(flowUV, bottomLeft + float2(0, 1));

    // We store total influence in the y channel, 
    // so we can divide it out for a weighted average.
    wave.x /= wave.y;

    // Here I tint the "low" parts a darker blue.
    c = lerp(c, c*c + float4(0, 0, 0.05, 0), waveBlend * 0.5f * saturate(1.2f - 4.0f * wave.x));

    // Then brighten the peaks.
    c += waveBlend * saturate((wave.x - 0.4f) * 20.0f) * 0.1f;

    // And finally return the tinted colour.
    return c * IN.color;
}