Kompresujesz wiele plików do wielu archiwów?

Mam folder pełen plików pdf i mam dość Winraring każdego pliku osobno. Nie chcę umieszczać ich wszystkich w jednym archiwum.

Czy nie ma wiersza polecenia, którego można użyć, aby Winrar skompresował plik najlepszą metodą, usunąć plik po utworzeniu pliku .rar, a następnie zrobić to samo dla następnego pliku?

Tak, w folderze instalacyjnym WinRAR znajduje się plik wykonywalny rar.exe. Uruchomienie go bez parametrów pokazuje pełną pomoc w jego użyciu. Na przykład najlepszy poziom kompresji ustawia się za pomocą przełącznika -m5.

Jak powiedziano, skrypt partii / powłoki jest dobrym sposobem na zrobienie tego, ale ten projekt może mieć interesujące cele: http://code.google.com/p/autorar/ .

To jest skrypt, który napisałem, aby skompresować każdy plik osobno za pomocą archiwizatora rar (format winrar5). Aby osobno skompresować wszystkie pliki * .pdf w folderze, musisz umieścić ten skrypt w pliku .bat, a następnie uruchomić go. Najpierw określ katalog początkowy (główny), w którym znajdują się twoje pliki, a następnie możesz określić rozszerzenia do znalezienia i skompresowania w tym katalogu (wyszukiwanie rekurencyjne, wprowadzanie podkatalogów katalogu głównego)

@echo off

REM -m5 max compression    
REM -md64m dictionary size 64m
REM -s solid
REM -ma5 rar5 format (rar4 - ma4)
REM -y yes to all
REM -t test after packing (if test NOT ok, then files will not be deleted if the -df/-dr specified)
REM -df delete files after successful archivation
REM -ep1 exclude base folder of file from archive
:: %%~nZ - file name extracted from var Z
:: %%~fZ - full path of file+ext from var Z
:: %%~dpZ - disk+path
:: setlocal - use local environment vars
setlocal

:step1
    echo Enter start path where files a located
    set /p rarpath=
    echo.
    :: remove doublequotes from path
    set rarpath=%rarpath:"=%

:check dir exist
    if not exist "%rarpath%" echo   "!!!  [%rarpath%] doesn't exist, please enter correct path  !!!"
    if not exist "%rarpath%" echo.
    if not exist "%rarpath%" goto step1
:::::
:::::
    echo.
    echo Enter which extensions to compress (like *.mp4;*.wmv)
    set /p exten=
    echo.
:::::
:::::
    echo.
    echo Final command: 
    echo for /R "%rarpath%" %%Z in (%exten%) do "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ"
    echo.
:::::
:::::
    echo.
    echo Continue? [y/n]
    set /p go=
    if /i %go%==Y goto ok
    if /i %go%==N goto exit

:ok
:: CD to each file's directory, compress file, log output (codepage 866)
set rartime=%time:~0,8%
set rartime=%rartime::=_%
set rartime=%rartime: =%
set rarlog=rar_log_%date%_%rartime%.txt
:: For directories located in current directory
:: for /d %D in (*) do "%programfiles%\winrar\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%D.rar" "%D"

    for /R "%rarpath%" %%Z in (%exten%) do (
        cd /d %%~dpZ
        "%programfiles%\WinRAR\rar.exe" a -ma5 -m5 -s -md64m -t -y -ep1 -df "%%~nZ.rar" "%%~fZ" >> c:\%rarlog% 2>&1
        type c:\%rarlog%
        echo. >> c:\%rarlog%
        echo ----------------------------------------------------------------------------- >> c:\%rarlog%
        echo. >> c:\%rarlog%
    )
    echo.
    echo.
    echo        !!! All Done !!!
    pause
    goto :EOF
    ::EXIT /B 0

:exit
    echo Program terminated
    pause
    goto :EOF