Przenoszenie okien za pomocą klawiatury… szybciej?

Lubię używać skrótów klawiaturowych, ponieważ jest szybszy, ponieważ nie zmusza mnie do odrywania rąk od klawiatury.

W systemie Windows mogę ich używać do przenoszenia okien po pulpicie:

1. Naciśnij Alt+, Spaceaby otworzyć wspólne menu systemu Windows
2. Naciśnij, Maby wybrać polecenie „Przenieś”
3. Poruszaj się po oknie za pomocą klawiszy kursora
4. Potwierdź nową pozycję za pomocą Enter

Dodatkowo, aby osiągnąć lepszą dokładność, mogę trzymać Ctrlpodczas nawigacji.

Problem polega na tym, że normalny „krok” podczas przenoszenia wynosi około 20 pikseli, a mój pulpit jest dość duży, więc „przejście” na drugą stronę zajmuje dość dużo czasu. Ten rodzaj nie pozwala na użycie klawiatury do tych zadań.

Czy można zmienić rozmiar tego kroku, aby przejść mniej więcej tyle samo kroków? (Wyobrażam sobie ukryte ustawienie w rejestrze systemu Windows ...?)

Próbowałem przytrzymać Altpodczas nawigacji, ale wydaje się, że nie ma to wpływu na prędkość.

Jeśli masz ochotę całkowicie przerobić paradygmaty okienkowania w kierunku dynamicznego kafelkowania, rozważ skrypt AutoHotkey o nazwie „ bug.n ”. Spodoba ci się, jeśli wolisz manipulować oknami za pomocą klawiatury.

Poruszanie się po klawiaturze tak jak ty jest precyzyjne, ale uciążliwe.

Jeśli zazwyczaj przenosisz okna do określonych pozycji i rozmiarów, spróbuj GridMove . Możesz zdefiniować własną siatkę (położenie i rozmiary okna) lub użyć predefiniowanych. Każdy z nich nazywany jest kafelkiem. Następnie możesz przyciągnąć dowolne aktywne okno, naciskając Win + 2, gdzie 2 to numer kafelka, w którym ma być przyciągany. Naciśnij Win + G, aby zobaczyć płytki i ich liczby w bieżącej siatce.

W systemie Windows 7 możesz używać klawiszy Windows + Strzałka, aby przenosić okna.

Nie jestem pewien, o ile pikseli przesuwa je na raz, ale to więcej niż 20.

Nie do końca na ten temat, ale uważam, że jest to nadal aktualne i warte podzielenia się.

Używam AutoHotKey i skryptu „KDEStyle”, który znalazłem dawno temu i zaadaptowałem, aby poprawić wykorzystanie myszy do tego celu.

• Win + Left Click
  • Umożliwia przesuwanie okna poprzez kliknięcie w dowolnym miejscu w nim.
• Win + Right Click
  • Umożliwia zmianę rozmiaru okna za pomocą najbliższego rogu - ponownie klikając w dowolnym miejscu w nim.

To znacznie zmniejsza wymaganą precyzję i moim zdaniem znacznie ułatwia i przyspiesza korzystanie z myszy do takich celów.

#LButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,,,ahk_id %KDE_id%
    loop {
        GetKeyState,KDE_Button,LButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        KDE_WinX2 := (KDE_WinX1 + KDE_X2)
        KDE_WinY2 := (KDE_WinY1 + KDE_Y2)
        WinMove,ahk_id %KDE_id%,,%KDE_WinX2%,%KDE_WinY2%
    }
    return

#RButton::
    MouseGetPos,KDE_X1,KDE_Y1,KDE_id
    WinGet,KDE_Win,MinMax,ahk_id %KDE_id%
    if KDE_Win
        return
    WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
    if (KDE_X1 < KDE_WinX1 + KDE_WinW / 2) {
        KDE_WinLeft := 1
    } else {
        KDE_WinLeft := -1
    }
    if (KDE_Y1 < KDE_WinY1 + KDE_WinH / 2) {
        KDE_WinUp := 1
    } else {
        KDE_WinUp := -1
    }
    loop {
        GetKeyState,KDE_Button,RButton,P
        if KDE_Button = U
            break
        MouseGetPos,KDE_X2,KDE_Y2
        WinGetPos,KDE_WinX1,KDE_WinY1,KDE_WinW,KDE_WinH,ahk_id %KDE_id%
        KDE_X2 -= KDE_X1
        KDE_Y2 -= KDE_Y1
        WinMove,ahk_id %KDE_id%,, KDE_WinX1 + (KDE_WinLeft+1)/2*KDE_X2
                                , KDE_WinY1 +   (KDE_WinUp+1)/2*KDE_Y2
                                , KDE_WinW  -     KDE_WinLeft  *KDE_X2
                                , KDE_WinH  -       KDE_WinUp  *KDE_Y2
        KDE_X1 := (KDE_X2 + KDE_X1)
        KDE_Y1 := (KDE_Y2 + KDE_Y1)
    }
    return

Standardowe kombinacje klawiatury Windows uzupełniają to i umożliwiają:

• Win+ Up/Down
  • Maksymalizuj / Przywróć / Minimalizuj
• Win+ Left/Right
  • Zmień rozmiar na lewą / prawą połowę ekranu
• Win+ Shift+ Left/Right
  • Przesuń jeden monitor w lewo / w prawo
• itp...