Uzupełnianie tabulacji zsh w pustej linii

Chciałbym tcsh'ism, którego nie byłem w stanie znaleźć: w pustym wierszu bez treści chcę nacisnąć klawisz tab i zobaczyć odpowiednik ls. To znaczy, że chcę

$ <tab>

zrobić coś innego niż dać mi. Znalazłem fantastyczne zasoby do wykonywania poleceń, ale nie w tym przypadku podstawowym. Każda pomoc w tym zakresie byłaby świetna! Dzięki.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Zachowanie Tabna początku linii jest kontrolowane przez styl . Istnieją jednak tylko dwa obsługiwane zachowania:insert-tab

• zakończenie jak zwykle poniżej zstyle ':completion:*' insert-tab false
• wstaw kartę pod zstyle ':completion:*' insert-tab true
• jedno lub drugie poniżej zstyle ':completion:*' insert-tab pending[=N]

Jeśli po prostu chcesz wykonać polecenia w tej pozycji, zstyle ':completion:*' insert-tab truezrobi to. Jeśli chcesz czegoś innego, na przykład umieszczenia plików w bieżącym katalogu, musisz zmodyfikować _main_complete.

Ostatni wątek na listę zsh-workers omówione insert-tab.

Oto pełna implementacja autolisty tcsh w zsh, gdy naciśniesz klawisz tabulacji w pustej linii

% <TAB>

Oto on:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Jeśli chcesz dokładniej emulować tcsh, dodaj również to do swojego .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt

Napisałem ten widżet Zsh, który poprawia użycie TAB, nie tylko w pustym wierszu, ale także podczas pisania polecenia.

• Wyświetli listę plików w pustym wierszu polecenia i pośrodku każdego polecenia.
• Wyświetli listę katalogów w pustym wierszu poleceń.
• Wyświetli listę plików wykonywalnych w pustym wierszu poleceń.

W tych przypadkach można go skonfigurować tak, aby poprzedzał „cd” lub „./” zmienną globalną.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA