Głęboko skopiować ciąg znaków w Elisp?

Mam ciąg znaków. Chcę zrobić jego głęboką kopię, aby dodać więcej właściwości, zachowując właściwości w oryginalnym ciągu. Jak mogę to zrobić (łatwo)?

Przykład

Oceniaj jeden po drugim:

(setq test-str-1
      #(";; This `is' a test"
        0 3 (fontified nil face font-lock-comment-delimiter-face)
        3 9 (fontified nil face font-lock-comment-face)
        9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face))
        11 19 (fontified nil face font-lock-comment-face)))
(setq test-str-2 (concat test-str-1))
(add-face-text-property 0 (length test-str-2) 'foobar t test-str-2)

A wynik:

test-str-2
;; =>
#(";; This `is' a test" 0 3 (fontified nil face (font-lock-comment-delimiter-face foobar))
  3 9 (fontified nil face (font-lock-comment-face foobar))
  9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face foobar))
  11 19 (fontified nil face (font-lock-comment-face foobar)))
test-str-1
;; =>
#(";; This `is' a test" 0 3 (face font-lock-comment-delimiter-face fontified nil)
  3 9 (face font-lock-comment-face fontified nil)
  9 11 (face (font-lock-constant-face font-lock-comment-face foobar) ; <= foobar is here
        fontified nil)
  11 19 (face font-lock-comment-face fontified nil))

Możesz użyć tej funkcji, font-lock-append-text-propertyaby dodać właściwość text. Nie zmienia destrukcyjnie wartości.

Na przykład:

(setq test-str-1
      #(";; This `is' a test"
        0 3 (fontified nil face font-lock-comment-delimiter-face)
        3 9 (fontified nil face font-lock-comment-face)
        9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face))
        11 19 (fontified nil face font-lock-comment-face)))
(setq test-str-2 (concat test-str-1))
(font-lock-append-text-property 0 (length test-str-2) 'face '(foobar t) test-str-2)


test-str-1
#(";; This `is' a test"
  0 3 (face font-lock-comment-delimiter-face fontified nil)
  3 9 (face font-lock-comment-face fontified nil)
  9 11 (face (font-lock-constant-face font-lock-comment-face) fontified nil)
  11 19 (face font-lock-comment-face fontified nil))

test-str-2
#(";; This `is' a test"
  0 3 (fontified nil face (font-lock-comment-delimiter-face foobar t))
  3 9 (fontified nil face (font-lock-comment-face foobar t))
  9 11 (fontified nil face (font-lock-constant-face font-lock-comment-face foobar t))
  11 19 (fontified nil face (font-lock-comment-face foobar t)))

Tutaj test-str-1zachował swoją pierwotną wartość.

Odkryłem, że możesz to zrobić, iterując właściwości tekstu, kopiując dane właściwości podstawowej i zastępując istniejące właściwości nowymi kopiami.

(defun deep-copy-text-properties (str)
  (with-temp-buffer
    (insert str)
    (goto-char 1)
    (while (not (eobp))
      (set-text-properties (point)
                           (goto-char (next-char-property-change (point) (point-max)))
                           ;; copy-tree is the important part
                           (copy-tree (text-properties-at (1- (point))))))
    (buffer-string)))

W moich testach było to około 20% szybciej niż twoje readrozwiązanie. Napisałem również wersję, która nie używała bufora tymczasowego i zmodyfikowałem właściwości łańcucha, który był mniejszy, ale wolniejszy.

Patrząc na kod C, kopiuje listy właściwości, z copy_sequence, która przebuduje strukturę listy, ale nie kopiuje elementów według wartości, więc właściwości takie jak face w twoim przykładzie, które mają wartość listy, są kopiowane przez odniesienie i modyfikowane. Błąd czy nie, nie wiem

Możesz użyć (concat the-original-string).

Na przykład:

(let ((s "TEXT"))
  (set-text-properties 2 3 '(:foreground "blue") s)
  (let ((q (concat s)))
    (add-text-properties 2 3 '(:background "red") q)
    (cons s q)))
;; Returns:
(#("TEXT" 2 3 (:foreground "blue")) . #("TEXT" 2 3 (:foreground "blue" :background "red")))

Znaleziono obejście (niezbyt wydajne):

(setq test-str-2
      (read (prin1-to-string test-str-1)))