podkreśl bieżący błąd w oknie * kompilacji *

Po uruchomieniu polecenia kompilacji i przejściu do „następnego błędu” emacs rozpoznaje linię bieżącego błędu, umieszczając mały czarny trójkąt skierowany w prawo w lewym skraju bufora * kompilacji * . To miłe, ale moje stare oczy chciałyby odważniejszego wskaźnika. Podstawowym celem jest tutaj możliwość szybkiego wizualnego zidentyfikowania, który emacs linii identyfikuje jako aktualny błąd kompilatora. Niektóre rozwiązania, które przychodzą na myśl:

1. inna twarz dla obecnego błędu (na przykład większa).
2. inny kolor tła dla bieżącego błędu (coś w stylu trybu linii-hl).
3. większy trójkąt.

ale jestem też otwarty na inne pomysły.

Czy ktoś może mi pomóc?

Chciałem osiągnąć to samo, ponieważ często bolesne było znalezienie bieżącego komunikatu o błędzie w buforze kompilacji. To rozwiązanie jest oparte na sugestii Drew, aby użyć a next-error-hookdo podświetlenia komunikatu o błędzie. Obecnie podświetla tylko pierwszą linię w komunikacie o błędzie, ale uważam, że to wystarczy.

(defcustom next-error-message-highlight-p nil
  "If non-nil, highlight the current error message in the ‘next-error’ buffer"
  :type 'boolean
  :group 'next-error
  :version "??")

(defface next-error-message
  '((t (:inherit highlight)))
  "Face used to highlight the current error message in the ‘next-error’ buffer"
  :group 'next-error
  :version "??")

(defvar next-error-message-highlight-overlay
  nil
  "Overlay highlighting the current error message in the ‘next-error’ buffer")

