wyjście vbscript do konsoli

Jakie jest polecenie lub najszybszy sposób wyprowadzenia wyników do konsoli przy użyciu vbscript?

Masz na myśli:

Wscript.Echo "Like this?"

Jeśli uruchomisz to w ramach wscript.exe(domyślny program obsługi rozszerzenia .vbs, więc co uzyskasz, jeśli dwukrotnie klikniesz skrypt), pojawi się okno dialogowe „MessageBox” z Twoim tekstem. Jeśli uruchomisz to poniżej cscript.exe, otrzymasz dane wyjściowe w oknie konsoli.

Zostało to znalezione w skryptach Dragon-IT i repozytorium kodu .

Możesz to zrobić w następujący sposób i trzymać się z dala od różnic między cscript / wscript, a także uzyskać takie same dane wyjściowe konsoli, jakie miałby plik wsadowy. Może to pomóc, jeśli dzwonisz do VBS z pliku wsadowego i chcesz, aby wyglądało bezproblemowo.

Set fso = CreateObject ("Scripting.FileSystemObject")
Set stdout = fso.GetStandardStream (1)
Set stderr = fso.GetStandardStream (2)
stdout.WriteLine "This will go to standard output."
stderr.WriteLine "This will go to error output."

Musisz tylko wymusić cscript zamiast wscript. Zawsze używam tego szablonu. Funkcja ForceConsole () wykona twoje vbs do cscript, masz również ładny alias do drukowania i skanowania tekstu.

 Set oWSH = CreateObject("WScript.Shell")
 vbsInterpreter = "cscript.exe"

 Call ForceConsole()

 Function printf(txt)
    WScript.StdOut.WriteLine txt
 End Function

 Function printl(txt)
    WScript.StdOut.Write txt
 End Function

 Function scanf()
    scanf = LCase(WScript.StdIn.ReadLine)
 End Function

 Function wait(n)
    WScript.Sleep Int(n * 1000)
 End Function

 Function ForceConsole()
    If InStr(LCase(WScript.FullName), vbsInterpreter) = 0 Then
        oWSH.Run vbsInterpreter & " //NoLogo " & Chr(34) & WScript.ScriptFullName & Chr(34)
        WScript.Quit
    End If
 End Function

 Function cls()
    For i = 1 To 50
        printf ""
    Next
 End Function

 printf " _____ _ _           _____         _    _____         _     _   "
 printf "|  _  |_| |_ ___ ___|     |_ _ _ _| |  |   __|___ ___|_|___| |_ "
 printf "|     | | '_| . |   |   --| | | | . |  |__   |  _|  _| | . |  _|"
 printf "|__|__|_|_,_|___|_|_|_____|_____|___|  |_____|___|_| |_|  _|_|  "
 printf "                                                       |_|     v1.0"
 printl " Enter your name:"
 MyVar = scanf
 cls
 printf "Your name is: " & MyVar
 wait(5)

Natknąłem się na ten post i wróciłem do podejścia, które stosowałem jakiś czas temu, które jest podobne do @ MadAntrax.

Główną różnicą jest to, że używa on zdefiniowanej przez użytkownika klasy VBScript do zawijania całej logiki przełączania na CScript i wysyłania tekstu do konsoli, dzięki czemu główny skrypt jest nieco czystszy.

Zakłada się, że Twoim celem jest strumieniowe przesyłanie danych wyjściowych do konsoli, zamiast kierowania danych wyjściowych do okien komunikatów.

Klasa cCONSOLE znajduje się poniżej. Aby z niej skorzystać, dołącz całą klasę na końcu skryptu, a następnie utwórz jej instancję bezpośrednio na początku skryptu. Oto przykład:

    Option Explicit

'// Instantiate the console object, this automatically switches to CSCript if required
Dim CONS: Set CONS = New cCONSOLE

'// Now we can use the Consol object to write to and read from the console
With CONS

    '// Simply write a line
     .print "CSCRIPT Console demo script"

     '// Arguments are passed through correctly, if present
     .Print "Arg count=" & wscript.arguments.count

     '// List all the arguments on the console log
     dim ix
     for ix = 0 to wscript.arguments.count -1
        .print "Arg(" & ix & ")=" & wscript.arguments(ix)
     next

     '// Prompt for some text from the user
     dim sMsg : sMsg = .prompt( "Enter any text:" )

     '// Write out the text in a box
     .Box sMsg

     '// Pause with the message "Hit enter to continue"
     .Pause

