Vim: Pokaż indeks kart w linii tabulacji

Powiedzmy, otworzyłem file1.txt, file2.txt, file3a.txti file3b.txttakie, że tabline (rzecz na górze) wygląda następująco:

file1.txt  file2.txt  2 file3a.txt

(Zwróć uwagę, jak go file3b.txt.brakuje, ponieważ jest pokazany w podziale, na tej samej karcie co file3a.txt)

Aby szybciej przechodzić między kartami (za pomocą <Number>gt), chciałbym, aby każda karta wyświetlała indeks wraz z nazwą pliku. Tak jak:

1:<file1.txt>  2:<file2.txt>  3:<2 file3a.txt>

Formatowanie (w szczególności nawiasy klamrowe) jest opcjonalne; Chcę tylko wskaźnik do pojawiają się (the 1:, 2:i tak dalej).

Żadnych wskazówek :h tab-page-commandsani google.

Musisz spojrzeć na:

:help 'tabline'
:help setting-tabline

A jeśli masz „e” w ustawieniu „guioptions”:

:help 'guitablabel'

włóż to do swojego vimrc

" Rename tabs to show tab number.
" (Based on http://stackoverflow.com/questions/5927952/whats-implementation-of-vims-default-tabline-function)
if exists("+showtabline")
    function! MyTabLine()
        let s = ''
        let wn = ''
        let t = tabpagenr()
        let i = 1
        while i <= tabpagenr('$')
            let buflist = tabpagebuflist(i)
            let winnr = tabpagewinnr(i)
            let s .= '%' . i . 'T'
            let s .= (i == t ? '%1*' : '%2*')
            let s .= ' '
            let wn = tabpagewinnr(i,'$')

            let s .= '%#TabNum#'
            let s .= i
            " let s .= '%*'
            let s .= (i == t ? '%#TabLineSel#' : '%#TabLine#')
            let bufnr = buflist[winnr - 1]
            let file = bufname(bufnr)
            let buftype = getbufvar(bufnr, 'buftype')
            if buftype == 'nofile'
                if file =~ '\/.'
                    let file = substitute(file, '.*\/\ze.', '', '')
                endif
            else
                let file = fnamemodify(file, ':p:t')
            endif
            if file == ''
                let file = '[No Name]'
            endif
            let s .= ' ' . file . ' '
            let i = i + 1
        endwhile
        let s .= '%T%#TabLineFill#%='
        let s .= (tabpagenr('$') > 1 ? '%999XX' : 'X')
        return s
    endfunction
    set stal=2
    set tabline=%!MyTabLine()
    set showtabline=1
    highlight link TabNum Special
endif

Na stronie wiki można znaleźć co najmniej dwa (te, które testowałem), które dają indeksy tabulatorów, a jedno z nich generuje liczbę okien w każdym buforze, które mają edytowane.

Oto wynik moich modyfikacji tego, który generuje liczbę edytowanych buforów. Wprowadzoną przeze mnie zmianą było dostosowanie wartości podświetlenia tej liczby do reszty zakładki:

set tabline=%!MyTabLine()  " custom tab pages line
function MyTabLine()
        let s = '' " complete tabline goes here
        " loop through each tab page
        for t in range(tabpagenr('$'))
                " set highlight
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " set the tab page number (for mouse clicks)
                let s .= '%' . (t + 1) . 'T'
                let s .= ' '
                " set page number string
                let s .= t + 1 . ' '
                " get buffer names and statuses
                let n = ''      "temp string for buffer names while we loop and check buftype
                let m = 0       " &modified counter
                let bc = len(tabpagebuflist(t + 1))     "counter to avoid last ' '
                " loop through each buffer in a tab
                for b in tabpagebuflist(t + 1)
                        " buffer types: quickfix gets a [Q], help gets [H]{base fname}
                        " others get 1dir/2dir/3dir/fname shortened to 1/2/3/fname
                        if getbufvar( b, "&buftype" ) == 'help'
                                let n .= '[H]' . fnamemodify( bufname(b), ':t:s/.txt$//' )
                        elseif getbufvar( b, "&buftype" ) == 'quickfix'
                                let n .= '[Q]'
                        else
                                let n .= pathshorten(bufname(b))
                        endif
                        " check and ++ tab's &modified count
                        if getbufvar( b, "&modified" )
                                let m += 1
                        endif
                        " no final ' ' added...formatting looks better done later
                        if bc > 1
                                let n .= ' '
                        endif
                        let bc -= 1
                endfor
                " add modified label [n+] where n pages in tab are modified
                if m > 0
                        let s .= '[' . m . '+]'
                endif
                " select the highlighting for the buffer names
                " my default highlighting only underlines the active tab
                " buffer names.
                if t + 1 == tabpagenr()
                        let s .= '%#TabLineSel#'
                else
                        let s .= '%#TabLine#'
                endif
                " add buffer names
                if n == ''
                        let s.= '[New]'
                else
                        let s .= n
                endif
                " switch to no underlining and add final space to buffer list
                let s .= ' '
        endfor
        " after the last tab fill with TabLineFill and reset tab page nr
        let s .= '%#TabLineFill#%T'
        " right-align the label to close the current tab page
        if tabpagenr('$') > 1
                let s .= '%=%#TabLineFill#%999Xclose'
        endif
        return s
endfunction

Tabline plugin jest to vim wtyczki, które realizuje wymagane funkcje i nie będzie zdmuchnąć swoją vimrc. Po prostu zainstaluj i uruchom ponownie vim.

Żeby zainstalować:

cd /usr/share/vim/vimfiles/plugin/
wget https://raw.githubusercontent.com/mkitt/tabline.vim/master/plugin/tabline.vim

lub użyj menedżera wtyczek.

W przypadku Vima opartego na graficznym interfejsie użytkownika (Gvim w systemie Linux, MacVim w systemie Mac itp.), Umieść to w .gvimrc:

set guitablabel=%N:%M%t " Show tab numbers

Kilka porad dotyczących faktycznego używania wyświetlanych liczb:

• Ngtprzejdzie do zakładki N. Na przykład 3gtidzie do zakładki 3.
• :tabm2przesuwa bieżącą kartę, aby pojawiała się po karcie 2.
  • Aby przenieść tę kartę do pierwszej pozycji, użyj :tabm0
  • Aby przenieść tę kartę do ostatniej pozycji, wystarczy użyć :tabm