Jak zmienić język wszystkich slajdów Powerpoint na raz?

Chociaż ten wątek jest dość stary, Microsoft nie dostarczył żadnego znanego mi rozwiązania. Sugeruję inne podejście dla użytkowników komputerów Mac: otwórz prezentację w Keynote, zmień język pisowni i ewentualnie edytuj całą prezentację, a następnie wyeksportuj ją do programu PowerPoint.

Aby łatwo zmienić język całego programu PowerPoint, otwórz kartę Widok i wybierz Widok konspektu .

Teraz naciśnij

• Ctrl+, Aaby zaznaczyć wszystko.
• Narzędzia → Język → Wybierz język, który chcesz ustawić.

Podobnie, gdy masz już wszystko wybrane, możesz zmieniać inne rzeczy, takie jak czcionki, kolory itp. Chociaż oczywiście w wielu przypadkach lepiej to zrobić, zmieniając suwak, prezentacja z wieloma edytorami może mieć wiele „twardych” zestawów formatujących, które odbiega od głównego wzorca i wymaga resetu, aby zachować spójność. Możesz także zresetować poszczególne slajdy do stylu głównego, ale może to również powodować przesuwanie symboli zastępczych, co może być niepożądane w niektórych sytuacjach.

PowerPoint 2013

• Widok → Zarys → wybierz wszystkie slajdy (w menu po lewej) za pomocą Ctrl+ A.
• Recenzja → Język → Ustaw język sprawdzania ... → Wybierz język, który chcesz ustawić.

Jeśli chodzi o mnie - konieczne było ponowne uruchomienie programu PowerPoint . Prawdopodobnie dlatego, że zmieniłem także język edycji :

• Recenzja → Język → Ustaw język sprawdzania ... → Preferencje językowe → Wybierz języki edycji .

Używając Powerpoint 2010 otworzyłem menu konspektu -

Zaznaczam cały tekst (Ctrl + A), otworzyłem menu języka i ustawiłem język sprawdzania

I zadziałało!

Menu języka znajduje się na karcie wstążki Recenzja (po karcie Pokaz slajdów i nie jest widoczne na zrzucie ekranu).

Istniejące odpowiedzi działają na tekst obecny w konspekcie. Niestety w moim przypadku nie obejmowało to znacznej części tekstu, w tym rysunków, tabel itp.

To makro rozwiązało problem dla mnie:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

„MsoLanguageIDEnglishUS”, który jest używany w powyższym makrze, można zastąpić dowolnym pożądanym językiem. Pełna lista języków znajduje się w tym artykule

(Podziękowania należą się Ganeshowi Kumarowi, który zamieścił tutaj oryginalne makro . Dodałem obsługę pierwszego poziomu grupowania kształtów. W celu dalszego ulepszenia makra można go rekurencyjnie szukać grup zawierających inne grupy itp.)

Poprawiłem odpowiedź Inigo, aby zapewnić wersję rekurencyjną, która zmienia wszystkie elementy na pożądany język.

Ta wersja bada rekurencyjnie każdy kształt, który jest typem grupy. Niektóre eksperymenty sugerują, że msoGroupi msoSmartArtsą to typy grup - możesz dodać do tej listy, jeśli znajdziesz inne typy kształtów, które mogą pomieścić obiekty tekstowe.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Na podstawie odpowiedzi Inigo, Duncana, Marii i DomDev działa to w przypadku kształtów, tabel, grup, SmartArt, teraz iw przyszłości:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Wersja Duncan działa dobrze do wszystkiego oprócz tabel. Znalazłem inny kod, który wydaje się również działać z tabelami: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Oprócz odpowiedzi udzielonej przez Mastergalen i odpowiedzi na komentarze dotyczące nowego tekstu:

Jeśli zauważysz, że język ten zmieni się automatycznie za każdym razem, gdy zaczniesz pisać nowy tekst (co jest bardzo denerwujące), musisz zmienić bieżący domyślny język programu PowerPoint:

• upewnij się, że okno programu PowerPoint jest aktywnym oknem
• w Windows Taskbar(tak, właściwie nie w programie PowerPoint) sprawdź, czy Language barjest widoczny,
  • jeśli nie, przejdź do Control Panel > Region and Language > Keyboards and Languages. Kliknij Change keybords..., przejdź do Language barzakładki i zaznacz Docked in the taskbaropcję. (pochodzi z Win7, więc może być nieco inaczej w innych wersjach).
• teraz kluczowa akcja - Language barna pasku zadań kliknij kod języka i przełącz się na EN (jeśli chcesz obecnie używać języka angielskiego w programie PowerPoint). Od teraz cały nowy tekst w programie PowerPoint będzie w wybranym języku :-)
• jeśli chcesz pisać w swoim oryginalnym języku, po prostu zmień go z powrotem.

W 2014 roku zrobiłem dla siebie dodatek, który nadal działa dobrze w programie PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Skanuje w poszukiwaniu używanych języków i umożliwia zmianę wszystkich naraz.