Jak mogę sprawdzić, gdzie JDK jest zainstalowany na moim komputerze z systemem Windows?

Muszę wiedzieć, gdzie JDK znajduje się na moim komputerze.

Po uruchomieniu Java -versionw cmd pokazuje wersję jako „1.6.xx”. Aby znaleźć lokalizację tego zestawu SDK na moim komputerze, próbowałem go użyć, echo %JAVA_HOME%ale pokazuje on tylko „JAVA_HOME” (ponieważ w moich zmiennych środowiskowych nie ma zestawu zmiennych „JAVA_PATH”).

Jeśli używasz Linux / Unix / Mac OS X:

Spróbuj tego:

$ which java

Powinien podać dokładną lokalizację.

Następnie możesz JAVA_HOMEsamodzielnie ustawić zmienną środowiskową.

Na moim komputerze (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

Jeśli używasz systemu Windows:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i

Windows> Start> cmd>

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

Jeśli masz zainstalowany JDK, wyświetlana jest ścieżka,
na przykład:C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

W systemie Windows w wierszu polecenia

where javac

W systemie Windows wartością domyślną jest: C:\Program Files\Java\jdk1.6.0_14(gdzie liczby mogą się różnić, ponieważ są wersją).

Instalator Java umieszcza kilka plików w folderze% WinDir% \ System32 (java.exe, javaws.exe i kilka innych). Gdy wpiszesz java.exe w wierszu polecenia lub utworzysz proces bez pełnej ścieżki, system Windows uruchomi je w ostateczności, jeśli brakuje ich w folderach% PATH%.

Możesz wyszukać wszystkie wersje Java zainstalowane w rejestrze. Spójrz na HKLM \ SOFTWARE \ JavaSoft \ Java Runtime Environment i HKLM \ SOFTWARE \ Wow6432Node \ JavaSoft \ Java Runtime Environment dla 32-bitowej wersji Java w 64-bitowym systemie Windows.

W ten sposób sama Java wykrywa zainstalowane różne wersje. I dlatego zarówno wersja 32-bitowa, jak i wersja 64-bitowa mogą współistnieć i działają dobrze bez ingerencji.

Proste i proste na platformach Windows:

gdzie java

Poniższy skrypt wsadowy wydrukuje istniejące domyślne środowisko JRE. To może być łatwo modyfikowane, aby znaleźć wersję JDK zainstalowane zastępując Java Runtime Environment z Java Development Kit .

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal

W systemie Windows 10 możesz znaleźć ścieżkę, przechodząc do Panelu sterowania> Java. W panelu, który się pojawi, możesz znaleźć ścieżkę, jak pokazano na zrzucie ekranu poniżej. W panelu sterowania Java przejdź do zakładki „Java”, a następnie kliknij przycisk „Widok” pod opisem „Wyświetl wersje środowiska Java Runtime i ustawienia dla aplikacji i apletów Java”.

Powinno to działać w systemie Windows 7 i ewentualnie innych najnowszych wersjach systemu Windows.

W wierszu polecenia systemu Windows wpisz:

set java_home

Lub, jeśli nie podoba ci się środowisko poleceń, możesz to sprawdzić w:

Menu Start> Komputer> Właściwości systemu> Zaawansowane właściwości systemu. Następnie otwórz kartę Zaawansowane> Zmienne środowiskowe i w zmiennej systemowej spróbuj znaleźć JAVA_HOME.

W systemie Windows możesz używać

C:>dir /b /s java.exe

aby wydrukować pełną ścieżkę każdego pliku „java.exe” na dysku C:, niezależnie od tego, czy znajdują się one w zmiennej środowiskowej PATH.

Więcej informacji o systemie Windows ... zmienna java.home nie zawsze jest tą samą lokalizacją, co uruchamiany plik binarny.

Jak mówi Denis The Menace, instalator umieszcza pliki Java w plikach programu , ale także java.exe w System32 . Bez ścieżki Java na ścieżce java -version może nadal działać. Jednak po uruchomieniu programu PeterMmm zgłasza wartość plików programu jako java.home , to nie jest źle (Java jest tam zainstalowana), ale faktycznie uruchamiany plik binarny znajduje się w System32 .

Jednym ze sposobów, aby dopaść lokalizację java.exe binarnego, dodaj następującą linię kodu PeterMmm by zachować program działa trochę dłużej:

try{Thread.sleep(60000);}catch(Exception e) {}

Skompiluj i uruchom go, a następnie wyszukaj lokalizację obrazu java.exe . Np. W Windows 7 otwórz menedżera zadań, znajdź pozycję java.exe , kliknij prawym przyciskiem myszy i wybierz „otwórz lokalizację pliku”, to otworzy dokładną lokalizację pliku binarnego Java. W tym przypadku byłby to System32 .

Uruchom ten program z wiersza poleceń:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main

Wkładka PowerShell One:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome

Próbowałeś sprawdzić swoją zmienną% PATH%. Właśnie tego używa Windows, aby znaleźć dowolny plik wykonywalny.

Wystarczy wykonać setpolecenie w linii poleceń. Następnie zobaczysz wszystkie ustawione zmienne środowiskowe.

Lub jeśli na Uniksie możesz to uprościć:

$ set | grep "JAVA_HOME" 

Jest to specyficzne dla systemu operacyjnego. W systemie Unix:

which java

wyświetli ścieżkę do pliku wykonywalnego. Nie znam odpowiednika systemu Windows, ale tam zwykle masz binfolder instalacji JDK w systemie PATH:

echo %PATH%

Żadna z tych odpowiedzi nie jest poprawna dla Linuksa, jeśli szukasz domu zawierającego podkatalogi, takie jak: bin, docs, include, jre, lib itp.

W Ubuntu dla openjdk1.8.0 jest to: /usr/lib/jvm/java-1.8.0-openjdk-amd64

i możesz tego użyć, JAVA_HOMEponieważ będziesz mógł znaleźć nagłówki, jeśli zbudujesz pliki źródłowe JNI. Chociaż prawda which javazapewnia ścieżkę binarną, nie jest to prawdziwy dom JDK.

W systemie macOS uruchom:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

Na moim komputerze to drukuje:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

Zauważ, że uruchomienie which javanie pokazuje położenia JDK, ponieważ javapolecenie jest zamiast tego częścią JavaVM.framework, która otacza prawdziwy JDK:

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

w Windows cmd:

set "JAVA_HOME" 

#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

Dla Windowsa:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

Ten link może pomóc wyjaśnić, jak znaleźć plik wykonywalny Java z bash: http://srcode.org/2014/05/07/detect-java-executable/

Poprawiłem powyższą odpowiedź munsingh , testując klucz rejestru w rejestrach 64-bitowych i 32-bitowych, w razie potrzeby:

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

odniesienie do dostępu do rejestru 64-bitowego

Skrypt dla 32/64-bitowego systemu Windows.

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal