Wyszukiwanie wartości w programie Excel, zwracanie tak lub nie

8

Mam jeden skoroszyt z dwoma osobnymi arkuszami. Chcę wiedzieć, czy wartości, które pojawiają się w arkuszu B, pojawiają się również w arkuszu A, jeśli tak, chcę zwrócić „TAK”. Jeśli nie, chcę zwrócić „NIE”.

(Przykład: Arkusz roboczy A to lista zaległych książek. Arkusz roboczy B to cała biblioteka).

W arkuszu A mam następujący zestaw danych:

     A
1  AB123CD
2  EF456GH
3  IJ789KL
4  MN1011OP

W arkuszu B mam następujący zestaw danych:

      A           Overdue 
1  AB123CD           ?
2  QR1516ST          ?
3  EF456GH           ?
4  GT0405RK          ?
5  IJ789KL           ?
6  MN1011OP          ?

Jak zbudowałbym funkcję, aby poprawnie wyszukać, jeśli wartości istnieją w tabeli A?

Bawiłem się kombinacją if (), vlookup () i match (), ale wydaje się, że nic nie działa w przypadku wielu arkuszy.

— Kapusta
źródło

18

Możesz użyć następującej funkcji

=IFERROR(IF(MATCH(A1,Sheet1!$A:$A,0),"yes",),"no")

Począwszy od wewnątrz

Dopasuj, szuka w kolumnie A arkusza 1, aby sprawdzić, czy istnieje wartość pasująca do komórki A1 bieżącego arkusza (arkusz 2). Jeśli istnieje dokładne dopasowanie, zwraca numer wiersza.

Instrukcja if. Jeśli dopasowanie zwróci coś (numer 1 lub wyższy), jest to traktowane jako prawda i zwraca „tak”

iferror. Jeśli dopasowanie niczego nie znajdzie, zwraca błąd na. Iferror sprawia, że ten zwrot jest ostatnim „nie”

— gtwebb
źródło

4

WYSZUKAJ.PIONOWO powinno działać ...

=IF(ISNA(VLOOKUP(A1,Sheet1!$A:$A,1,false)),"NO","YES")

Jeśli nie znaleziono dopasowania, WYSZUKAJ.PIONOWO zwraca NA. Widzimy więc, czy jego wynikiem jest ISNA? Następnie zwróć NIE, inaczej TAK

— EkriirkE
źródło

0

Możesz także użyć COUNTIFinstrukcji połączonej z IF:

=IF(COUNTIF(WorksheetA!$A:$A,WorksheetB!$A1)>0,"Yes","No")

Zlicza to, ile razy zawartość komórki A1 znajduje się w kolumnie A pierwszego arkusza roboczego. Jeśli liczba jest większa niż 0, pozycja jest na liście, dlatego zwracamy „Tak”, w przeciwnym razie, jeśli COUNTIFzwraca 0, to element nie został znaleziony i zwracamy „Nie”.

Używam COUNTIFcodziennie, aby identyfikować elementy z jednej listy i drugiej (a także duplikatów).

— JG7
źródło