Emacs zawiodła rada

Chciałbym tymczasowo zastąpić funkcję w kodzie.

Weźmy na przykład:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

Co nie działa:

• To. Byłoby o wiele czystsze, gdybym mógł uniknąć ręcznego włączania i wyłączania porad i ufać jednowątkowej naturze Emacsa, aby zajął się wszystkim.
• cl-letfnie pozwala mi odwoływać się do funkcji oryginalnej, więc nie mogę zaimplementować rzeczy, :filter-argsktóre normalnie by to zrobiły.
• cl-flet nie można zastąpić funkcji w innych funkcjach.
• nofletto pakiet zewnętrzny, którego chciałbym uniknąć. (Robi też o wiele więcej niż potrzebuję)

Nie możesz użyć, (cl-)letfgdy sam odwołujesz się do oryginalnej funkcji?

Coś takiego:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)

Możesz również zawinąć to w makro, jeśli planujesz go ponownie użyć:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

Powyższy przykład można następnie przepisać w następujący sposób:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")