Jak korzystać z sortowania w poleceniu drukowania awk?

Mam kilka poleceń w skrypcie awk, które piszę:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Które wyjścia:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Jak mogę użyć sortpolecenia w skrypcie awk, aby posortować TYLKO graczy i ich liczby?

możesz dodać | sort -k2do swojego polecenia. To posortuje alfabetycznie na podstawie drugiej kolumny.

Przykład:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

prowadzi do

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Chociaż nie poleciłbym tego (biorąc pod uwagę względną prostotę przesyłania wyników za pomocą zewnętrznego sortpolecenia), możesz to zrobić przynajmniej w najnowszych wersjach GNU awk (co najmniej 4.0 IIRC), jak opisano w Sortowanie wartości i indeksów tablicy za pomocą gawk

Oto jak możesz to zaimplementować, zakładając, że masz dane w tablicy asocjacyjnej, w której znajduje się indeks Firstname Lastname. Najpierw musisz zdefiniować niestandardową funkcję porównania, która dzieli indeks, porównuje najpierw Lastname(jako remis) Firstnamenp.

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Teraz możesz użyć PROCINFO["sorted_in"]metody sortowania tablic, o której mowa w komentarzach @zwets

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Składając to razem

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

Testowanie:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

W mniejszych lub starszych wersjach awk najlepszym rozwiązaniem może być przechowywanie zaindeksowanych danych Lastname Firstname, sortowanie za pomocą konwencjonalnej asorti, a następnie dzielenie i zamiana pól indeksów podczas przechodzenia przez tablicę, aby ją wydrukować:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Aby sortużyć tylko drugiego pola oddzielonego spacjami, użyj klucza -k2,2:

... | sort -k2,2

domyślnie sortsortowanie odbywa się leksykograficznie.

Zauważ, że jeśli nie podasz ostatniego pola dla klucza sortowania, tzn. Jeśli po prostu użyjesz, -k2możesz nie uzyskać pożądanego wyniku, ponieważ będzie to sortzgodne ze wszystkimi polami zaczynającymi się od drugiego.

Sprawdź również man sort.

Próbować

awk -f myscript.awk | sort -k2

Gdzie myscript.awk zawiera wyłącznie polecenia awk.

Jeśli twój skrypt jest skryptem powłoki, masz kilka opcji, w tym

• Przepływaj przez sortowanie. ./myscript.bash | sort -k2

• Przepisz kod jako funkcję w skrypcie
  Zamiast

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Zrobić

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Pamiętaj jednak, że możesz także zastosować sortowanie do struktury do ... done zamiast tworzyć funkcję.

    do
       echo $i
    done | sort

Aby posortować dane do wydrukowania:

• Załóżmy, że chcesz wydrukować drugie pole (oddzielone spacjami):

  awk '{print $2}' data.txt | sort
  

  na przykład:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Jeśli chcesz wydrukować całość, data.txtale posortowane według kolumny 2, to:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Użyj tej logiki w swoich wymaganiach.

Możesz użyć man sortdo ciekawszych funkcji sort.

co poniżej:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

działa, kiedy testowałem.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

Aby posortować dane wyjściowe do pliku:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}