Jak mogę automatycznie aktualizować Flash Playera przy każdej nowej wersji?

Streszczenie:

Flash Player Update Service nie działa na wiarygodnego harmonogramu, a nie automatycznie pobrać i zastosować aktualizacje, gdy nie działać.

Biorąc pod uwagę znaczenie posiadania aktualnej wersji Flash Playera (dla tych z nas, którzy nie używają Chrome z jego wbudowanym odtwarzaczem), chciałbym znaleźć sposób, aby zapewnić szybkie wykrywanie nowych aktualizacji i zainstalowany.

Poniżej znajdują się szczegóły moich starań, aby rozwiązać ten problem na własną rękę ...

Dodatek A: Usługa aktualizacji Flash Player

OK, wracając do Flash Playera 11.2 (czy tak?) Adobe dodał usługę aktualizacji Flash Playera (FlashPlayerUpdateService.exe), miała aktualizować Flash Playera ...

• Po instalacji FPUS jest skonfigurowany do działania jako usługa systemu Windows, z typem uruchomienia ustawionym na Ręcznie.

• Zaplanowane zadanie (Adobe Flash Player Updater.job) jest dodawane w celu uruchomienia tej usługi co godzinę.

Jak dotąd, tak dobrze - ta konfiguracja pozwala uniknąć ciągłego działania usługi, ale zapewnia, że ​​kontrole są uruchamiane wystarczająco często, aby szybko wykryć wszelkie aktualizacje. Aktualizator oprogramowania Google jest skonfigurowany w podobny sposób, i to działa dobrze ...

... A jednak, kiedy sprawdziłem wersję zainstalowanego Flash Playera, okazało się, że była to wersja 11.6.602.180 , która w oparciu o sprawdzenie znaczników czasowych plików C:\Windows\System32\Macromed\Flashzostała ostatnio zaktualizowana (lub zainstalowana) w wtorek, 12 marca, 2013 --- 3/12/13, 17:00:08 pm .

Dokonałem tej obserwacji w czwartek, 25 kwietnia 2013 r. - 25.04.2013, godz. 19:00 , a po sprawdzeniu witryny Adobe stwierdziłem, że bieżąca wersja Flash Playera to 11.7.700.169 .

To już ponad miesiąc od ostatniej aktualizacji - nowa jest wyraźnie dostępna na stronie internetowej, ale nie wskazuje, że cogodzinna kontrola uruchomiona na moim komputerze zauważyła ją lub nie zamierza jej pobierać.

Dodatek B: ręczne uruchamianie programu aktualizującego Flash Player

Dawno, dawno temu, uruchomienie dałoby Ci okno z przyciskiem Instaluj ; naciśnięcie go spowoduje pobranie instalatora dla bieżącej wersji (automatycznie, bez otwierania przeglądarki) i uruchomienie go, a następnie kliknięcie tego instalatora i gotowe. To było ręczne, ale działało! Znalezienie mojej aktualnej instalacji (patrz Załącznik A), najpierw wypróbowałem ten proces ręcznej aktualizacji. Jednak...FlashUtil32_<version>_Plugin.exe -update plugin

• Uruchamianie (w moim przypadku to jest ) ... przedstawia tylko okno z przyciskiem Pobierz, kliknięcie tego przycisku Pobierz otwiera moją przeglądarkę na adres URL https://get3.adobe.com/flashplayer/update/activex .FlashUtil32_<version>_ActiveX.exe -update activexFlashUtil32_11_6_602_180_ActiveX.exe -update activex

• Uruchamianie (w moim przypadku to jest ) ... przedstawia tylko okno z przyciskiem Pobierz, kliknięcie tego przycisku Pobierz otwiera moją przeglądarkę na adres URL https://get3.adobe.com/flashplayer/update/plugin .FlashUtil32_<version>_Plugin.exe -update pluginFlashUtil32_11_6_602_180_Plugin.exe -update plugin

