Windows Vista: Jak uruchomić program .exe w cmd „As Administrator”

11

Tak, to jest to. Muszę uruchomić program .exe w wierszu dos cmd i musi on działać tak, jak po kliknięciu prawym przyciskiem myszy i wybraniu opcji „uruchom jako administrator”

windows-vista shell command-line

— BinaryMisfit
źródło

Też się nad tym zastanawiałem. Moim rozwiązaniem było albo utworzenie pliku wsadowego za pomocą polecenia i pozwolić, aby zawsze działał jako admin, albo otwarcie cmd jako admin. Ale wydaje się, że powinno być jakieś eleganckie rozwiązanie.

— OregonGhost

15

Windows ma polecenie „runas”, które działa trochę tak jak sudo w systemach Unix-y. Spróbuj wpisać „runas /?” w wierszu polecenia.

— Neall
źródło

Lub zobacz tutaj: technet.microsoft.com/en-us/library/cc771525.aspx

— Asaf R

To nie jest poprawna odpowiedź, chyba że użytkownik Administrator ma włączone niepuste hasło.

— jiggunjer

7

Jeśli uruchomisz cmd jako administrator, wszystko inne, które z niego uruchomisz, również będzie działać. Właśnie skonfigurowałem skrót do wiersza polecenia, który otwiera się jako administrator. Wszystko stąd jest gotowe.

— Kilhoffer
źródło

5

Użyłem duetu skryptu .cmd & .vbs o nazwie elevate, który działa dobrze dla moich potrzeb. Wszystko czego potrzebujesz to pisać

elevate [polecenie]

z Start> Uruchom lub z wiersza poleceń, a polecenie zostanie uruchomione z uprawnieniami administratora. Mam nadzieję, że to pomoże!

Oto Elevate.cmd:

:: //***************************************************************************
:: // ***** Script Header *****
:: //
:: // File:      Elevate.cmd
:: //
:: // Additional files required:  Elevate.vbs
:: //
:: // Purpose:   To provide a command line method of launching applications that
:: //            prompt for elevation (Run as Administrator) on Windows Vista.
:: //
:: // Usage:     elevate.cmd application <application arguments>
:: //
:: // Version:   1.0.0
:: // Date :     01/02/2007
:: //
:: // History:
:: // 1.0.0   01/02/2007  Created initial version.
:: //
:: // ***** End Header *****
:: //***************************************************************************


@echo off

:: Pass raw command line agruments and first argument to Elevate.vbs
:: through environment variables.
set ELEVATE_CMDLINE=%*
set ELEVATE_APP=%1

start wscript //nologo "%~dpn0.vbs" %*

i elevate.vbs:

' //***************************************************************************
' // ***** Script Header *****
' //
' // File:      Elevate.vbs
' //
' // Additional files required:  Elevate.cmd
' //
' // Purpose:   To provide a command line method of launching applications that
' //            prompt for elevation (Run as Administrator) on Windows Vista.
' //
' // Usage:     (Not used directly.  Launched from Elevate.cmd.)
' //
' // Version:   1.0.1
' // Date :     01/03/2007
' //
' // History:
' // 1.0.0   01/02/2007  Created initial version.
' // 1.0.1   01/03/2007  Added detailed usage output.
' //
' // ***** End Header *****
' //***************************************************************************


Set objShell = CreateObject("Shell.Application")
Set objWshShell = WScript.CreateObject("WScript.Shell")
Set objWshProcessEnv = objWshShell.Environment("PROCESS")

' Get raw command line agruments and first argument from Elevate.cmd passed
' in through environment variables.
strCommandLine = objWshProcessEnv("ELEVATE_CMDLINE")
strApplication = objWshProcessEnv("ELEVATE_APP")
strArguments = Right(strCommandLine, (Len(strCommandLine) - Len(strApplication)))

If (WScript.Arguments.Count >= 1) Then
    strFlag = WScript.Arguments(0)
    If (strFlag = "") OR (strFlag="help") OR (strFlag="/h") OR (strFlag="\h") OR (strFlag="-h") _
        OR (strFlag = "\?") OR (strFlag = "/?") OR (strFlag = "-?") OR (strFlag="h") _
        OR (strFlag = "?") Then
        DisplayUsage
        WScript.Quit
    Else
        objShell.ShellExecute strApplication, strArguments, "", "runas"
    End If
Else
    DisplayUsage
    WScript.Quit
End If


