Jak wyrównać do prawej region i / lub linię?

Możemy wyśrodkować tekst za pomocą M-x center-regioni M-o M-s. Czy istnieje coś podobnego do wyrównania do prawej?

Przykład przed:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

po:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

Jaki jest najłatwiejszy sposób wyrównania tekstu do prawej?

Zgodnie z ręcznym węzłem wypełniania kilka funkcji wypełniania przyjmuje opcjonalny argument JUSTIFY, którego można użyć. Na przykład, aby wypełnić akapit z odpowiednim uzasadnieniem, możesz użyć (fill-paragraph 'right).

Możesz także użyć (justify-current-line 'right)dla pojedynczej linii.

Jeśli planujesz dużo korzystać z tych opcji, możesz zawinąć je w funkcje, takie jak poniższe, a następnie powiązać te funkcje z wybranymi klawiszami:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

Oto funkcja, którą możesz zastąpić fill-paragraph. Dzięki różnym prefiksom pozwala zdecydować, jakiego rodzaju uzasadnienia użyć w wypełnianym akapicie:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

Jeśli nie chcesz wypełniać, gdy wyrównujesz do prawej, możesz użyć następującej funkcji, która jest kopiowana bezpośrednio z center-regionfunkcji za pomocą zmiany w jednej linii, aby zamiast tego wyrównać do prawej:

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))