Jak mogę natychmiast wyjść z Ediff bez konieczności wpisywania „y”

Kiedy rezygnuję z Ediffa q, pytają mnie, czy naprawdę chcę odejść. Wolałbym, żeby natychmiast przestał. Dostosowywanie nie ma nic oczywistego . Jest tutaj rozwiązanie , które wydaje się działać poprzez przedefiniowanie qklucza, ale nie jestem pewien szczegółów działania tej funkcji. Jaki jest najprostszy sposób, aby naprawdę rzucić palenie?

Możesz doradzić, ediff-quitaby dynamicznie ponownie powiązać y-or-n-pz funkcją, która zwraca t.

(defun disable-y-or-n-p (orig-fun &rest args)
  (cl-letf (((symbol-function 'y-or-n-p) (lambda (prompt) t)))
    (apply orig-fun args)))

(advice-add 'ediff-quit :around #'disable-y-or-n-p)

Jest to bardziej odporne na zmiany na wcześniejszym etapie niż redefiniowanie ediff-quit.

Niestety myślę, że musisz albo ponownie powiązać q lub dostosować źródło ediff-quit. Jak widać w źródle ediff-quitpodpowiedzi zawsze się zdarza.

(defun ediff-quit (reverse-default-keep-variants)
  "Finish an Ediff session and exit Ediff.
Unselects the selected difference, if any, restores the read-only and modified
flags of the compared file buffers, kills Ediff buffers for this session
\(but not buffers A, B, C\).

If `ediff-keep-variants' is nil, the user will be asked whether the buffers
containing the variants should be removed \(if they haven't been modified\).
If it is t, they will be preserved unconditionally.  A prefix argument,
temporarily reverses the meaning of this variable."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (let ((ctl-buf (current-buffer))
    (ctl-frm (selected-frame))
    (minibuffer-auto-raise t))
    (if (y-or-n-p (format "Quit this Ediff session%s? "
              (if (ediff-buffer-live-p ediff-meta-buffer)
                  " & show containing session group" "")))
    (progn
      (message "")
      (set-buffer ctl-buf)
      (ediff-really-quit reverse-default-keep-variants))
      (select-frame ctl-frm)
      (raise-frame ctl-frm)
      (message ""))))

Sugerowałbym przedefiniowanie ediff-quitw tobie .emacsi przesłanie łatki do źródła, dodając zmienną dostosowywania.

Pamiętaj, że źródło implementacji w emacsie jest zawsze o kilka kroków. Zakładając, że źródła elisp są zainstalowane, wpisz C-h f, wprowadź nazwę funkcji i kliknij łącze do miejsca jej zdefiniowania.

Używam następującego ponownego wiązania q w Ediff. Jeśli którykolwiek z buforów zostanie zmodyfikowany, zapyta, czy mają zostać zapisane, a następnie po prostu wyjdzie. Jeśli nie zostaną zmodyfikowane żadne bufory, po prostu zostanie zamknięty.

(add-hook 'ediff-startup-hook
          (lambda ()
            (local-set-key (kbd"q") 'my-ediff-quit)))

(defun my-ediff-quit ()
  "If any of the ediff buffers have been modified, ask if changes
should be saved. Then quit ediff normally, without asking for
confirmation"
  (interactive)
  (ediff-barf-if-not-control-buffer)
  (let* ((buf-a ediff-buffer-A)
         (buf-b ediff-buffer-B)
         (buf-c ediff-buffer-C)
         (ctl-buf (current-buffer))
         (modified (remove-if-not 'buffer-modified-p
                                  (list buf-a buf-b buf-c))))
    (let ((save (if modified (yes-or-no-p "Save changes?")nil)))
      (loop for buf in modified do
            (progn
              (set-buffer buf)
              (if save
                  (save-buffer)
                (set-buffer-modified-p nil))))
      (set-buffer ctl-buf)
      (ediff-really-quit nil))))