lekarstwem na trackball bez kółka przewijania?

Zastanawiam się nad zakupem trackballa, a moją opcją jest marmur Trackman firmy Logitech. Ale potem odkryłem, że nie ma kółka do przewijania. Jak sobie z tym poradzić? Czy zdecydowanie chcę kupić trackball z kółkiem do przewijania? Dużo przewijam za pomocą Facebooka.

Nie chcę klikać palcem wskazującym i środkowym, więc niektóre myszy trackball nie będą dla mnie działać, jak Wheel Trackman.

Jeśli korzystasz z systemu Windows, sugeruję wypróbowanie AutoHotKey, inni użytkownicy mieli już problem z przewijaniem za pomocą Marble Mouse (użyłem skryptu na dole):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

Rozwiązanie firmy Logitech dostarczane ze sterownikami jest dziwne: kliknij raz, aby włączyć przewijanie w 4 kierunkach, a następnie kliknij ponownie, aby je wyłączyć. Nie możesz przytrzymywać i przewijać, o co mi chodziło. Skończyło się odinstalowywanie ich oprogramowania.

Mam ten sam trackball, a rozwiązanie jest bardzo eleganckie: po kliknięciu wybranego przycisku sama kula staje się kółkiem do przewijania. Wybrałem duży prawy przycisk, który naciskam małym palcem.

Jest to bardzo wygodne i przyzwyczajenie się zajmuje tylko kilka dni.

Szybko stwierdzisz, że jakiekolwiek kółko przewijania (na myszy lub trackballu) jest czymś bezużytecznym. Zaufaj mi, warto ;-)

Zalety:

• Przewijanie 2D zamiast 1D
• szybsze i bardziej precyzyjne przewijanie niż koło
• bardziej wygodne przy długim przewijaniu (dzięki bezwładności piłki). Idealny na przykład na Facebooku.

Nie mogę bez tego dłużej żyć.

Konfiguracja tego w dowolnym systemie operacyjnym Linux nie jest trudna. Wymaga tylko utworzenia pliku /etc/X11/xorg.conf (zobacz moją konfigurację tutaj: Skonfiguruj trackball pod Linuksem bez edycji Xorg.conf )

Więcej informacji można znaleźć tutaj: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

W systemie Windows nie mam doświadczenia, ale myślę, że wraz z trackballem dostarczane jest narzędzie konfiguracyjne.

Możesz wypróbować marmurowe kółko przewijania myszy, opracowane specjalnie dla tej myszy:

Marble Mouse Scroll Wheel, lub po prostu Marble Scroll, to mały program zaprojektowany do symulacji kółka przewijania na dowolnym trackballu lub myszy bez niego. Został zaprojektowany specjalnie dla marmurowej myszy Logitech, ale może współpracować z każdą standardową myszą lub trackballem. Jest przeznaczony dla systemu Windows 2000 i nowszych wersji.

Marble Scroll zastępuje funkcje automatycznego przewijania Logitech i Universal Scroll; żadne z nich nie emuluje prawidłowo prawdziwego kółka przewijania i oba mają ograniczenia i wady.

Marble Scroll działa z każdą myszą lub trackballem i nie wymaga instalacji sterowników Logitech SetPoint lub MouseWare.

cechy

• Dodaj kółko przewijania do dowolnej myszy z więcej niż dwoma przyciskami
• Kompatybilność z większością aplikacji obsługujących kółko przewijania (dla dowolnego rodzaju danych wejściowych)
• Regulowane przyspieszenie
• Regulowana odległość przewijania (na „krok” - patrz poniżej)
• Stopniowe przewijanie w celu symulacji prawdziwego kółka myszy
• Szybki przełącznik trybu lewo / prawo
• Szybkie włączanie / wyłączanie poprzez kliknięcie ikony na pasku zadań
• Mały i lekki w zasobach systemowych

