Jak transponować dwa argumenty funkcji w Pythonie?

Jak mogę zamienić dwa argumenty w wywołaniu funkcji Python?

Jeśli wstawię pointspację między tymi dwoma argumentami:

self.assertEqual(json.loads(some.data), json_data)

a następnie M-t( transpose-words) otrzymuję:

self.assertEqual(json.loads(some.json), data_data)

Z drugiej strony dzięki CMt ( transpose-sexps) otrzymuję:

self.assertEqual(json.loadsjson_data, (some.data))

Chcę to:

self.assertEqual(json_data, json.loads(some.data))

Czy istnieje polecenie, które to zrobi?

To też chciałem mieć od dłuższego czasu, a tutaj znalazłem motywację do pracy nad tym. Prawdopodobnie nie jest zbyt solidny, ale przy pierwszej próbie wydaje się, że obejmuje przypadki, które próbowałem:

(defun my/calculate-stops ()
  (save-excursion
    (let ((start
           (condition-case e
               (while t (backward-sexp))
             (error (point))))
          stops)
      (push start stops)
      (condition-case e
          (while t
            (forward-sexp)
            (when (looking-at "\\s-*,")
              (push (point) stops)))
        (error (push (point) stops)))
      (nreverse stops))))

(defun my/transpose-args ()
  (interactive)
  (when (looking-at "\\s-") (backward-sexp))
  (cl-loop with p = (point)
           with previous = nil
           for stop on (my/calculate-stops)
           for i upfrom 0
           when (<= p (car stop)) do
           (when previous
             (let* ((end (cadr stop))
                    (whole (buffer-substring previous end))
                    middle last)
               (delete-region previous end)
               (goto-char previous)
               (setf middle (if (> i 1) (- (car stop) previous)
                              (string-match "[^, \\t]" whole 
                                            (- (car stop) previous)))
                     last (if (> i 1) (substring whole 0 middle)
                            (concat (substring whole (- (car stop) previous) middle)
                                    (substring whole 0 (- (car stop) previous)))))
               (insert (substring whole middle) last)))
           (cl-return)
           end do (setf previous (car stop))))

Używam odmiany transpose-sexpstego wyglądu opisanego przypadku i transponuje rzeczy oddzielone przecinkami lub po prostu regularnie transpose-sexps. Pozostawia również kursor w miejscu zamiast przeciągania go do przodu, co jest nieco inne, ale ja osobiście lubię.

(defun my-transpose-sexps ()
  "If point is after certain chars transpose chunks around that.
Otherwise transpose sexps."
  (interactive "*")
  (if (not (looking-back "[,]\\s-*" (point-at-bol)))
      (progn (transpose-sexps 1) (forward-sexp -1))
    (let ((beg (point)) end rhs lhs)
      (while (and (not (eobp))
                  (not (looking-at "\\s-*\\([,]\\|\\s)\\)")))
        (forward-sexp 1))
      (setq rhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (re-search-backward "[,]\\s-*" nil t)
      (setq beg (point))
      (while (and (not (bobp))
                  (not (looking-back "\\([,]\\|\\s(\\)\\s-*" (point-at-bol))))
        (forward-sexp -1))
      (setq lhs (buffer-substring beg (point)))
      (delete-region beg (point))
      (insert rhs)
      (re-search-forward "[,]\\s-*" nil t)
      (save-excursion
        (insert lhs)))))

W trybach, które używają SMIE, transpose-sexppowinny działać poprawnie w tym przypadku. Nadal nie powiedzie się, gdy symbol infix (aka „separator”) nie jest a ,(lub a ;), ale jest słowem (np and.).

Moim zdaniem jest to polecenie, transpose-sexpa gdy to nie działa poprawnie, uważam to za błąd (ale błąd, który może być trudny i / lub wymaga czasu, aby go naprawić i mieć niski priorytet, więc nie wstrzymaj oddech). Aby to naprawić, należy ustawić forward-sexp-functionfunkcję, która będzie wiedziała, że ​​„po zobaczeniu przecinka po prostu przeskakuję cały argument”.