Dodaj etykiety wartości osi Y do wykresu słupkowego gnuplot

Odnoszę się do tego przykładu, aby narysować wykres słupkowy. Podoba mi się dokładna wartość wyświetlana na każdym z czerwonych pasków.

Na przykład te wartości liczbowe, które są zakreślone na zielono,

Mój kod gnuplot to

set size 1, 1
set term png size 600, 400
set title "sk plot"
set output "figure.png"
set boxwidth 0.75
set style fill solid
set title "Population of Australian cities (millions), as of June 2012"
plot "population.dat"  using 2:xtic(1) with boxes

Population.dat zawiera,

Adelaide    1.277174
Brisbane    2.189878
Canberra    0.374658
Darwin      0.131678
Hobart      0.216959
Melbourne   4.246345
Sydney      4.667283

gnuplot

— Madhavan
źródło

Możesz to zrobić, dodając drugi wykres tych samych danych (pokazany jako nazwa pliku ""), używając with labelsdo dodania tekstu o podanej współrzędnej x, y obliczonej z kolumny 0, tj. Tylko indeksu danych, i kolumny 2 z przesunięciem więc tekst siedzi nad polem, ($2+.1).

plot "population.dat"  using 2:xtic(1) with boxes,\
  ""  using 0:($2+.1):(sprintf("%3.2f",$2)) with labels notitle

sprintfZmniejsza tekst wydrukowany do zaledwie 2 miejsc po przecinku.

Możesz przesunąć klawisz pokazany na górze wykresu, aby set key top leftna przykład przestać mu przeszkadzać .

— meuh
źródło