Czy można dodać szablony inne niż # + BEGIN_ # + END_ do org-structure-template-alist?

Zauważyłem, że zmieniono org-structure-template-alist (używam trybu org w wersji 9.2), aby automatycznie rozwinąć #+BEGIN_<some block tag> #+END_<some block tag>. Zastanawiam się, czy można dodać różnego rodzaju szablony. Na przykład :PROPERTIES:<some properties>:END:szablon.

Czy to możliwe, czy powinienem przejść do innego pakietu, takiego jak yasnippets?

AKTUALIZACJA:

Nie zauważyłem, że Org Mode 9.2 zmienił mechanizm rozszerzania szablonów, gdzie org-structure-template-alistdotyczy tylko bloków zdefiniowanych przez "#+BEGIN_"i "#+END_". I wejście jak ("p" ":PROPERTIES:?:END:")nie jest już akceptowane.

Jak wspomniano w powyższym linku, inny „złożony” szablon może być zdefiniowany przez funkcję tempo-define-templatei należy załadować org-tempo ( (require 'org-tempo)). W rzeczywistości wpisy org-structure-template-alist są konwertowane na org-tempo-tagsvia tempo-define-templateprzez org-tempoi org-tempo-tagsdomyślnie są to:

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

W twoim przypadku możesz zdefiniować szablon poprzez:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

Poniższa odpowiedź działa tylko dla wersji trybu Org wcześniejszej niż 9.2

Tak, możesz dodać do niego wpis w następujący sposób:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Następnie w pliku org wpisujesz <pi TAB, rozwinie się ono do właściwości i pozostawi punkt na pozycji ?.

Więcej szczegółów znajdziesz w dokumentacji zmiennej, pisząc C-h v org-structure-template-alist RET.

Szkoda, jak często wprowadzają niekompatybilne zmiany w dostosowywaniu trybu org.

Poniższy kod przedstawia stare szablony struktur trybu org przed wersją 9.2 wstecz. Ta funkcja org-complete-expand-structure-templatejest czystą kopią z wersji 9.1 i org-try-structure-completionjest nieco zmodyfikowaną wersją tej z wersji 9.1. (Dodałem tam kontrolę typu).

Po zainstalowaniu tego kodu możesz
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
ponownie użyć starego szablonu .

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))