End With     




'= =========== End of script - the cCONSOLE class code follows here

Oto kod klasy cCONSOLE

     CLASS cCONSOLE
 '= =================================================================
 '= 
 '=    This class provides automatic switch to CScript and has methods
 '=    to write to and read from the CSCript console. It transparently
 '=    switches to CScript if the script has been started in WScript.
 '=
 '= =================================================================

    Private oOUT
    Private oIN


    Private Sub Class_Initialize()
    '= Run on creation of the cCONSOLE object, checks for cScript operation


        '= Check to make sure we are running under CScript, if not restart
        '= then run using CScript and terminate this instance.
        dim oShell
        set oShell = CreateObject("WScript.Shell")

        If InStr( LCase( WScript.FullName ), "cscript.exe" ) = 0 Then
            '= Not running under CSCRIPT

            '= Get the arguments on the command line and build an argument list
            dim ArgList, IX
            ArgList = ""

            For IX = 0 to wscript.arguments.count - 1
                '= Add the argument to the list, enclosing it in quotes
                argList = argList & " """ & wscript.arguments.item(IX) & """"
            next

            '= Now restart with CScript and terminate this instance
            oShell.Run "cscript.exe //NoLogo """ & WScript.ScriptName & """ " & arglist
            WScript.Quit

        End If

        '= Running under CScript so OK to continue
        set oShell = Nothing

        '= Save references to stdout and stdin for use with Print, Read and Prompt
        set oOUT = WScript.StdOut
        set oIN = WScript.StdIn

        '= Print out the startup box 
            StartBox
            BoxLine Wscript.ScriptName
            BoxLine "Started at " & Now()
            EndBox


    End Sub

    '= Utility methods for writing a box to the console with text in it

            Public Sub StartBox()

                Print "  " & String(73, "_") 
                Print " |" & Space(73) & "|"
            End Sub

            Public Sub BoxLine(sText)

                Print Left(" |" & Centre( sText, 74) , 75) & "|"
            End Sub

            Public Sub EndBox()
                Print " |" & String(73, "_") & "|"
                Print ""
            End Sub

            Public Sub Box(sMsg)
                StartBox
                BoxLine sMsg
                EndBox
            End Sub

    '= END OF Box utility methods


            '= Utility to center given text padded out to a certain width of text
            '= assuming font is monospaced
            Public Function Centre(sText, nWidth)
                dim iLen
                iLen = len(sText)

                '= Check for overflow
                if ilen > nwidth then Centre = sText : exit Function

                '= Calculate padding either side
                iLen = ( nWidth - iLen ) / 2

                '= Generate text with padding
                Centre = left( space(iLen) & sText & space(ilen), nWidth )
            End Function



    '= Method to write a line of text to the console
    Public Sub Print( sText )

        oOUT.WriteLine sText
    End Sub

    '= Method to prompt user input from the console with a message
    Public Function Prompt( sText )
        oOUT.Write sText
        Prompt = Read()
    End Function

    '= Method to read input from the console with no prompting
    Public Function Read()
        Read = oIN.ReadLine
    End Function

    '= Method to provide wait for n seconds
    Public Sub Wait(nSeconds)
        WScript.Sleep  nSeconds * 1000 
    End Sub

    '= Method to pause for user to continue
    Public Sub Pause
        Prompt "Hit enter to continue..."
    End Sub


 END CLASS

Istnieje pięć sposobów wyświetlania tekstu na konsolę:

Dim StdOut : Set StdOut = CreateObject("Scripting.FileSystemObject").GetStandardStream(1)

WScript.Echo "Hello"
WScript.StdOut.Write "Hello"
WScript.StdOut.WriteLine "Hello"
Stdout.WriteLine "Hello"
Stdout.Write "Hello"

WScript.Echo wyświetli dane wyjściowe do konsoli, ale tylko wtedy, gdy skrypt zostanie uruchomiony przy użyciu cscript.exe. Wyświetli się w oknach komunikatów, jeśli zostanie uruchomiony przy użyciu wscript.exe.

WScript.StdOut.Write i WScript.StdOut.WriteLine zawsze będą wyświetlane na konsoli.

StdOut.Write i StdOut.WriteLine będą również zawsze wyświetlane na konsoli. Wymaga tworzenia dodatkowych obiektów, ale jest około 10% szybsze niż WScript.Echo.