(make-variable-buffer-local 'next-error-message-highlight-overlay)

(defun next-error-message-highlight ()
  "Highlight the current error message in the ‘next-error’ buffer."
  (when next-error-message-highlight-p
    (with-current-buffer next-error-last-buffer
      (when next-error-message-highlight-overlay
        (delete-overlay next-error-message-highlight-overlay))
      (save-excursion
        (goto-char (point))
        (let ((ol (make-overlay (line-beginning-position) (line-end-position))))
          ;; do not override region highlighting
          (overlay-put ol 'priority -50)
          (overlay-put ol 'face 'next-error-message)
          (overlay-put ol 'window (get-buffer-window))
          (setf next-error-message-highlight-overlay ol))))))

(add-hook 'next-error-hook 'next-error-message-highlight)

Stosowanie:

(setq next-error-message-highlight-p t)

Próbny:

Oto przykład, jak zmodyfikować obraz bitmapy, który pojawia się w lewej części *compilation*bufora (np. *grep*Bufor wyników):

(define-fringe-bitmap 'custom-right-arrow [128 192 96 48 24 48 96 192 128] 9 8 'center)

(put 'overlay-arrow-position 'overlay-arrow-bitmap 'custom-right-arrow)

Oto przykład ustawiania kolorów prążkowych bitmap:

(defface right-triangle-face
  '((t (:background "red" :foreground "yellow")))
  "Face for `right-triangle-face`.")

(set-fringe-bitmap-face 'right-triangle 'right-triangle-face)

Oto przykład, jak utworzyć własną bitmapę z marginesami:

;; AUTHOR:  Nikolaj Schumacher -- https://github.com/nschum/fringe-helper.el
;;
(defun fringe-helper-convert (&rest strings)
"Convert STRINGS into a vector usable for `define-fringe-bitmap'.
Each string in STRINGS represents a line of the fringe bitmap.
Periods (.) are background-colored pixel; Xs are foreground-colored. The
fringe bitmap always is aligned to the right. If the fringe has half
width, only the left 4 pixels of an 8 pixel bitmap will be shown.
For example, the following code defines a diagonal line.
\(fringe-helper-convert
\"XX......\"
\"..XX....\"
\"....XX..\"
\"......XX\"\)"
  (unless (cdr strings)
  ;; only one string, probably with newlines
    (setq strings (split-string (car strings) "\n")))
  (apply 'vector
    (mapcar
      (lambda (str)
        (let ((num 0))
          (dolist (c (string-to-list str))
            (setq num (+ (* num 2) (if (eq c ?.) 0 1))))
          num))
      strings)))

(define-fringe-bitmap 'backslash (fringe-helper-convert
  "XX......"
  "XX......"
  " XX....."
  ".XX....."
  "..XX...."
  "..XX...."
  "...XX..."
  "...XX..."
  "....XX.."
  "....XX.."
  ".....XX."
  ".....XX.") nil nil 'center)

Nie next-errorprzewija bufora błędów kompilacji, więc bieżący błąd jest wyświetlany jako pierwszy wiersz okna?

Jeśli nie, to czy przynajmniej nie umieszcza kursora w bieżącym wierszu błędu? Jeśli tak, a kursor nie jest dla Ciebie wystarczająco widoczny, rozważ użycie przycisku hl-line-modedo podświetlenia bieżącej linii. Lub rozważ użycie biblioteki crosshairsdo podświetlenia bieżącej linii i bieżącej kolumny.

Zaktualizuj po swoim komentarzu

Myślałem, że inwokujesz next-errorw buforze *compilation*. Jeśli to zrobisz, linia zostanie przewinięta do góry, jak opisałem.

Ale jeśli powołując się next-errorna zewnątrz bufor *compilation*następnie trzeba użyć next-error-hook, aby, w buforze*compilation* , podświetlenie aktualnej linii lub frędzli lub cokolwiek, w jakikolwiek sposób chcesz.

Oto szybki i brudny przykład:

(defun foo ()
  "..."
  (with-current-buffer next-error-last-buffer
    (hl-line-mode 1)))

(add-hook 'next-error-hook 'foo)

(Oczywiście, tak naprawdę wystarczy włączyć hl-line-moderaz w tym buforze. Robi to w sposób pokazany powyżej jest przesadą, ale to nie boli. Można by pomyśleć, że można po prostu dodać foodo grep-mode-hooklub compilation-mode-hook. Ale kiedy te haki są wywoływane jest nie next-error-last-buffer.)

Uwaga:

1. Istnieją dwie opcje użytkownika, które kontrolują sposoby wskazywania trafienia w buforze źródłowym (nie w buforze kompilacji): next-error-highlighti next-error-highlight-no-select. Oferują te same możliwości, ale są używane przez różne polecenia. Możliwości obejmują użycie strzałki frędzlowej lub podświetlanie meczu na określony czas.

2. Ale nie ma takiej opcji kontrolującej wskazanie bieżącego trafienia w buforze *compilation*. Dlatego Emacs oferuje dwie opcje (gdzie prawdopodobnie wystarczyłaby) dla bufora źródłowego, ale nie ma opcji dla bufora kompilacji.

Można rozważyć złożenie wniosku powiększenia, aby uzyskać podobną opcję kompilacji (w tym grep) Bufor: M-x report-emacs-bug. Użycie haka z własną funkcją do wykonania podświetlenia jest w porządku, ale nie powinno być konieczne.

A jeśli chcesz tylko zmienić wskaźnik grzywki, możesz to zrobić (użyj dowolnej bitmapy z frędzlami, a nie filled-rectangle- patrz (elisp) Bitmapy z grzywką, aby uzyskać listę predefiniowanych):

(defun bar ()
  (with-current-buffer next-error-last-buffer
    (unless (eq 'filled-rectangle (cdr (assq 'overlay-arrow fringe-indicator-alist)))
      (setq fringe-indicator-alist
            (cons '(overlay-arrow . filled-rectangle) fringe-indicator-alist)))))

(add-hook 'next-error-hook 'bar)

Aktualizacja nr 2:

Właśnie odkryłem, że jeśli wyłączysz wyświetlanie lewej grzywki, zobaczysz zachowanie, które opisałem na początku: okno jest przewijane, aby umieścić bieżący błąd na górze. To kolejna możliwość. (Jest to zachowanie, które widzę w mojej konfiguracji, ponieważ nie pokazuję grzywki.)

W tym zachowaniu jest błąd, który właśnie zgłosiłem ( # 20829 ). Liczy się (obecnie, dopóki błąd nie zostanie naprawiony) to, czy lewy margines pojawia się w wybranym oknie, kiedy to robisz C-x `( next-error). (Obecnie) nie wystarczy, że okno pokazujące bufor kompilacji nie pokazuje lewej krawędzi.