Chciałbym zobaczyć wyniki testu (system.out / err, rejestruj komunikaty z testowanych komponentów), ponieważ działają one w tej samej konsoli, którą uruchamiam:

gradle test

I nie czekaj, aż testy zostaną wykonane, aby przejrzeć raporty z testów (które są generowane tylko po zakończeniu testów, więc nie mogę „ogonić” niczego podczas testów)

Możesz uruchomić Gradle z poziomem rejestrowania INFO w wierszu poleceń. Pokaże wynik każdego testu podczas jego działania. Minusem jest to, że uzyskasz znacznie więcej wyników w przypadku innych zadań.

gradle test -i

Oto moja wymyślna wersja:

import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

tasks.withType(Test) {
    testLogging {
        // set options for log level LIFECYCLE
        events TestLogEvent.FAILED,
               TestLogEvent.PASSED,
               TestLogEvent.SKIPPED,
               TestLogEvent.STANDARD_OUT
        exceptionFormat TestExceptionFormat.FULL
        showExceptions true
        showCauses true
        showStackTraces true

        // set options for log level DEBUG and INFO
        debug {
            events TestLogEvent.STARTED,
                   TestLogEvent.FAILED,
                   TestLogEvent.PASSED,
                   TestLogEvent.SKIPPED,
                   TestLogEvent.STANDARD_ERROR,
                   TestLogEvent.STANDARD_OUT
            exceptionFormat TestExceptionFormat.FULL
        }
        info.events = debug.events
        info.exceptionFormat = debug.exceptionFormat

        afterSuite { desc, result ->
            if (!desc.parent) { // will match the outermost suite
                def output = "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} passed, ${result.failedTestCount} failed, ${result.skippedTestCount} skipped)"
                def startItem = '|  ', endItem = '  |'
                def repeatLength = startItem.length() + output.length() + endItem.length()
                println('\n' + ('-' * repeatLength) + '\n' + startItem + output + endItem + '\n' + ('-' * repeatLength))
            }
        }
    }
}

Możesz dodać Groovy zamknięcie w pliku build.gradle, który rejestruje się za Ciebie:

test {
    afterTest { desc, result -> 
        logger.quiet "Executing test ${desc.name} [${desc.className}] with result: ${result.resultType}"
    }
}

Na konsoli wyświetla się następująco:

:compileJava UP-TO-DATE
:compileGroovy
:processResources
:classes
:jar
:assemble
:compileTestJava
:compileTestGroovy
:processTestResources
:testClasses
:test
Executing test maturesShouldBeCharged11DollarsForDefaultMovie [movietickets.MovieTicketsTests] with result: SUCCESS
Executing test studentsShouldBeCharged8DollarsForDefaultMovie [movietickets.MovieTicketsTests] with result: SUCCESS
Executing test seniorsShouldBeCharged6DollarsForDefaultMovie [movietickets.MovieTicketsTests] with result: SUCCESS
Executing test childrenShouldBeCharged5DollarsAnd50CentForDefaultMovie [movietickets.MovieTicketsTests] with result: SUCCESS
:check
:build

Od wersji 1.1 Gradle obsługuje znacznie więcej opcji rejestrowania wyników testu . Dzięki tym dostępnym opcjom możesz osiągnąć podobny wynik w następującej konfiguracji:

test {
    testLogging {
        events "passed", "skipped", "failed"
    }
}

Jak odpowiedział stefanglase :

dodanie następującego kodu do build.gradle(od wersji 1.1) działa dobrze dla danych wyjściowych z pozytywnych , pomijanych i nieudanych testów.

test {
    testLogging {
        events "passed", "skipped", "failed", "standardOut", "standardError"
    }
}

Chciałbym dodatkowo powiedzieć (dowiedziałem się, że jest to problem na początek), że gradle testpolecenie wykonuje test tylko raz na zmianę .

Więc jeśli uruchomisz go po raz drugi, wyniki testu nie będą wyświetlane . Można również zobaczyć w produkcji budowlanej: Gradle czym mówi się na bieżąco na testach. Więc nie jest wykonywany n-ty raz.

Inteligentna klasa!

Jeśli chcesz wymusić uruchomienie przypadków testowych, użyj gradle cleanTest test.

To nieco nie na temat, ale mam nadzieję, że pomoże niektórym początkującym.

edytować

Jak sparc_spread stwierdził w komentarzach:

