Czy można używać dwóch różnych kolorów tła w jednym buforze vim?

Szukam możliwego rozwiązania dla zastosowania dwóch różnych kolorów tła w jednym buforze vim, w zależności od kontekstu, jak w tym wzniosłym przykładzie tekstu .

Jednym z takich przypadków jest odmienne kodowanie fragmentów kodu w plikach znaczników, aby wyróżniały się bardziej.

Jednak nigdy nie widziałem takiego przykładu z taką konfiguracją.

Czy to w ogóle możliwe w vimie?

Ponieważ byłem ciekawy, jak dobrze by to zadziałało, zhakowałem coś razem tego rodzaju prace.

Jak wspomniano w komentarzach do wcześniejszej odpowiedzi, jedynym sposobem na to jest wypełnienie regionów spacjami; co dokładnie robimy; przed napisaniem usuwamy te spacje, więc nie powinieneś przeszkadzać innym.

Pamiętaj, że ten przykład jest bardzo specyficzny dla typu pliku przeceny!

Efekty uboczne :

• Kopiowanie tekstu spowoduje również skopiowanie dużej ilości spacji
• Używanie $i Endnie działa już zgodnie z oczekiwaniami (przechodzi do kolumny 80), a klucze takie jak ji kzachowują się inaczej.
• Tło nie jest wyświetlane, gdy 'list'jest włączone
• Całkowicie puste linie nie działają, musisz ręcznie dodać tabulator lub 4 spacje
• ... może więcej?

Najpierw musisz dodać to do ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Oczywiście możesz dostosować kolory do swoich upodobań ;-)

Następnie dodaj to do swojego vimrc:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Nie zamierzam wyjaśniać kodu wiersz po wierszu, komentarze powinny wyjaśnić ogólną treść ;-)

Z pewnością możliwe jest użycie innego koloru tła dla elementów wyróżnionych składnią. Wystarczy zdefiniować guibgi ctermbgkolory w swoim hilightpoleceniu. Pierwszy z nich ustawia kolor tła dla GUI Vima, a drugi dla terminala Vima.

Ma to jednak istotne ograniczenie, ponieważ może ustawić kolory tła tylko dla znaków, które faktycznie istnieją w pliku.

Powoduje to, że kolor tła nie może rozciągać się poza koniec tekstu w linii do krawędzi okna, więc kolorowanie bloków kodu pokazanych w twoim przykładzie nie jest możliwe:

Możesz także zmienić kolor tła całych linii za pomocą funkcji Znak. (Patrz linehlw :help sign.txt)

Należy jednak pamiętać, że:

1. Wymaga to napisania kodu do umieszczenia znaków w każdym wierszu, który musi być pokolorowany, i aktualizowania ich wraz ze zmianą zawartości pliku,

2. Domyślnie podczas umieszczania znaku kolumna znaku będzie wyświetlana po lewej stronie okna. Można zmienić kolorystykę kolumny znaku za pomocą SignColumngrupy wyróżnień, aw nowszych wersjach Vima można ją całkowicie usunąć. (Patrz :help 'signcolumn'.)

Na przykład, aby dostosować rozwiązanie Carpetsmoker do korzystania z (bardziej niezawodnego) mechanizmu znakowania , możesz wykonać następujące czynności:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Upraszcza to nieco kod i ma mniej zastrzeżeń niż wersja Carpetsmokera.

@ChristianBrabandt „s DynamicSigns plugin sprawia, że korzystanie z funkcji znak dla tego celu łatwiejszego: on opisuje, jak go używać, aby zrobić w tej odpowiedzi .