Strona produktu wydaje się obecnie niedostępna, ale tutaj jest kopia tekstu strony na Archive.org .

Link do pobrania jest tutaj .

Istnieje prosta 100-liniowa alternatywa C ++, która jest dość podobna do rozwiązań AutoHotKey

• wysyłanie zdarzeń pionowego / poziomego kółka przewijania poprzez przesuwanie kulki, przytrzymując jeden z przycisków X i
• środkowe kliknięcie podczas naciskania i zwalniania przycisku X bez poruszania kulką.

https://github.com/Seelge/TrackballScroll

Edycja: nowsze wersje zawierają ikonę paska zadań, działają w systemie Windows 10 i są oparte na języku C #.

Oto skrypt AutoHotKey, którego używam. Przewijasz, przytrzymując lewy mały przycisk i obracając piłkę w górę / w dół. Jednak kliknięcie lewego małego przycisku nadal powoduje POWRÓT. Może także przewijać w lewo / w prawo, ale było to dla mnie zbyt wrażliwe, więc zostało skomentowane tutaj (blok, który zaczyna się od ;timesX := Abs(movedx) / 4).

Oryginalną wersję znalazłem na stronie http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/ . Opublikowałem tam swoją wersję jako inny person8923.

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Szkoda, że ​​Logitech nie wdrożył symulacji kółka przewijania. Ich sterownik obiecuje taką funkcję, ale nie działa dla wszystkich aplikacji, co czyni ją zupełnie bezużyteczną. Byli tak blisko stworzenia idealnej myszy! : s

Jedynym obejściem, jakie znalazłem, jest użycie do tego skryptu AutoHotkey . Za jego pomocą możesz sprawić, że małe lewe / prawe przyciski będą przewijać w górę i w dół. Działa idealnie, ale konfiguracja jest bardzo trudna: musisz najpierw nauczyć się podstaw AutoHotkey. Jeśli zdecydujesz się to zrobić, oto mój skrypt AutoHotkey. Jest to adaptacja oryginalnego skryptu Jerbo . Pojedyncze kliknięcie rozpocznie przewijanie w normalnym tempie, ale podwójne lub potrójne kliknięcie rozpocznie przewijanie szybciej.

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

Właśnie dostałem mysz Logitech Marble i miałem problem z przewijaniem. Więc zrobiłem ten skrypt na AutoHotKey. Lewy przycisk X umożliwia przewijanie, co oznacza, że ​​podczas gdy w dół możesz przewijać piłkę w pionie i poziomie, oraz poruszać się do przodu i do tyłu w przeglądarce za pomocą lewego i prawego przycisku. Prawy przycisk X ma taką samą akcję jak środkowy przycisk.

Im w systemie Windows 7.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

W zależności od systemu operacyjnego możesz skonfigurować jeden z przycisków, aby umożliwić przewijanie poprzez przesuwanie wskaźnika podczas trzymania. Np. Poniższy skrypt włącza to na przycisku 10 mojej myszy („środkowy górny” przycisk Logitech MX310):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Istnieją takie marmurowe myszy (myszy), które zawierają kółko przewijania. W przeciwnym razie wygląda na to, że aplikacja lub jakiś skrypt byłaby wymagana dla myszy bez kółek wraz z użyciem jednego z przycisków do włączenia funkcji przewijania (co zanotowano w komentarzu do innej odpowiedzi, jako niedopuszczalne rozwiązanie).

Więc „Po co wymyślać koło?” to dobre przysłowie w tym przypadku.

W tych przykładach element jest fizycznie zainstalowany i istnieje wiele rodzajów do wyboru. Poniżej znajdują się dwa przykłady i style.

Lub coś takiego: Adesso

Dwie niekonwencjonalne opcje

• Oprócz trackballa użyj gładzika Apple Magic Trackpad. (To jest moje obecne rozwiązanie) http://www.apple.com/magictrackpad/

