Czy istnieje sposób wyświetlania wszystkich kształtów używanych w prezentacji Powerpoint?

Pracuję nad prezentacją, która zawiera około 150 połączonych tabel i wykresów. Panel wyboru i widoczności (Narzędzia obrazów> Rozmieść & gt; Okienko wyboru) pozwala mi nazywać i wyświetlać listę wszystkich kształtów na slajdzie, ale czy istnieje opcja podniesienia poziomu i wyświetlenia listy wszystkich kształtów używanych w cała prezentacja?

microsoft-powerpoint

— SuziLmrdo
źródło

Odpowiedzi:

Nie, PowerPoint nie ma żadnej funkcji, która pozwoliłaby ci to zrobić.

Co dokładnie próbujesz osiągnąć? Być może jest jakiś inny sposób.

— Steve Rindsberg
źródło

Firma, dla której pracuję, używa programu PowerPoint jako oprogramowania do publikacji. Jest to dla nich ustalona metoda i nie mam takiego wpływu, aby przekonać cały dział do przejścia na oprogramowanie takie jak Adobe Pagemaker, a nawet Microsoft Word.

— SuziLmrdo

Jednym z moich podstawowych zadań jest tworzenie raportów wraz z wykresami i tabelami, które mają się w nich znaleźć, średnio po 100 cyfr i 50 tabel na publikację. Każdy raport ma średnio około 70-90 stron, więc śledzenie lokalizacji każdej figury w prezentacji jest obecnie bardzo trudne. Chciałbym znaleźć sposób na stworzenie tabeli liczb, która automatycznie aktualizuje lokalizację slajdu w przypadku dodawania lub usuwania slajdów pomiędzy.

— SuziLmrdo

Coś, co zaktualizowałoby się automatycznie, byłoby dość trudne do napisania, ale ponowne utworzenie takiego raportu zajęłoby około minuty. Unikalna identyfikacja każdej tabeli / figury byłaby trudna. Jak możesz zidentyfikować postać na slajdzie 42, aby kod mógł ją rozpoznać i zgłosić użytkownikowi w znaczący sposób?

— Steve Rindsberg

W raporcie nazywam tabele i figury w kolejności ich pojawiania się od góry do dołu, zgodnie z ruchem wskazówek zegara. Przeszedłem już i nazwałem każdy obraz, więc kiedy idę do panelu wyboru slajdu 42, widzę, że zawiera on liczby 74 i 75, a tabela 21 (liczby i tabele są liczone osobno). Różni się to od kolejności, w jakiej zostały utworzone, może to być treść z pytania ankietowego 12 i 66. Gdyby istniał sposób na włączenie danych wejściowych z tekstu alt, mógłby tam być opis każdej figury / tabeli. Czy o to pytasz?

— SuziLmrdo

Raport o linkach jest łatwy. Mam komercyjny dodatek, który pomaga naprawić uszkodzone linki. Bezpłatne demo zawiera raport z linkiem, zawierający listę linków na każdym slajdzie. Nazywa się PTools FixLinks. Za to, o czym mówisz, uważaj to za freebie; wersja płatna nie dodawałaby żadnej wartości w twoim przypadku. pptools.com/fixlinks/index.html

— Steve Rindsberg

Chciałem dostarczyć częściową odpowiedź na moje własne pytanie, oparte na VBA znalezionym w następującym wątku na temat przepełnienia stosu: VBA, aby wyświetlić listę wszystkich nazw obiektów prezentacji Powerpoint

Rozwiązanie to technicznie pozwala osobie przeglądać wszystkie kształty używane w prezentacji Power Point za pomocą raportu pliku tekstowego.

Sub ListAllShapes()

    Dim curSlide As Slide
    Dim curShape As Shape
    Dim lFile As Long
    Dim sPath As String

    sPath = ActivePresentation.Path

    lFile = FreeFile

    Open sPath & "\All Shapes.txt" For Append As #lFile

    For Each curSlide In ActivePresentation.Slides
        Print #lFile, "SLIDE " & curSlide.SlideNumber
        For Each curShape In curSlide.Shapes
                Print #lFile, "    " & curShape.Name
        Next curShape
    Next curSlide

    Close #lFile

End Sub

Spowoduje to wygenerowanie raportu tekstowego, który wygląda tak:

SLIDE 1
    Rectangle 2
    Rectangle 4
    Rectangle 4
    TextBox 10
    Rectangle 4
SLIDE 2
    TextBox 7
    Rectangle 2
    Rectangle 4
    Rectangle 4
    Line 37
    Picture 1
    Picture 2
SLIDE 3
    Rectangle 2
    Rectangle 4
    Rectangle 7
    TextBox 7
    Line 28
    Picture 3
    Picture 4, etc...

W przypadku mojej konkretnej sprawy chciałem listę tylko niektórych kształtów na slajd, którą osiągnąłem, używając najpierw panelu wyboru, aby nazwać każdy obraz zawierający figurę lub tabelę z odpowiednim prefiksem, a następnie uruchamiając to:

Sub ListFiguresAndTables()

    Dim curSlide As Slide
    Dim curShape As Shape
    Dim lFile As Long
    Dim sPath As String

    sPath = ActivePresentation.Path

    lFile = FreeFile

    Open sPath & "\Figures and Tables.txt" For Append As #lFile

    For Each curSlide In ActivePresentation.Slides
        Print #lFile, "SLIDE " & curSlide.SlideNumber
        For Each curShape In curSlide.Shapes
            If Left(curShape.Name, 4) = "Fig." Or Left(curShape.Name, 5) = "Table" Then
                Print #lFile, "    " & curShape.Name
            End If
        Next curShape
    Next curSlide

    Close #lFile

End Sub

Niestety, jedynym sposobem, w jaki makro może wydrukować te obiekty w porządku rosnącym, jest użycie panelu wyboru do ręcznego uporządkowania kształtów w kolejności odwrotnej (malejąco).

SLIDE 1
    Fig. 1
    Fig. 2
    Fig. 3
    Table 1
SLIDE 2
    Fig. 4
    Fig. 5
    Fig. 6  
SLIDE 3
    Table 2
    Table 3 (etc.)

— SuziLmrdo
źródło