Jeśli chcesz wymusić na gradie, aby zawsze uruchamiał nowe testy (co może nie zawsze być dobrym pomysłem), możesz outputs.upToDateWhen {false}do niego dodać testLogging { [...] }. Kontynuuj czytanie tutaj .

Pokój.

Oświadczenie: Jestem twórcą wtyczki Gradle Test Logger.

Możesz po prostu użyć wtyczki Gradle Test Logger, aby wydrukować piękne logi na konsoli. Wtyczka używa rozsądnych ustawień domyślnych, aby zadowolić większość użytkowników z niewielką konfiguracją lub bez niej, ale oferuje także szereg motywów i opcji konfiguracji, które zadowolą każdego.

Przykłady

Standardowy motyw

Motyw mokka

Stosowanie

plugins {
    id 'com.adarshr.test-logger' version '<version>'
}

Upewnij się, że zawsze otrzymujesz najnowszą wersję od Gradle Central .

Konfiguracja

W ogóle nie potrzebujesz żadnej konfiguracji. Jednak wtyczka oferuje kilka opcji. Można to zrobić w następujący sposób (pokazane wartości domyślne):

testlogger {
    // pick a theme - mocha, standard, plain, mocha-parallel, standard-parallel or plain-parallel
    theme 'standard'

    // set to false to disable detailed failure logs
    showExceptions true

    // set to false to hide stack traces
    showStackTraces true

    // set to true to remove any filtering applied to stack traces
    showFullStackTraces false

    // set to false to hide exception causes
    showCauses true

    // set threshold in milliseconds to highlight slow tests
    slowThreshold 2000

    // displays a breakdown of passes, failures and skips along with total duration
    showSummary true

    // set to true to see simple class names
    showSimpleNames false

    // set to false to hide passed tests
    showPassed true

    // set to false to hide skipped tests
    showSkipped true

    // set to false to hide failed tests
    showFailed true

    // enable to see standard out and error streams inline with the test results
    showStandardStreams false

    // set to false to hide passed standard out and error streams
    showPassedStandardStreams true

    // set to false to hide skipped standard out and error streams
    showSkippedStandardStreams true

    // set to false to hide failed standard out and error streams
    showFailedStandardStreams true
}

Mam nadzieję, że spodoba ci się korzystanie z niego.

Dodaj to, aby build.gradlezatrzymać gradle od połykania stdout i stderr.

test {
    testLogging.showStandardStreams = true
}

Jest to udokumentowane tutaj .

zadanie „test” nie działa dla wtyczki dla Androida, dla wtyczki dla Androida użyj:

// Test Logging
tasks.withType(Test) {
    testLogging {
        events "started", "passed", "skipped", "failed"
    }
}

Zobacz: https://stackoverflow.com/a/31665341/3521637

Jako kontynuacja wspaniałej odpowiedzi Shubhama chciałbym zasugerować użycie wartości wyliczeniowych zamiast łańcuchów . Proszę spojrzeć na dokumentację klasy TestLogging .

import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

tasks.withType(Test) {
    testLogging {
        events TestLogEvent.FAILED,
               TestLogEvent.PASSED,
               TestLogEvent.SKIPPED,
               TestLogEvent.STANDARD_ERROR,
               TestLogEvent.STANDARD_OUT
        exceptionFormat TestExceptionFormat.FULL
        showCauses true
        showExceptions true
        showStackTraces true
    }
}

Moja ulubiona minimalistyczna wersja oparta na odpowiedzi Shubhama Chaudhary'ego.

Umieść to w build.gradlepliku:

test {
    afterSuite { desc, result ->
    if (!desc.parent)
        println("${result.resultType} " +
            "(${result.testCount} tests, " +
            "${result.successfulTestCount} successes, " +
            "${result.failedTestCount} failures, " +
            "${result.skippedTestCount} skipped)")
    }
}

W Gradle przy użyciu wtyczki do Androida:

gradle.projectsEvaluated {
    tasks.withType(Test) { task ->
        task.afterTest { desc, result ->
            println "Executing test ${desc.name} [${desc.className}] with result: ${result.resultType}"
        }
    }
}

Następnie dane wyjściowe będą:

Wykonywanie testu testConversionMinutes [org.example.app.test.DurationTest] z wynikiem: SUCCESS

Połączenie doskonałej odpowiedzi Shubhama i JJD używają wyliczenia zamiast łańcucha

