Plik wsadowy zastępujący „.” Za pomocą „-”

Muszę zachować rozszerzenia plików i pracować z podfolderami.

Na przykład: „File.name.ext” powinno stać się „File-name.ext”

Jestem całkowicie nieświadomy co do skryptu powłoki, więc proszę o szczegółową odpowiedź. Nie mam pojęcia, co oznaczają przełączniki, ani nawet jak określić ścieżkę do tego celu.

Całkowicie zgadzam się z drugą odpowiedzią. Byłoby to narzędzie do zmiany nazw masowych GUI więc znacznie łatwiejszy w użyciu. Jednak dla zabawy napisałem następujący plik wsadowy, który powinien rekursywnie zmieniać wszystkie pliki w bieżącym katalogu. i podkatalogi. i zastąp. z - (na przykład „ Długi plik. .name.ext " stanie się " Long -file--name.ext „):

@echo off
setlocal enabledelayedexpansion
for /r %%f in (*.*) do (
    set fn=%%~nf

    REM Remove the echo from the following line to perform the actual renaming!
    if not [!fn!]==[] if not ["%%~nxf"]==["!fn:.=-!%%~xf"] echo ren "%%~f" "!fn:.=-!%%~xf"
)
pause

Uruchom plik wsadowy raz, a jeśli wynik wydaje się zadowalający, wykonaj rzeczywistą zmianę nazwy, usuwając słowo echo (druga instancja, nie z pierwszej linii) i ponowne uruchomienie pliku.

W jakiś sposób nie rozumiem, dlaczego w takim razie chcesz zawracać sobie głowę plikiem wsadowym. Dlaczego nie skorzystasz z jednego z bazillionowych narzędzi do zmiany nazw GUI, takich jak:

http://www.beroux.com/english/softwares/renameit/

Jeśli ten konkretny nie unosi twojej łodzi, sprawdź tę paradę:

http://www.techsupportalert.com/best-free-rename-utility.htm

Oto moja ostateczna, przetestowana wersja pliku wsadowego, która może robić to, co chcesz. Działa z plikami z lub bez nazw plików lub rozszerzeń, jednak pliki z nazwami zawierającymi % lub ! będzie powodować problemy .

Używa rozszerzenia opóźnionego, więc musisz uruchomić go z wiersza polecenia z opóźnionym rozszerzeniem (po prostu uruchom setlocal /enabledelayedexpansion nie rozetnie go, ponieważ tylko to włącza jeśli jest już włączony ; nie działa, jeśli nie jest włączony, gdy uruchamiany jest wiersz polecenia).

Możesz włączyć rozszerzenie opóźnione, otwierając wiersz polecenia za pomocą /V:ON przełącznik, ale możesz to również zrobić z istniejącego wiersza polecenia, jak w pliku wsadowym poniżej.

@echo off

:: This batch file (prints the command to) rename files so that
:: any dots (.) are replaced with dashes (-)
::
:: Note, files with names containing percents (%) and exclamantions (!)
:: will intefere with command-prompt syntax and are not supported, but
:: can be worked around: https://stackoverflow.com/questions/5226793/

:: If this batch-file has no parameters...
if [%1]==[] (
    :: Open a new command-prompt with delayed-expansion enabled and call self
    cmd /v:on /c "%0" +
    :: Quit
    goto :eof
)

:: Recurse through all files in all subdirectories
for /r %%i in (*) do (

    rem (:: cannot be used for comments in a FOR loop)
    rem Check if it has an extension
    if [%%~xi]==[] (
        rem If it has an extension, preserve it
        set RENFN=%%~nxi
    ) else (
        rem Copy the path (and filename)
        set RENFN=%%~ni
        rem Check if it has a filename
        if not [%%~ni]==[] (
            rem If it has a filename, replace dots with dashes
            set RENFN=!RENFN:.=-!
        )
    )

    rem Rename original file
    ren "%%i" "!RENFN!%%~xi"

)

:: Exit spawned shell (no need to use setlocal to wipe out the envvar)
exit

:: Test output:
::
:: C:\t> dir /b/a
::
:: .txt
:: blah
:: file.blah.txt
:: foo.bar.txt
:: super duper. .blah.ttt. omergerd.---.mp4
:: t.bat
::
:: C:\t> t.bat
::
:: ren "C:\t\.txt" ".txt"
:: ren "C:\t\blah" "blah"
:: ren "C:\t\file.blah.txt" "file-blah.txt"
:: ren "C:\t\foo.bar.txt" "foo-bar.txt"
:: ren "C:\t\super duper. .blah.ttt. omergerd.---.mp4" "super duper- -blah-ttt- omergerd----.mp4"
:: ren "C:\t\t.bat" "t.bat"