Czy ktoś ma skrypt terminala Mac do usuwania ukrytych plików?

Moje radio samochodowe może odtwarzać muzykę z pamięci flash USB, więc zapytałem o kopiowanie plików MP3 z listy odtwarzania iTunes . To działało dobrze, ale moje stereo nie odtwarzało plików MP3. W końcu umieściłem dysk flash na komputerze z systemem Windows 7 i znalazłem problem: ._[filename].mp3załadowano także kilka ukrytych plików w tym formacie .

Wiem, że w systemie Windows możesz usuwać pliki na podstawie atrybutów i zastanawiałem się, czy możesz zrobić to samo w Terminalu? Być może ze skryptem, który mogę uruchomić z woluminem jako parametrem?

Pliki te są ukryte w OS X, ponieważ zaczynają się od .i dlatego nie są domyślnie wyświetlane w Finderze. W tych plikach nie ma specjalnego atrybutu.

Bardzo uproszczonym podejściem byłoby usunięcie wszystkich plików, które zaczynają się od kropki i podkreślenia:

find /Volumes/<your-volume-name> -name '._*' -type f -delete

Uwaga dotycząca bezpieczeństwa: uruchom to bez, -deleteaby zobaczyć, które pliki zostaną usunięte. I nigdy nie rób tego na całym komputerze Mac HD, tylko na dysku USB.

Aby uzyskać dodatkowe informacje: Te pliki są nazywane „Widelcami zasobów” i czasami zawierają informacje, których nie chcesz usunąć. W twoim przypadku powinno być dobrze. Możesz trwale wyłączyć tworzenie tych plików za pomocą BlueHarvest . Istnieje również aplikacja, która twierdzi, że czyści ich woluminy, ale nie wypróbowałem jej i jest w wersji beta, więc używaj ostrożnie: Hidden Cleaner .

Jeszcze jedno rozwiązanie, które zadziałało dla mnie (MacOS 10.6.8) w typie terminala:

dot_clean "/Volumes/<your-volume-name>"

Miałem dokładnie ten sam problem z moim samochodowym zestawem stereo, 1 plik / 2 jest niemożliwy do odtworzenia, ponieważ odtwarzacz uważa, że ​​plik kropkowy utworzony przez MAC OS jest plikiem muzycznym ... Dzięki temu ten post był bardzo przydatny, dzięki.

Wracam teraz z ulepszonym i bezpłatnym rozwiązaniem dla Mavericks:

1. Utwórz aplikację Automator, aby uruchomić skrypt AppleScript

2. Użyj tego skryptu:

   on run {input, parameters}
       try
           tell application "Finder" to set allDrives to the name of every disk whose local volume is true and startup is false
           set driveName to {choose from list allDrives with title "DiskCleaner" with prompt "Disk to Clean and Eject:" OK button name "Clean and Eject" cancel button name "Abort"} as text
           set getDriveIdentifier to "diskutil info " & quoted form of driveName & " | grep Ident | awk '{print $3}'"
           set driveIdentifier to do shell script getDriveIdentifier
           try
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete"
               do shell script "rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}"
               display notification "Disk Cleaned"
           on error
               try
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete" with administrator privileges
                   do shell script "sudo rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}" with administrator privileges
                   display notification "Disk Cleaned"
               on error
                   display notification "Can't Clean, Permission Denied"
               end try
           end try
           delay 1
           try
               do shell script "diskutil eject " & driveIdentifier
               display notification "Disk Ejected"
           on error
               display notification "Can't Eject, Disk in Use"
           end try
       on error
           display notification "No Disk to Clean and Eject"
       end try
   end run
   

3. Zapisz na przykład aplikację jako DiskCleaner.app

Ten skrypt poprosi Cię o wybranie dysku USB do wyczyszczenia i wysunięcia. Następnie wyczyści dysk USB (spróbuje z poświadczeniami administratora, jeśli nie powiedzie się z bieżącymi), a następnie usunie, jeśli to możliwe.

Oczywiście jest jeszcze miejsce na ulepszenia, zrobiłem ten skrypt dla siebie!

Masz również swobodę dodawania wierszy kodu do czyszczenia większej liczby plików.

Cieszyć się!

Możesz również użyć Automatora, aby osiągnąć to samo, jeśli terminal Cię przeraża:

Ten skrypt służy do usuwania ukrytych plików lub katalogów na dyskach USB. https://github.com/ulasyurtsever/delete-hidden-files-or-directories