Ukryj okno * kompilacji *

20

To denerwujące, że okno kompilacji pojawia się, gdy się powiedzie. Jak usunąć to automatycznie?

Chcę to zobaczyć, jeśli się nie powiedzie.

window compilation

— Husain
źródło

11

lata temu na kanale IRC #emacs dostałem ten fragment kodu, którego używam od zawsze. Wartość „2 s” określa czas, przez który okno udanej kompilacji pozostaje widoczne.

; from enberg on #emacs
(setq compilation-finish-function
  (lambda (buf str)
    (if (null (string-match ".*exited abnormally.*" str))
        ;;no errors, make the compilation window go away in a few seconds
        (progn
          (run-at-time
           "2 sec" nil 'delete-windows-on
           (get-buffer-create "*compilation*"))
          (message "No Compilation Errors!")))))

— shapr
źródło

14

Przyglądając się szybko kodowi (w bibliotece compile.el), powinieneś być w stanie po prostu zabić lub ukryć wyświetlany bufor za pomocą funkcji przechwytującej compilation-finish-functions. Aby to zrobić, użyj czegoś takiego:

 (add-hook 'compilation-finish-functions (lambda (buf strg) (kill-buffer buf))

Jeśli nie chcesz zabić bufora, użyj czegoś takiego:

 (add-hook 'compilation-finish-functions
           (lambda (buf strg)
             (let ((win  (get-buffer-window buf 'visible)))
               (when win (delete-window win)))))

Zasadniczo można sobie wyobrazić, że w przypadku czegoś takiego zapewniono już hak, dzięki czemu można łatwo dołączyć kod w tak znaczącym miejscu w przetwarzaniu. Trochę przeglądania kodu lub używania M-x aproposzazwyczaj szybko da ci znać. Nazwy haków zwykle kończą się na -hooklub -functions.

— Rysował
źródło

2

Ten wątek jest również istotny, na wypadek, gdyby ktoś był zainteresowany:

/programming/11043004/emacs-compile-buffer-auto-close

Podziękowania należą się oryginalnemu autorowi jpkotta . Oto jego odpowiedź:

Używam następujących do kompilacji. Przechowuje bufor kompilacji, jeśli występują ostrzeżenia lub błędy, i zakopuje go w inny sposób (po 1 sekundzie).

(defun bury-compile-buffer-if-successful (buffer string)
  "Bury a compilation buffer if succeeded without warnings "
  (if (and
       (string-match "compilation" (buffer-name buffer))
       (string-match "finished" string)
       (not
        (with-current-buffer buffer
          (search-forward "warning" nil t))))
      (run-with-timer 1 nil
                      (lambda (buf)
                        (bury-buffer buf)
                        (switch-to-prev-buffer (get-buffer-window buf) 'kill))
                      buffer)))
(add-hook 'compilation-finish-functions 'bury-compile-buffer-if-successful)

— Swarnendu Biswas
źródło

1

Proszę nie pisać odpowiedź, która składa się tylko z linkiem . Umieść istotne części odpowiedzi w swoim poście, aby Twój post odpowiedział na pytanie. Podaj link jako źródło i dodatkowe informacje. Aby uzyskać więcej informacji, przeczytaj nasze wytyczne dotyczące pisania odpowiedzi .

— Gilles „SO- przestań być zły”

Zaktualizowałem moją odpowiedź.

— Swarnendu Biswas

Pamiętaj, że możesz cytować czyjąś odpowiedź z Stack Exchange , ale musisz podać odpowiednie informacje , w tym nazwisko autora.

— Gilles „SO- przestań być zły”

1

Mam ten fragment w moim .emacs.d:

    (defcustom compilation-auto-quit-window-delay 1
      "Time in seconds before auto closing the window."
      :group 'compilation
      :type 'number)  

    (defun compilation-auto-quit-window-finish-function (buffer status)
      "Quit the *compilation* window if it went well."
      (let ((window (get-buffer-window buffer)))
        (when (and (equal status "finished\n")
                   (compilation-went-super-p))
          (run-with-timer
              (or compilation-auto-quit-window-delay 0) nil
            (lambda nil
              (when (and (window-live-p window)
                         (eq (window-buffer window)
                             buffer)
                         (not (eq (selected-window)
                                  window)))
                (save-selected-window
                  (quit-window nil window))))))))

    (define-minor-mode compilation-auto-quit-window
      "Automatically close the *compilation* window if it went well."
      :global t
      (cond (compilation-auto-quit-window
             (add-hook 'compilation-finish-functions
                       'compilation-auto-quit-window-finish-function))
            (t
             (remove-hook 'compilation-finish-functions
                          'compilation-auto-quit-window-finish-function))))

    (defun compilation-went-super-p (&optional buffer)
      "Return t, if no gotoable output appeared."
      (with-current-buffer (or buffer (current-buffer))
        (save-excursion
          (goto-char (point-min))
          (let (;; (compilation-skip-threshold 1)
                )
            (not (ignore-errors
                   (compilation-next-error 1)
                   t))))))

— politza
źródło