Wyszukiwanie zapytania i komentowanie linii?

Mam nadzieję dowiedzieć się, jak przeprowadzić wyszukiwanie zapytania, które skomentuje wiersz zamiast zamiany zapytania. To znaczy, wykonaj interaktywne wyszukiwanie zapytań, a jeśli powiem tak, skomentuj wiersz, w którym jest dopasowanie.

Czy to polecenie istnieje? Jeśli nie, jak bym to napisał? Jestem nowy w elisp i nie wiem, jak zaprogramować własne funkcje.

(defun my-comment-matching-line ()
  (interactive "*")
  (call-interactively 'search-forward)
  (beginning-of-line)
  ;; don't comment the region maybe
  (push-mark)
  (comment-line 1))

Jeżeli linia komentarza nie będzie dostępna, tutaj z najnowszego komentarza. El:

(defun comment-line (n)
  "Comment or uncomment current line and leave point after it.
With positive prefix, apply to N lines including current one.
With negative prefix, apply to -N lines above.  Also, further
consecutive invocations of this command will inherit the negative
argument.

If region is active, comment lines in active region instead.
Unlike `comment-dwim', this always comments whole lines."
  (interactive "p")
  (if (use-region-p)
      (comment-or-uncomment-region
       (save-excursion
         (goto-char (region-beginning))
         (line-beginning-position))
       (save-excursion
         (goto-char (region-end))
         (line-end-position)))
    (when (and (eq last-command 'comment-line-backward)
               (natnump n))
      (setq n (- n)))
    (let ((range
           (list (line-beginning-position)
                 (goto-char (line-end-position n)))))
      (comment-or-uncomment-region
       (apply #'min range)
       (apply #'max range)))
    (forward-line 1)
    (back-to-indentation)
    (unless (natnump n) (setq this-command 'comment-line-backward))))