Jak mogę wyszukiwać i zamieniać wiele plików Word?

Szukam sposobu wyszukiwania i zastępowania wielu plików Word (.doc) (w celu automatyzacji procesu).

Znalezione do tej pory oprogramowanie pozwala mi tylko na wyszukiwanie, ale nie na zamianę.

Jak mogę to zrobić za pomocą programu Word?

Możesz spróbować VBA Find & Replace (link z pamięci podręcznej).

VBA Znajdź i zamień © zapewnia metodę wyszukiwania i zastępowania tekstu w dowolnym miejscu dokumentu (lub zbioru dokumentów) za pomocą par zmiennych zdefiniowanych przez użytkownika „znajdź” i „zamień” lub zdefiniowaną przez użytkownika listę „znajdź” i „zamień” pary. Zapewnia również metodę wyszukiwania tekstu i zastępowania znalezionego tekstu zdefiniowanym przez użytkownika wpisem „Autotekst” lub „Blok konstrukcyjny”.

W celu wykonania wielu zastąpień normalnych i symboli zastępczych w wielu plikach MS Word znajdujących się w wielu folderach w danym folderze głównym, utworzyłem następujące makro VBA. Aby go użyć, musisz zmienić zawartość następujących zmiennych (stałych):

• rootPath : folder główny, w którym znajdują się foldery zawierające dokumenty Word.
• findTextsWild and replaceTextsWild : tablica wyrażeń znajdź i zamień na podstawie symboli zastępczych.
• findTexts and replaceTexts : tablica normalnych wyrażeń find i replace.

Może ci się przyda :-)

Sub GlobalTextReplacement()
' Root under which all manuals are stored
Dim rootPath As String
rootPath = "c:\Data\Manuals\"

' Find and replace text for wildcard replacement. Performed first.
Dim findTextsWild() As Variant, replaceTextsWild() As Variant
findTextsWild = Array("[ ]{2;}", "[cC]onfiguration[/ ]@[pP]olicy [rR]epository", "[sS]ervlet[- ]@[fF]ilter")
replaceTextsWild = Array(" ", "Configuration/Policy Repository", "Servlet-Filter")

' Find and replace text for normal case insensitive replacement. Performed second.
Dim findTexts() As Variant, replaceTexts() As Variant
findTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "servletfilter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p ", " ^p")
replaceTexts = Array("DirX Access", "Policy Repository", "User Repository", "Servlet", "Servlet-Filter", "SAML assertion", "DirX Access Server", "DirX Access Manager", "Deployment Manager", "Policy Manager", "Client SDK", "^p", "^p")

' Main code
Application.ScreenUpdating = False

Dim dirNames(20) As String
Dim dirNamesCount As Integer
dirNamesCount = 0

Dim dirName As String
dirName = Dir$(rootPath & "*", vbDirectory)
Do Until LenB(dirName) = 0
    Dim dirPath As String
    dirPath = rootPath & dirName
    If ((GetAttr(dirPath) And vbDirectory) = vbDirectory) And (dirName <> ".") And (dirName <> "..") Then
        dirNamesCount = dirNamesCount + 1
        dirNames(dirNamesCount) = dirPath & "\"
    End If
    dirName = Dir$
Loop

Do While dirNamesCount > 0
    Dim fileName As String
    dirName = dirNames(dirNamesCount)
    dirNamesCount = dirNamesCount - 1
    fileName = Dir$(dirName & "*.doc", vbDirectory)
    Do Until LenB(fileName) = 0
        Dim filePath As String
        filePath = dirName & fileName
        fileName = Dir$

        Dim document As document
        Set document = Documents.Open(filePath)
        document.TrackRevisions = True

        document.Select

        Dim i As Integer, maxIndex As Integer
        maxIndex = UBound(findTextsWild)
        For i = LBound(findTextsWild) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTextsWild(i)
                .Replacement.Text = replaceTextsWild(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchWildcards:=True
            End With
        Next

        maxIndex = UBound(findTexts)
        For i = LBound(findTexts) To maxIndex
            With Selection.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Text = findTexts(i)
                .Replacement.Text = replaceTexts(i)
                .Execute Replace:=wdReplaceAll, Forward:=True, _
                    Wrap:=wdFindContinue, MatchCase:=False, MatchWildcards:=False
            End With
        Next

        document.Save
        document.Close
    Loop
Loop

Application.ScreenUpdating = True
End Sub

Czy nie można tego zrobić w samym programie Microsoft Word?

Jest w menu Edycja (Word 2003) lub na karcie Narzędzia główne / w sekcji Edycja (Word 2007)

http://office.microsoft.com/en-us/word/HA012303921033.aspx

Jeśli nie posiadasz programu Microsoft Word i szukasz bezpłatnej alternatywy, która Ci pomoże, wypróbuj OpenOffice.org .

Nie sądzę, aby ci to pomogło, jeśli szukasz sposobu na zautomatyzowanie tego procesu.

Notepad ++ potrafi to zrobić za pomocą „Znajdź w plikach”

Option Explicit

Public Sub BatchReplaceAll()
    Dim FirstLoop As Boolean
    Dim myFile As String
    Dim PathToUse As String
    Dim myDoc As Document
    Dim Response As Long

    PathToUse = ActiveDocument.Path
    On Error Resume Next
    Documents.Close SaveChanges:=wdPromptToSaveChanges
    FirstLoop = True
    myFile = Dir$(PathToUse & "\*.doc*")

    While myFile <> ""
        Set myDoc = Documents.Open(PathToUse & "\" & myFile)
        If FirstLoop Then
            Application.Dialogs(wdDialogEditReplace).Show
            FirstLoop = False

            Response = MsgBox("Do you want to process the rest of the files in this folder", vbYesNo)
            If Response = vbNo Then Exit Sub
        Else
            With Dialogs(wdDialogEditReplace)
                .ReplaceAll = 1
                .Execute
            End With
        End If
        myDoc.Close SaveChanges:=wdSaveChanges
        myFile = Dir$()
    Wend
End Sub