Jak ustalić, czy mój system to Windows 10, używając wiersza polecenia? [duplikować]

Pracuję z InstallAnywhere, starym programem do tworzenia instalatorów. Chciałbym zainstalować konkretny plik, tylko w przypadku Windows XP i Windows Vista.

Ze względu na ograniczenia InstallAnywhere nie jest to możliwe. Mogę zdecydować o usunięciu pliku, który został już zainstalowany, na podstawie reguły.

W ramach tej reguły mogę sprawdzić platformę, na której działam, co daje mi możliwość sprawdzenia w systemie Windows XP, Windows Vista, Windows 7 itd., Ale nie w przypadku systemu Windows 10. Nie mogę powiedzieć „Wykonaj to akcja, gdy system nie jest XP lub Vista ”, więc muszę powiedzieć„ Wykonaj tę akcję na wszystkich platformach, które nie są XP ani Vista ”.

Mogę jednak uruchamiać polecenia wiersza polecenia i wychwytywać wynik, więc oto moje pytanie: czy istnieje polecenie, którego mogę użyć do ustalenia, czy pracuję w systemie Windows 10?

Czy istnieje polecenie określające, czy pracuję w systemie Windows 10?

Możesz użyć wmic.

Następujące polecenie zwróci wersję systemu Windows.

wmic os get Caption | findstr /v Caption

Przykładowe dane wyjściowe:

F:\test>wmic os get Caption | findstr /v Caption
Microsoft Windows 7 Home Premium

Jeśli chcesz trochę więcej informacji, możesz użyć następującego pliku wsadowego (GetOS.cmd), który pobierze i wyświetli:

• Wersja systemu operacyjnego
• Wersja główna dodatku Service Pack
• Architektura (64 lub 32 bity)

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
rem get OS
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
rem get Service Pack
for /f "usebackq skip=1 tokens=*" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
rem get Architecture
for /f "usebackq skip=1 tokens=*" %%i in (`wmic OS get OSArchitecture ^| findstr /r /v "^$"`) do (
  set "_bits=%%i"
  )
echo Operating System Version: %_os%
echo Service Pack Major Version: %_sp%
echo Architecture: %_bits%
endlocal

Wersja systemu operacyjnego jest przechowywana w %_os, Service Pack Wersja główna jest przechowywana w %_sp%, a architektura jest przechowywana w %_bits%.

Uwagi:

• Nie do końca przetestowane, ponieważ nie mam wszystkich kombinacji systemu operacyjnego i dodatku Service Pack do przetestowania.

• forPolecenie pobiera tylko w 3. części (Token) systemu operacyjnego. Działa to w przypadku wersji na komputery stacjonarne (jeśli chcesz odróżnić Server 2008 od innych wersji, musisz znaleźć inne rozwiązanie).

• %_oszostanie ustawiony na jedną z następujących wartości: Server, Vista, 7, 8, 8.1lub 10.

Przykładowe dane wyjściowe:

F:\test>GetOS
Operating System Version: 7
Service Pack Major Version: 1
Architecture: 64-bit

F:\test>

Dalsza lektura

• Indeks AZ wiersza polecenia systemu Windows CMD - doskonałe odniesienie do wszystkich rzeczy związanych z wierszem poleceń systemu Windows.
• Findstr - Wyszukaj ciągi znaków - Windows CMD - SS64.com
• For / f- Pętla przez wyjście poleceń - Windows CMD - SS64.com
• Jeśli - Warunkowo wykonaj polecenie - Windows CMD - SS64.com
• WMIC - Zarządzanie Windows - Windows CMD - SS64.com

Nie mogę w to uwierzyć tak długo i nie mam komendy ver

C:\>ver

Microsoft Windows [Version 10.0.10586]

C:\>

Działa w przekierowaniach, więc możesz to zrobić

ver | find "Version 10."

Ale zwykle powinieneś pisać „dla tej i wszystkich przyszłych wersji”, więc lepiej wyliczyć poprzednie.

Informacja o systemie

pobiera wiele przydatnych informacji, takich jak system operacyjny, typ systemu (32/64 bit) i tak długo:

Nie mam doświadczenia z InstallAnywhere, ale istnieją dwie opcje, aby zobaczyć, jaki system operacyjny jest zainstalowany za pomocą wiersza polecenia.

1. Korzystanie z Cmd

   systeminfo.exe
   

   Za pomocą polecenia systeminfo.exemożesz zobaczyć wynik pod polem OS Name. Może to dać więcej informacji, niż potrzebujesz.

   Więcej informacji na temat tego polecenia można znaleźć w witrynie Microsoft TechNet .

2. PowerShell

   Alternatywnie możesz użyć następującego skryptu Powershell, który zwróci dokładne informacje, których potrzebujesz.

   Get-CimInstance Win32_OperatingSystem | Select-Object  Caption | ForEach{ $_.Caption }