Sub DisplayUsage

    WScript.Echo "Elevate - Elevation Command Line Tool for Windows Vista" & vbCrLf & _
                 "" & vbCrLf & _
                 "Purpose:" & vbCrLf & _
                 "--------" & vbCrLf & _
                 "To launch applications that prompt for elevation (i.e. Run as Administrator)" & vbCrLf & _
                 "from the command line, a script, or the Run box." & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage:   " & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate application <arguments>" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate notepad ""C:\Windows\win.ini""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate cmd /k cd ""C:\Program Files""" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command Set-Location 'C:\Windows'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "Usage with scripts: When using the elevate command with scripts such as" & vbCrLf & _
                 "Windows Script Host or Windows PowerShell scripts, you should specify" & vbCrLf & _
                 "the script host executable (i.e., wscript, cscript, powershell) as the " & vbCrLf & _
                 "application." & vbCrLf & _
                 "" & vbCrLf & _
                 "Sample usage with scripts:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate wscript ""C:\windows\system32\slmgr.vbs"" –dli" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate powershell -NoExit -Command & 'C:\Temp\Test.ps1'" & vbCrLf & _
                 "" & vbCrLf & _
                 "" & vbCrLf & _
                 "The elevate command consists of the following files:" & vbCrLf & _
                 "" & vbCrLf & _
                 "    elevate.cmd" & vbCrLf & _
                 "    elevate.vbs" & vbCrLf

End Sub

— kolrie
źródło

Ciekawe, jaka jest przewaga tego nad runami?

— tfinniga

Hه! Masz mnie! :) Nie poznałbym przewagi nad runami, ale jeśli nie znasz run, jest to jedyna alternatywa. Jestem zdecydowanie zawstydzony :)

Myślę, że pomogłoby to, gdybyśmy raz przeczytali to, czego używamy jako skrypt!

1

Ten duet jest opisany na technet.microsoft.com/en-us/magazine/...

2

Niewątpliwą zaletą skryptu Elevate jest to, że umożliwiają podniesienie użytkownika do poziomu administratora pod kontrolą konta użytkownika bez konieczności podawania użytkownika administratora i hasła (pod warunkiem, że użytkownik jest zalogowany jako administrator). Czy może to zrobić runas.exe?

3

Musisz użyć polecenia RunAs.exe.

Oto kilka instrukcji: http://www.softtreetech.com/24x7/archive/53.htm

— Gthompson83
źródło

RunAs jest niepoprawny. Nie podnosi polecenia.

— surfasb

2

Możesz także nacisnąć klawisz Windows, wpisać CMD, wyświetli to cmd w programach, kliknij go prawym przyciskiem myszy -> Właściwości -> Zgodność -> Uruchom ten program jako administrator

To zawsze będzie działać jako administrator.

— Listonosz
źródło

Możesz także użyć Ctrl + Shift + Enter.

— Joey,

1

Ponieważ ktoś opublikował odpowiednik VBS, oto funkcja Invoke-Admin dla PowerShell

function Invoke-Admin() {
param ( [string]$program = $(throw "Please specify a program" ),
        [string]$argumentString = "",
        [switch]$waitForExit )

$psi = new-object "Diagnostics.ProcessStartInfo"
$psi.FileName = $program 
$psi.Arguments = $argumentString
$psi.Verb = "runas"
$proc = [Diagnostics.Process]::Start($psi)
if ( $waitForExit ) {
    $proc.WaitForExit();
}

}

— JaredPar
źródło

0

W skrócie:

Kliknij / naciśnij Start, a następnie CTRL + SHIFT i ENTER. Potwierdzać.

Szczegółowo:

Naciśnij natychmiast przycisk Start Wpisz „cmd” (bez cudzysłowów) (1)
Przytrzymaj CTRL i SHIFT
Naciśnij enter
Potwierdź okno dialogowe UAC systemu Windows Vista

(1) Natychmiast oznacza wpisanie go w polu wyszukiwania, a nie w polu Uruchom.

— Mackaaij
źródło

0

Możesz użyć VBScript jako takiego. Utwórz .vbsplik, np . ambika.vbs:

Set objShell = CreateObject(“Shell.Application”)
Set objWshShell = WScript.CreateObject(“WScript.Shell”)
Set objWshProcessEnv = objWshShell.Environment(“PROCESS”)

objShell.ShellExecute “C:\Windows\system32\cmd.exe”, “/k”, “”, “runas”

— Ambika Singh
źródło