• Kup kontroler skoków i używaj go oprócz trackballa. Machaj ręką przed urządzeniem, aby przewijać w górę lub w dół. https://www.leapmotion.com/product

Kredyt na zdjęcia http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

Prostym (i odważnym ergonomicznym rozwiązaniem) jest wprowadzenie funkcji przewijania w lewą stronę.

Można to osiągnąć za pomocą myszy lewą ręką / za pomocą klawiatury z wbudowanym kółkiem przewijania na lewej krawędzi / poprzez przypisanie funkcji przewijania do klawiszy programowalnej klawiatury za pomocą programu takiego jak Mkey ( http: // www.seriosoft.org/en/index.php ).

Dlaczego uważam, że jest to bardziej ergonomiczne - ponieważ takie podejście rozkłada napięcie bardziej równomiernie na obie ręce. (Więcej na ten temat: http://capsoff.org/checklist ).

Korzystam z systemu Windows7 i korzystam z optycznego trackballa Kensington Orbit bez przewijania - to trackball z dwoma przyciskami, bez przycisków X wymaganych przez większość skryptów i aplikacji AHK wskazanych przez innych.

Jednak MouseImp pracuje dla mnie na Windows7. To jest konfigurowalne, ale mam skonfigurowane, right-click + rollaby uzyskać ekran przewijania. Bardziej przypomina przeciąganie, więc wskaźnik się porusza i masz tylko jeden ekran na raz [aktualizacja: szybkość przewijania można konfigurować, więc może być więcej niż „jedna strona”].

W tym samym czasie TrackballWorks firmy Kensington został skonfigurowany w taki sposób, że umożliwia przewijanie strony w dół left-click + right-click. Niestety nie można wtedy przewijać strony w górę (w jednym lub w drugim).

To nie jest wtyczka produktu - to po prostu praca z tym modelem / rodzajem trackballa .

Uwaga: stale klikasz prawym i lewym przyciskiem myszy, co może prowadzić do zamieszania i śledzenia linków / aktywacji js, gdy chcesz przestać przewijać . :::westchnienie:::

Właśnie dostałem bezprzewodową trackball na orbitę z Kensington, to całkiem niesamowite. Masz piłkę, masz oba przyciski po każdej stronie i masz coś w rodzaju koła poza kulką, która umożliwia przewijanie strony w górę lub w dół. To naprawdę działa, a ja korzystam z systemu Windows i Mac OSX.

Rzeczywiście zrobiłem coś do tego za pomocą AutoHotkey jakiś czas temu i pomyślałem, że też tu podzielę się: Emulator kółka myszy

To emuluje przewijanie kółka myszy poprzez poruszanie myszą, trzymając lewy i prawy przycisk myszy.

Możesz także emulować środkowe kliknięcie, klikając jednocześnie lewy i prawy przycisk myszy.

Kolejne rozwiązanie dla systemu Windows 7, które umożliwia przewijanie we wszystkich aplikacjach, w tym Internet Explorer:

1. Zainstaluj AutoHotKey .
2. Zapisz ten skrypt jak scroll.ahkna pulpicie.
3. Kliknij prawym przyciskiem myszy scroll.ahk.
4. Wybierz Uruchom skrypt .
5. Potwierdź, jeśli pojawi się monit.

Spowoduje to przytrzymanie małego prawego przycisku przewijania w pionie podczas przesuwania kulki. Mały lewy przycisk to przycisk Wstecz.

W przypadku zniknięcia linku do kodu Erika Elmore'a, oto on:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Inny użytkownik Trackman Marble tutaj.

Używam X-Mouse Button Control do emulacji przewijania. Ta implementacja funkcji nie jest jeszcze doskonała (ale?), Ale jest znacznie bardziej użyteczna niż implementacja Logitech w ich własnym oprogramowaniu SetPoint ™.

Polecam XMBC każdemu, kto nie chce zadzierać z AutoHotKey i szuka czegoś, co po prostu działa.