Przejdź do X bajtów stąd

Jak mogę przenieść bajty X do przodu, zaczynając od bieżącej lokalizacji kursora (łącznie z podziałami linii)?

[count]gomoże być użyty do przesunięcia X bajtów do przodu od początku bufora. Próbowałem Shift + V, G, [count]go(zakładając, [count]goże zacznie się odliczanie od początku mojego wyboru), ale niestety to też nie zadziałało, ponieważ gozaczyna się odliczanie od początku bufora.

Próbowałem również :set rulerformat=%owyświetlić bieżące przesunięcie bajtu (jak sugeruje Przeskok do przesunięcia bajtu i wyświetlanie pozycji jako przesunięcie bajtu ), dodałem liczby w mojej głowie i ostatecznie wydałem [count]go. To działa, ale nie jest zbyt praktyczne ...

To wyszukiwanie przesuwa 40 znaków (ale nie bajtów) do przodu:

/\_.\{40}/e

wyszukując dokładnie 40 znaków \{40}dowolnego rodzaju (w tym newline ( \_.) i umieszczając kursor na końcu wyszukiwania ( /e). Zobacz: http://vimregex.com/#Non-Greedy , :help search-offseti:help \_

Zobacz także :h 23.4edycję binarną.

Aktualizacja: Na podstawie tej odpowiedzi, oto funkcja, która przeskakuje do przesunięcia bajtu:

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

Można użyć w następujący sposób:

:JumpToOffset 400

lub wpisując mapowane mapowanie klawiatury z liczbą:

40CTRL-C

Jeśli nie użyjesz licznika, poprzedni numer zostanie ponownie użyty. Więc możesz zrobić: 40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-Cprzeskoczyć 40, 40, 40, 30, 30 bajtów itp.

Naciśnij, Ctrl-Oaby przeskoczyć do tyłu (patrz komentarze wewnątrz funkcji).

Skończyło się na użyciu następującego rozwiązania, które implementuje logikę z mojego pytania.

• [count]GOaby przenieść [count]bajty do przodu.
• [count]Goaby przenieść [count]bajty do tyłu.

Dodaj to do .vimrc:

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

Dzięki VanLaser za jego początkową implementację, która skierowała mnie we właściwym kierunku.