Sposób na ukrycie ograniczników bloku SRC

13

czy istnieje sposób na zachowanie tylko kodu źródłowego w kodzie źródłowym, dzięki czemu # + BEGIN_SRC i # + END_SRC są niewidoczne? Jest kosmetyczny, ale sprawia, że wszystko staje się wyraźniejsze, gdy mamy do czynienia z wieloma krótkimi fragmentami kodu. Na przykład:

(defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))

zamiast :

  #+BEGIN_SRC emacs-lisp
       (defun org-xor (a b)
          "Exclusive or."
          (if a (not b) b))
  #+END_SRC

org-mode

— Loukios
źródło

Mój komentarz pod pytaniem w tym częściowo powiązanym wątku pokazuje, jak programowo ukryć nagłówki / stopki bloków źródłowych. emacs.stackexchange.com/q/26163/2287 - tzn.

(save-excursion (goto-char (point-max)) (while (re-search-backward "#\\+BEGIN_SRC\\|#\\+END_SRC" nil t) (let ((ov (make-overlay (line-beginning-position) (1+ (line-end-position))))) (overlay-put ov 'invisible t))))

Aby odkryć wszystko, użyj (remove-overlays). Konieczne są dalsze prace nad poszczególnymi wpisami i usunięcie tylko wybranych nakładek (zamiast wszystkich nakładek), ale to jest ogólny pomysł.

— lawlist

Dzięki, to interesujące ... Będę się z tym bawić.

— loukios 30.09.16

5

#+Nazywa się twarz dla wszystkich linii zaczynających się od org-meta-line.

Możesz dostosować tę twarz, aby była mniejsza, ciemniejsza itp., Aby była mniej widoczna.

— Juancho
źródło

W rzeczy samej. Jako przykład mam to skonfigurować za pomocą (set-face-attribute 'org-meta-line nil :height 0.8 :slant 'normal). Uważam, że to trochę pomaga.

— Harald Hanche-Olsen

Dzięki za odpowiedź, to pomaga. Zmieniłem wysokość btw, ale to nie ma żadnego efektu ...

— loukios 30.09.16

Zobacz dokumentację Emacs Lisp na temat opcji, które możesz przypisać do org-meta-line gnu.org/software/emacs/manual/html_node/elisp/…

— salotz

4

Używam następującego fragmentu kodu, który idzie w pewien sposób. To nie jest idealne. Może minor-modektóregoś dnia stanie się to właściwe . ( źródło ).

(with-eval-after-load 'org
  (defvar-local rasmus/org-at-src-begin -1
    "Variable that holds whether last position was a ")

  (defvar rasmus/ob-header-symbol ?☰
    "Symbol used for babel headers")

  (defun rasmus/org-prettify-src--update ()
    (let ((case-fold-search t)
          (re "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*")
          found)
      (save-excursion
        (goto-char (point-min))
        (while (re-search-forward re nil t)
          (goto-char (match-end 0))
          (let ((args (org-trim
                       (buffer-substring-no-properties (point)
                                                       (line-end-position)))))
            (when (org-string-nw-p args)
              (let ((new-cell (cons args rasmus/ob-header-symbol)))
                (cl-pushnew new-cell prettify-symbols-alist :test #'equal)
                (cl-pushnew new-cell found :test #'equal)))))
        (setq prettify-symbols-alist
              (cl-set-difference prettify-symbols-alist
                                 (cl-set-difference
                                  (cl-remove-if-not
                                   (lambda (elm)
                                     (eq (cdr elm) rasmus/ob-header-symbol))
                                   prettify-symbols-alist)
                                  found :test #'equal)))
        ;; Clean up old font-lock-keywords.
        (font-lock-remove-keywords nil prettify-symbols--keywords)
        (setq prettify-symbols--keywords (prettify-symbols--make-keywords))
        (font-lock-add-keywords nil prettify-symbols--keywords)
        (while (re-search-forward re nil t)
          (font-lock-flush (line-beginning-position) (line-end-position))))))

  (defun rasmus/org-prettify-src ()
    "Hide src options via `prettify-symbols-mode'.

  `prettify-symbols-mode' is used because it has uncollpasing. It's
  may not be efficient."
    (let* ((case-fold-search t)
           (at-src-block (save-excursion
                           (beginning-of-line)
                           (looking-at "^[ \t]*#\\+begin_src[ \t]+[^ \f\t\n\r\v]+[ \t]*"))))
      ;; Test if we moved out of a block.
      (when (or (and rasmus/org-at-src-begin
                     (not at-src-block))
                ;; File was just opened.
                (eq rasmus/org-at-src-begin -1))
        (rasmus/org-prettify-src--update))
      ;; Remove composition if at line; doesn't work properly.
      ;; (when at-src-block
      ;;   (with-silent-modifications
      ;;     (remove-text-properties (match-end 0)
      ;;                             (1+ (line-end-position))
      ;;                             '(composition))))
      (setq rasmus/org-at-src-begin at-src-block)))

  (defun rasmus/org-prettify-symbols ()
    (mapc (apply-partially 'add-to-list 'prettify-symbols-alist)
          (cl-reduce 'append
                     (mapcar (lambda (x) (list x (cons (upcase (car x)) (cdr x))))
                             `(("#+begin_src" . ?✎) ;; ➤ 🖝 ➟ ➤ ✎
                               ("#+end_src"   . ?□) ;; ⏹
                               ("#+header:" . ,rasmus/ob-header-symbol)
                               ("#+begin_quote" . ?»)
                               ("#+end_quote" . ?«)))))
    (turn-on-prettify-symbols-mode)
    (add-hook 'post-command-hook 'rasmus/org-prettify-src t t))
  (add-hook 'org-mode-hook #'rasmus/org-prettify-symbols))

— rasmus
źródło