Jak sprawić, aby przypomnienia kalendarza programu Outlook pozostały na topie w systemie Windows 7

Właśnie zaczynam korzystać z systemu Windows 7 i chcę wiedzieć, jak sprawić, by moje przypomnienia programu Outlook pojawiały się i były widoczne. Otwierają się dyskretnie, jako kolejne okno w stosie programu Outlook na pasku zadań. W rezultacie przeoczam je, ponieważ wyskakują za wszystko inne.

Jak sprawić, by były łatwiejsze do przeoczenia?

(Oczywiście, zwykle nie chce się nieprzyjemnych aplikacji, które pchają się na czoło. Ale jest kilka miejsc, w których takie zachowanie jest pożądane, a przypomnienia kalendarza programu Outlook są jednym z nich.)

Miałem ten sam problem z programem Outlook 2010. Wykonaj czynności wymienione poniżej, działa jak urok. Nie zapomnij włączyć wszystkich makr: Centrum zaufania> Ustawienia makr.

• Utwórz certyfikat cyfrowy na później: kliknij Start i wpisz „certyfikat”, wybierz „Certyfikat cyfrowy dla projektów VBA”
• Wpisz nazwę swojego certyfikatu. Kliknij OK. Otwórz program Outlook i naciśnij Alt+, F11aby uruchomić edytor VBA.
• W drzewie po lewej rozwiń „Obiekty Microsoft Office Outlook” i dwukrotnie kliknij „ThisOutlookSession”

• Wklej ten kod:

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• Podpisz makro, aby uruchomiło się: Narzędzia> Podpis cyfrowy ... i wybierz wcześniej utworzony certyfikat

• Zamknij okno VBA
• Włącz wszystkie makra w Plik> Opcje> Centrum zaufania> Ustawienia Centrum zaufania> Ustawienia makr

AutoHotKey może być również wykorzystany do rozwiązania tego problemu. Ten skrypt umieści okno przypomnienia na górze bez kradzieży fokusu (testowane z Win10 / Outlook 2013)

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

Skrypt AHK - skompilowany plik EXE

Najlepsza odpowiedź, którą znalazłem, jest tutaj: jak sprawić, by przypomnienia o spotkaniu programu Outlook pojawiały się ponownie przed innymi oknami za pomocą prostego VBA.

Wymaga to dodania kilku wierszy prostego kodu VBA do „ThisOutlookSession”. Teraz za każdym razem wyskakuje okno. Dużo lepiej.

• Utwórz certyfikat cyfrowy na później
• Kliknij Start i wpisz „certyfikat”, wybierz „Certyfikat cyfrowy dla projektów VBA”
• Wpisz nazwę swojego certyfikatu
• Gotowy
• Otwórz program Outlook i naciśnij klawisze Alt + F11, aby uruchomić edytor VBA.
• W drzewie po lewej rozwiń „Obiekty Microsoft Office Outlook” i dwukrotnie kliknij „ThisOutlookSession”

• Wklej ten kod, modyfikując tekst w cudzysłowach zgodnie z własnymi preferencjami. Zostaw cytaty w.

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• Podpisz makro, aby działało, przechodząc do Narzędzia> Podpis cyfrowy… i wybierając wcześniej utworzony certyfikat

• Zamknij okno VBA

Nie ma mowy. Nasza firma próbowała przekazać ją bezpośrednio do Microsoft. Jedną rzeczą, którą ludzie tutaj robią, jest przypisanie mu bardziej nieznośnego dźwięku, aby to zauważyć. Ale Microsoft powiedział nam, że jest to zgodne z projektem.

To samo co powyżej odpowiedź Gullu, ale ze zmianą w celu dostosowania do innego tytułu okna:

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Od wersji 1803 (luty 2018 r.) Dostępna jest teraz opcja „Pokaż przypomnienia nad innymi oknami”. Nie wydaje się być domyślnie włączony.

To mnie też wkurzyło. Po intensywnych poszukiwaniach znalazłem częściową odpowiedź: http://www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

Jeśli zmienisz ustawienie „Przyciski paska zadań” w „Właściwości paska zadań i menu Start” na „Nigdy nie łącz”, wówczas grupa zostanie oddzielona, ​​a przypomnienie pojawi się przed wszystkim, co masz otwarte.

Próbowałem to przetestować i okazało się, że było niespójne; pewnego razu ukrył się za tym, nad czym pracowałem, a innym razem wyskoczył z przodu. W obu przypadkach na pasku zadań znajdowała się ikona, która wyglądała inaczej niż sam Outlook, więc była szansa, że ​​ją zauważę.

Użyłem Filebox eXtender i kiedy pojawia się pierwsze przypomnienie, otwieram je i klikam nową ikonę „pinezki” w prawym górnym rogu paska napisów. Następnie, gdy pojawi się następne przypomnienie, pojawi się na pierwszym planie ...

Znalazłem dodatek o nazwie ShowReminders ( http://www.sagelamp.com/pages/showreminders.aspx ), który przenosi okno przypomnień na górę. Działa nawet po zminimalizowaniu okna przypomnienia.

W końcu znajduję proste rozwiązanie za pomocą programu Outlook VBA i prostego pliku EXE.

Oto, jak nigdy więcej nie przegapić spotkania z programem Outlook.

Dlaczego samodzielna aplikacja exe tylko w tym celu? Cóż, miałem dużą czerwoną skrzynkę osadzoną w VBA, ale to rozwiązanie było pełne problemu (wierzę, że dzieje się tak, ponieważ muszę użyć hwnd i innych niezwykłych właściwości systemowych, aby utrzymać dużą czerwoną skrzynkę na wierzchu). Tak więc, aby uprościć sprawę, dlaczego nie podstawowy plik EXE, który robi jedną rzecz. Możesz korzystać z bezpłatnych narzędzi firmy Microsoft (Visual Studio Community 2015 jest bezpłatny).

To jest kod EXE. prosta aplikacja formularza systemu Windows z jednym formularzem. Skompiluj ten kod.

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

I to wszystko, czego potrzebuję w Outlook VBA. Umieść to w ThisOutlookSession

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

To jest ulepszona wersja odpowiedzi tbone, która działa na wersjach niemieckich.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Dodałem niemieckie tytuły okien, a także kilka nowych funkcji ( BringWindowToTop, SetForegroundWindowi SetFocus).

Działa na moim niemieckim systemie Windows 10 wraz z programem Outlook 2016.

Nie udało mi się wygenerować nowego certyfikatu (naciśnięcie Start i wpisanie „certyfikat” niczego nie ujawniło), ale po prostu wybrałem inny certyfikat z listy podczas podpisywania.