Na podstawie tego, co przeczytałem, jeśli te, które napisały, że netshnie działa, zaczynają się od 7 i więcej - to jest nieprawidłowe. Teraz, jeśli chodzi tylko o „ netsh routing”, myślę, że masz rację, ale to działa - zaraz pokażę zawartość pliku wsadowego, który utworzyłem w systemie Windows 8.1. Zamiast otrzymywać zwykłe komentarze i informacje, postaram się pomóc tym z pełnymi informacjami.
Po pierwsze, musisz upewnić się, że połączenie, które będziesz udostępniać, jest ustawione tak, aby współdzielić połączenie. Ten link tutaj powinien Cię zabrać:
http://windows.microsoft.com/en-us/windows/set-internet-connection-sharing#1TC=windows-7
Otwórz Połączenia sieciowe, klikając przycisk Start Obraz przycisku Start, a następnie Panel sterowania. W polu wyszukiwania wpisz adapter, a następnie w obszarze Centrum sieci i udostępniania kliknij opcję Wyświetl połączenia sieciowe.
Kliknij prawym przyciskiem myszy połączenie, które chcesz udostępnić, a następnie kliknij polecenie Właściwości. Wymagane pozwolenie administratora Jeśli zostanie wyświetlony monit o hasło administratora lub potwierdzenie, wpisz hasło lub potwierdź.
Kliknij kartę Udostępnianie, a następnie zaznacz pole wyboru Zezwalaj innym użytkownikom sieci na łączenie się za pośrednictwem połączenia internetowego tego komputera.
Po wykonaniu powyższych kroków, aby skonfigurować ICS na komputerze hosta, wprowadź następujące zmiany na wszystkich pozostałych komputerach (ale nie na komputerze hosta).
Otwórz Opcje internetowe, klikając przycisk Start Obraz przycisku Start, klikając Panel sterowania, klikając Sieć i Internet, a następnie klikając Opcje internetowe.
Kliknij kartę Połączenia, a następnie kliknij opcję Nigdy nie wybieraj połączenia.
Kliknij Ustawienia LAN.
W oknie dialogowym Ustawienia sieci lokalnej (LAN), w obszarze Konfiguracja automatyczna wyczyść pola wyboru Automatycznie wykryj ustawienia i Użyj skryptu automatycznej konfiguracji.
W obszarze Serwer proxy wyczyść pole wyboru Użyj serwera proxy do sieci LAN, a następnie kliknij przycisk OK.
Według mojej wiedzy uważam, że powinno to działać zarówno w systemie Windows 7, jak i 8.
Ponieważ tematem było rozwiązanie z linii poleceń, jest to zawartość pliku wsadowego, w jaki sposób konfiguruję i jestem gotowy do pracy z wirtualnym adapterem bezprzewodowym.
Po utworzeniu może być konieczne skorzystanie z powyższych instrukcji i upewnienie się, że współdzielisz połączenie źródłowe z nowo utworzonym wirtualnym adapterem, który będzie widoczny dla twoich urządzeń bezprzewodowych.
Plik .bat udostępniania połączenia:
@echo off
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%
cd\
if NOT EXIST "C:\TEMP\switch.txt" (
GOTO :START
) ELSE (
GOTO :STOP
)
:START
REM Create Temp File for On and Off switch.
ECHO WOOHOO >"C:\TEMP\switch.txt"
REM -- Output everything that is happening into a file called wifi.txt.
REM -- Start out with a timestamp at the top to show when it was done.
REM -- All 'netsh' commands are for setting up the SSID and starting the sharing.
REM -- I stop and start when starting the service just for prosperity.
echo _%_my_datetime% >"C:\TEMP\wifi.txt"
netsh wlan set hostednetwork mode=allow ssid=ITWORKS key=111222333 >> "C:\TEMP\wifi.txt"
netsh wlan stop hostednetwork >>"C:\TEMP\wifi.txt"
netsh wlan start hostednetwork >>"C:\TEMP\wifi.txt"
echo MSGBOX "Wifi Sharing Started!" > %temp%\TEMPmessage.vbs
call %temp%\TEMPmessage.vbs
del %temp%\TEMPmessage.vbs /f /q
GOTO :END
REM -- This will turn ICS off and give a prompt via VBS that you're turned off.
REM -- I timestamp when the service is turned off in the output file.
REM -- I delete the switch file to let the code know to turn it on when
REM -- when fired off again. Tempmessage is the msgbox used to show the service
REM -- has been turned off. Same for the msgbox above when it's on.
:STOP
echo OFF AT _%_my_datetime% >>"C:\TEMP\wifi.txt"
netsh wlan stop hostednetwork >>"C:\TEMP\wifi.txt"
DEL /Q "C:\TEMP\switch.txt"
echo MSGBOX "Wifi Sharing Stopped!" > %temp%\TEMPmessage.vbs
call %temp%\TEMPmessage.vbs
del %temp%\TEMPmessage.vbs /f /q
:END
Z przyjemnością odpowiem na pytania na ten temat, ponieważ będą wyjątkowe sytuacje i chciałbym pomóc, ponieważ musiałem poskładać to, co znalazłem powyżej.
Aby jednak spojrzeć na to z perspektywy, działa to w systemie Windows 8.1 za pomocą połączenia Ethernet z laptopem współdzielącym połączenie z wirtualnym adapterem. Może działać równie dobrze, jeśli próbujesz udostępnić źródłowe połączenie bezprzewodowe.