I mógł kontynuować strony pobrać go wysłał mnie, odznacz pole foistware (! "Bezpłatne McAfee Security skanowania Plus"), że pobieranie instalatora (ActiveX, nie foistware: install_flashplayer11x32axau_mssd_aih.exe, Plugin, nie foistware: install_flashplayer11x32au_mssd_aih.exe) & prawdopodobnie mam zaktualizowaną wersję Flash ... ale jaki jest sens usługi aktualizacji Flash Playera, jeśli muszę ręcznie pobrać i uruchomić inny plik exe?

Epilog

Od tamtej pory podejrzewam, że usługa aktualizacji celowo spętała się, by zachęcić pierwszych użytkowników do pobrania strony. Jeśli to prawda, prawdopodobnie nie ma rozwiązania tego braku pisania własnego aktualizatora; mam nadzieję, że się mylę.

Być może program aktualizujący stosuje tylko aktualizacje z zakresu 11.6.x?

Zawsze możesz użyć bezpośrednich linków do instalatorów, które uważam za bardziej niezawodne: ActiveX ; Plugin .

Z tym plikiem .bat spróbuje automatycznie zaktualizować lub zainstalować Flash Player dla Internet Explorera, Firefoxa (SeaMonkey i etc), opartego na Chromium (Chrome, Opera 15+ itp.):

del install_flash_player.exe
del install_flash_player_ax.exe
del install_flash_player_ppapi.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe
wget http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe
install_flash_player.exe -install
install_flash_player_ax.exe -install
install_flash_player_ppapi.exe -install

Wymagany wget można pobrać tutaj i należy go umieścić w tym samym katalogu, w którym umieszczono .bat.

Trochę bardziej zaawansowany przykład napisany w Autoit .

Funkcje: Proste sprawdzenie nowej wersji, jeśli tutaj nie ma nowej wersji, zamknij program bez pobierania instalatora Flash Player. Jeśli pobieranie instalatora nie powiedzie się, pokaż komunikat z błędem i zakończ. Ukryte okno wiersza polecenia. Nie potrzebuję wgeta.

Po instalacji Autoit i edytora . Kliknij prawym przyciskiem myszy na pulpicie-> Nowy-> Autoit Script. Kliknij utworzony plik prawym przyciskiem myszy-> Edytuj. Teraz powinieneś zobaczyć okno SCITE i po wierszu „Dodaj swój kod poniżej” dodaj ten kod:

#NoTrayIcon
#include <WinAPIDiag.au3>
$flashplayerlink="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
$flashplayername="install_flash_player.exe"
$flashplayerlinkAX="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
$flashplayernameAX="install_flash_player_ax.exe"
updateflashplayer($flashplayerlink,$flashplayername)
updateflashplayer($flashplayerlinkAX,$flashplayernameAX)

$flashplayerlinkPPAPI="http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
$flashplayernamePPAPI="install_flash_player_ppapi.exe"
updateflashplayer($flashplayerlinkPPAPI,$flashplayernamePPAPI)



Func updateflashplayer($link,$fname)
    if FileGetSize($fname)<>InetGetSize($link) then
        InetGet($link,$fname)
        if @error then
            MsgBox(16,"","Error: '"&_WinAPI_GetErrorMessage(@error)&"'"&@CRLF&$fname)
            Exit
        EndIf
        RunWait($fname&" -install","",@SW_HIDE)
    EndIf
EndFunc

Następnie w oknie SciTE naciśnij Narzędzia-> Buduj lub naciśnij F7. Teraz otrzymasz samodzielny plik wykonywalny w tym samym katalogu, w którym znajdował się skrypt Autoit.

Polecam utworzenie nowego folderu (z uprawnieniami do zapisu) dla tego „programu aktualizującego”. Możesz dodać skrót do tego „narzędzia aktualizującego”, aby również uruchomić .

Tutaj aplikacja do odinstalowania Flash Playera.

Chcę udostępnić Ci mój skrypt wsadowy, zapisz ten fragment kodu w swoim notatniku i nazwij go jako Download_Install_Last_Flash_Player.bat