tasks.withType(Test) {
   testLogging {
       // set options for log level LIFECYCLE
       events TestLogEvent.PASSED,
            TestLogEvent.SKIPPED, TestLogEvent.FAILED, TestLogEvent.STANDARD_OUT
       showExceptions true
       exceptionFormat TestExceptionFormat.FULL
       showCauses true
       showStackTraces true

    // set options for log level DEBUG and INFO
       debug {
        events TestLogEvent.STARTED, TestLogEvent.PASSED, TestLogEvent.SKIPPED, TestLogEvent.FAILED, TestLogEvent.STANDARD_OUT, TestLogEvent.STANDARD_ERROR
        exceptionFormat TestExceptionFormat.FULL
       }
       info.events = debug.events
       info.exceptionFormat = debug.exceptionFormat

       afterSuite { desc, result ->
           if (!desc.parent) { // will match the outermost suite
               def output = "Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)"
               def startItem = '|  ', endItem = '  |'
               def repeatLength = startItem.length() + output.length() + endItem.length()
               println('\n' + ('-' * repeatLength) + '\n' + startItem + output + endItem + '\n' + ('-' * repeatLength))
           }
       }
   }
}

Kontynuując odpowiedź Benjamina Muschko (19 marca 2011 r.), Możesz użyć -iflagi wraz z grep , aby odfiltrować tysiące niechcianych linii. Przykłady:

Silny filtr - wyświetla tylko nazwę i wynik testu każdej jednostki oraz ogólny status kompilacji. Błędy konfiguracji lub wyjątki nie są wyświetlane.

./gradlew test -i | grep -E " > |BUILD"

Filtr miękki - wyświetla nazwę i wynik testu każdej jednostki, a także błędy konfiguracji / wyjątki. Ale będzie również zawierać pewne nieistotne informacje:

./gradlew test -i | grep -E -v "^Executing |^Creating |^Parsing |^Using |^Merging |^Download |^title=Compiling|^AAPT|^future=|^task=|:app:|V/InstrumentationResultParser:"

Filtr miękki, Alternatywna składnia: (tokeny wyszukiwania są podzielone na poszczególne ciągi)

./gradlew test -i | grep -v -e "^Executing " -e "^Creating " -e "^Parsing " -e "^Using " -e "^Merging " -e "^Download " -e "^title=Compiling" -e "^AAPT" -e "^future=" -e "^task=" -e ":app:" -e "V/InstrumentationResultParser:"

Wyjaśnienie, jak to działa: Dane wyjściowe pierwszego polecenia, ./gradlew test -isą przesyłane potokowo do drugiego polecenia grep, które odfiltruje wiele niechcianych wierszy na podstawie wyrażenia regularnego. "-E"włącza tryb wyrażeń regularnych i "|"oznacza „lub”. Nazwa testu jednostkowego i wynik mogą być wyświetlane za pomocą " > ", a ogólny status jest dozwolony za pomocą "BUILD". W filtrze miękkim "-v"flaga oznacza „nie zawiera” i "^"oznacza „początek linii”. Usuwa więc wszystkie wiersze, które zaczynają się od „Wykonanie” lub zaczynają się od „Tworzenie” itp.

Przykład testów jednostkowych przyrządów z systemem Android, z klasą 5.1:

./gradlew connectedDebugAndroidTest --continue -i | grep -v -e \
"^Transforming " -e "^Skipping " -e "^Cache " -e "^Performance " -e "^Creating " -e \
"^Parsing " -e "^file " -e "ddms: " -e ":app:" -e "V/InstrumentationResultParser:"

Przykład pokrycia testowego jednostki Jacoco z klasą 4.10:

./gradlew createDebugCoverageReport --continue -i | grep -E -v "^Executing |^Creating |^Parsing |^Using |^Merging |^Download |^title=Compiling|^AAPT|^future=|^task=|:app:|V/InstrumentationResultParser:"

Jeśli masz build.gradle.ktsnapisane w DSL Kotlin , możesz wydrukować wyniki testu (opracowałem projekt wieloplatformowy Kotlin , bez wtyczki „java”):

tasks.withType<AbstractTestTask> {
    afterSuite(KotlinClosure2({ desc: TestDescriptor, result: TestResult ->
        if (desc.parent == null) { // will match the outermost suite
            println("Results: ${result.resultType} (${result.testCount} tests, ${result.successfulTestCount} successes, ${result.failedTestCount} failures, ${result.skippedTestCount} skipped)")
        }
    }))
}