make `previous-buffer` i` next-buffer`, aby zignorować niektóre bufory

10

w Hełmie ignoruję niektóre bufory przed wyświetlaniem podczas używania C-x b, szukam sposobu na wykonanie poleceń previous-bufferi next-bufferzachowuję się tak samo, ignorując niektóre bufory.

buffers

— shackra
źródło

8

Oto dwa sposoby:

Jeśli spojrzysz na definicję funkcji switch-to-next-buffer(w bibliotece window.el), zobaczysz, że filtruje ona bufory według predykatu (jeśli istnieje), który jest wartością parametru frame buffer-predicate. Z tej funkcji korzysta next-buffer.

Możesz ustawić ten parametr ramki na predykat, który filtruje tak, jak chcesz.
Możesz po prostu poradzić funkcji, switch-to-next-bufferaby filtrowała tak, jak chcesz. Zasadniczo zastąpisz jego definicję prawie taką samą definicją, ale dodatkowo filtrujesz tak, jak chcesz.

Podobnie dla switch-to-previous-buffer.

— Rysował
źródło

7

(defvar my-skippable-buffers '("*Messages*" "*scratch*" "*Help*")
  "Buffer names ignored by `my-next-buffer' and `my-previous-buffer'.")

(defun my-change-buffer (change-buffer)
  "Call CHANGE-BUFFER until current buffer is not in `my-skippable-buffers'."
  (let ((initial (current-buffer)))
    (funcall change-buffer)
    (let ((first-change (current-buffer)))
      (catch 'loop
        (while (member (buffer-name) my-skippable-buffers)
          (funcall change-buffer)
          (when (eq (current-buffer) first-change)
            (switch-to-buffer initial)
            (throw 'loop t)))))))

(defun my-next-buffer ()
  "Variant of `next-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'next-buffer))

(defun my-previous-buffer ()
  "Variant of `previous-buffer' that skips `my-skippable-buffers'."
  (interactive)
  (my-change-buffer 'previous-buffer))

(global-set-key [remap next-buffer] 'my-next-buffer)
(global-set-key [remap previous-buffer] 'my-previous-buffer)

— phils
źródło