Czy pojedynczy zestaw Ubuntu SDK może obsługiwać dotyk i pulpit z osobnymi układami?

Wiem, że aplikacje dotykowe będą działały na pulpicie z tym samym interfejsem użytkownika, ale zastanawiałem się, czy w pojedynczej aplikacji Ubuntu SDK będzie można korzystać z wielu okien interfejsu użytkownika z elementami interfejsu użytkownika w stylu pulpitu podczas pracy w trybie pulpitu, a jednocześnie udostępnienie osobnego interfejsu dotykowego podczas pracy na platformach dotykowych.

Zmiana aspektów układu w zależności od wielkości okna może być dokonana na wiele sposobów. Na najbardziej podstawowym poziomie możesz po prostu ustawić właściwości na różne wartości w zależności od wymiarów. Oto minimalny przykład, który rysuje szary kwadrat, który zmienia kolor na pomarańczowy, jeśli powiększysz okno:

Biegnij z qmlscene path/to/file.qml

import QtQuick 2.0
import Ubuntu.Components 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(50)

    Rectangle {
        id: hello
        color: parent.width > units.gu(60) ? UbuntuColors.orange : UbuntuColors.warmGrey
        anchors.fill: parent
    }
}

Oczywiście, jeśli masz bardziej złożone elementy aplikacji, może to być nieco nudne. Aby temu zaradzić, pakiet Ubuntu Toolkit udostępnia składnik ConditionalLayout, w którym można zdefiniować różne układy, które będą aktywowane, gdy zostanie spełniony warunek. Dzieje się to dynamicznie i zmiany można zobaczyć podczas zmiany rozmiaru okna.

Oto bardziej złożony przykład z użyciem ConditionalLayout:

import QtQuick 2.0
import Ubuntu.Components 0.1
import Ubuntu.Components.ListItems 0.1 as ListItem
import Ubuntu.Layouts 0.1

MainView {
    id: root
    width: units.gu(50)
    height: units.gu(75)

    Page {
        anchors.fill: parent

        Layouts {
            id: layouts
            anchors.fill: parent
            layouts: [

                ConditionalLayout {
                    name: "flow"
                    when: layouts.width > units.gu(60)

                    Flow {
                        anchors.fill: parent
                        flow: Flow.LeftToRight

                        ItemLayout {
                            item: "sidebar"
                            id: sidebar
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                            }
                            width: parent.width / 3
                        }

                        ItemLayout {
                            item: "colors"
                            anchors {
                                top: parent.top
                                bottom: parent.bottom
                                right: parent.right
                                left: sidebar.right
                            }
                        }
                    }
                }
            ]

            Column {
                id: sidebar
                anchors {
                    left: parent.left
                    top: parent.top
                    right: parent.right
                }
                Layouts.item: "sidebar"

                ListItem.Header {
                    text: "Ubuntu Color Palette"
                }

                ListItem.Standard {
                    id: orangeBtn
                    text: "Ubuntu Orange"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.orange
                        }
                    }
                }

                ListItem.Standard {
                    id: auberBtn
                    text: "Canonical Aubergine"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.lightAubergine
                        }
                    }
                }

                ListItem.Standard {
                    id: grayBtn
                    text: "Warm Grey"
                    control: Button {
                        text: "Click me"
                        onClicked: {
                            hello.color = UbuntuColors.warmGrey
                        }
                    }
                }
            } // Column

            Rectangle {
                id: hello
                Layouts.item: "colors"
                color: UbuntuColors.warmGrey
                anchors {
                    top: sidebar.bottom
                    bottom: parent.bottom
                    left: parent.left
                    right: parent.right
                }

                Label {
                    anchors.centerIn: parent
                    text: "Hello (ConditionalLayout) World!"
                    color: "black"
                    fontSize: "large"
                }
            }
        } // Layouts
    } // Page
} // Main View

W domyślnym rozmiarze podobnym do telefonu wygląda następująco:

Po rozwinięciu do rozmiaru tabletu lub pulpitu wygląda następująco:

Myślę, że możesz uzyskać ten wynik za pomocą układów warunkowych .