@echo off
REM Help page related to installation problems flash player windows (English)
REM English https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html
REM Page d'aide relative aux problèmes d'installation flash player windows (Français)
REM French https://helpx.adobe.com/fr/flash-player/kb/installation-problems-flash-player-windows.html
Mode 90,3 & color 9D
Title Download and install the latest version of Adobe Flash Player by Hackoo 2017
Set "Download_Folder=%~dp0Latest_Flash_Player_Installers"
Set "Uninstaller_Folder=%~dp0Uninstaller"
Set "Uninstaller_URL=https://fpdownload.macromedia.com/pub/labs/flashruntimes/flashplayer/uninstall_flash_player.exe"
Set "URL1=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player.exe"
Set "URL2=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ax.exe"
Set "URL3=http://fpdownload.macromedia.com/pub/flashplayer/latest/help/install_flash_player_ppapi.exe"
Set "URL_Help=https://helpx.adobe.com/flash-player/kb/installation-problems-flash-player-windows.html"
If Not Exist "%Uninstaller_Folder%" MD "%Uninstaller_Folder%"
If Not Exist "%Download_Folder%" MD "%Download_Folder%"
Call :Killing_Running_Browsers
Rem We Play radio just for fun and in order to let the user be patient until the download ended
Call :Play_DJ_Buzz_Radio
Call :Uninstalling_Flash_Player
Call :Download_and_Install_Flash_Player
REM Just to check (Check Button on the web page) if the latest Adobe Flash Player is installed successfully or not !
Start "Help page" "%URL_Help%" & Call :Stop_Radio & Exit
::***************************************************************************************************
:Uninstalling_Flash_Player
cls & echo( 
@For %%i in (%Uninstaller_URL%) do Set "Uninstaller_File=%%~nxi"
Call :Download "%Uninstaller_URL%" "%Uninstaller_Folder%\%Uninstaller_File%"
echo    Unistalling older and previous version of Adobe Flash Player ...
%Uninstaller_File% -uninstall
exit /b
::***************************************************************************************************
:Killing_Running_Browsers
set "Browsers_List=firefox chrome iexplore opera"
cls & echo(
echo     Killing any running instances of those browsers "%Browsers_List%" ...
@For %%i in (%Browsers_List%) Do ( 
    Taskkill /IM "%%i.exe" /F>nul 2>&1
)
exit /b
::***************************************************************************************************
:Download_and_Install_Flash_Player
@For %%i in (%URL1%) do Set "File1=%%~nxi"
Call :Download "%URL1%" "%Download_Folder%\%File1%"
Call :Installing_Flash_Player "%Download_Folder%\%File1%"
@For %%i in (%URL2%) do Set "File2=%%~nxi"
Call :Download "%URL2%" "%Download_Folder%\%File2%"
Call :Installing_Flash_Player "%Download_Folder%\%File2%"
@For %%i in (%URL3%) do Set "File3=%%~nxi"
Call :Download "%URL3%" "%Download_Folder%\%File3%"
Call :Installing_Flash_Player "%Download_Folder%\%File3%"
exit /b
::***************************************************************************************************
:Installing_Flash_Player <Install_File>
cls & color 9B
echo(
echo   Please wait a while ... installing "%~nx1" is in progress ...
%1 -install
exit /b
::***************************************************************************************************
:Download <url> <File>
cls & color 0A
echo(
echo      Please wait a while ... Downloading "%~n2" is in progress ...
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::***************************************************************************************************
:Play_DJ_Buzz_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
Set "vbsfile=%temp%\DJBuzzRadio.vbs"
Set "URL=http://www.chocradios.ch/djbuzzradio_windows.mp3.asx"
Call:Play "%URL%" "%vbsfile%"
Start "" "%vbsfile%"
Exit /b
::**************************************************************
:Play
(
echo Play "%~1"
echo Sub Play(URL^)
echo    Dim Sound
echo    Set Sound = CreateObject("WMPlayer.OCX"^)
echo    Sound.URL = URL
echo    Sound.settings.volume = 100
echo    Sound.Controls.play
echo    do while Sound.currentmedia.duration = 0
echo       wscript.sleep 100
echo    loop
echo    wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000
echo End Sub
)>%~2
exit /b
::**************************************************************
:Stop_Radio
Taskkill /IM "wscript.exe" /F >nul 2>&1
If Exist "%vbsfile%" Del "%vbsfile%"
::**************************************************************