Koloruj numery w emacs inaczej

Chcę kolorować numery inaczej niż znaki tekstowe w emacs dla każdego trybu, w którym znajduje się emacs. Jak zmodyfikować plik .emacs w tym celu? Chciałbym moje liczby zawsze pojawiać się na różowo.

Wydaje się, że Gvim ma już tę funkcję.

emacs

— smilingbuddha
źródło

Tu jest późno w nocy, gdzie jestem i testowałem to tylko raz:

(add-hook 'text-mode-hook (lambda () (font-lock-add-keywords nil (list (list "\\([0-9]+\\)" '(0 font-lock-warning-face t)) ))))

To powinno skierować cię w dobrym kierunku - hak jest w trybie głównym text-mode. W razie potrzeby możesz dostosować wyrażenie regularne.

— lawlist

Jest podświetl numery tryb na melpa i również dostępny tutaj .

— amitp

Użycie - aktywacja lub dezaktywacja lokalnie z: M-x smilingbuddha-mode

Umożliwić smilingbuddha-mode globalnie , albo odkomentuj (global-smilingbuddha-mode) i uruchom ponownie; lub wpisz M-x global-smilingbuddha-mode (które będą obowiązywać do czasu ponownego uruchomienia).

Prosimy o modyfikowanie wyrażenia regularnego w celu dostosowania go do własnych potrzeb.

(define-minor-mode smilingbuddha-mode
  "Minor mode for highlighting numbers."
  :group 'smilingbuddha
  :lighter " :)"
  (cond
    (smilingbuddha-mode
      (when (not (or font-lock-mode global-font-lock-mode))
        (font-lock-mode 1))
      (font-lock-add-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (message "Turned ON `smilingbuddha-mode`."))
    ((not smilingbuddha-mode)
      (font-lock-remove-keywords nil
        (list (list "\\([0-9]+\\)" '(0 'smilingbuddha-pink-face t)) ))
      (font-lock-fontify-buffer)
      (message "Turned OFF `smilingbuddha-mode`."))))

(defgroup smilingbuddha nil
  "Highlight numbers."
  :version "0.1"
  :group 'smilingbuddha)

(defface smilingbuddha-pink-face
  '((t (:foreground "black" :background "pink")))
  "Face for `smilingbuddha-pink-face`."
  :group 'smilingbuddha)

(defun turn-on-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode 1))

(defun turn-off-smilingbuddha-mode ()
(interactive)
  (smilingbuddha-mode -1))

(define-globalized-minor-mode global-smilingbuddha-mode
  smilingbuddha-mode turn-on-smilingbuddha-mode)
;; (global-smilingbuddha-mode)

— lawlist
źródło