Eksportować arkusz kalkulacyjny Excel do pliku tekstowego o stałej szerokości?

Excel ma funkcję importowania plików tekstowych o stałej szerokości, w których wyświetla okno dialogowe, które pozwala wybrać, gdzie są początki i końce pól, które umieszcza w kolumnach.

Czy ma również funkcję, w której przy istniejącym arkuszu kalkulacyjnym można eksportować do pliku tekstowego o stałej szerokości?

Jeśli tak, jak mogę uzyskać do tego dostęp? Próbowałem użyć opcji Zapisz jako i wybrania pliku tekstowego, ale wydaje się, że zapisuje się tylko jako znak rozdzielany tabulatorami, co mi nie pomaga.

To Excel 2003, jeśli ma to znaczenie.

Myślę, że najbliższą dostępną funkcją natywnego programu Excel jest Zapisz jako | Tekst sformatowany (rozdzielany spacjami) (* .prn) . Automatycznie określi szerokości i wstawi spacje do tej szerokości w razie potrzeby.

Poza tym musisz mieć makro lub inny dodatek, który pozwoli ci zrobić więcej.

Jeśli masz pakiet Office Professional, możesz otworzyć plik Excel w programie Access, a następnie Eksportuj z programu Access. Access pozwoli ci określić układ stałej szerokości dla eksportowanego pliku i zapewni ci bardzo szczegółowe kontrolki do określania tych szerokości.

Wow, chciałem sam zadać to pytanie, ale zostało już zadane. Wszystkie dane wyjściowe ze schowka programu Excel są tabdomyślnie ograniczone. Jest to trochę denerwujące dla „prawdziwego” tekstu wyjściowego, gdy masz czcionkę o stałej szerokości, ale niekoniecznie obsługuje ogranicznik tabulatorów.

W każdym razie znalazłem i zmodyfikowałem małe makro Excela, które skopiuje aktualnie wybrany region jako prostą tabelę kolumn ASCII o stałej szerokości - tak:

187712 201 37 0,18   
2525 580 149 0,25   
136829 137 43 0,31   

Oto kod makra. Aby z niego skorzystać, należy włączyć kartę Deweloper w Opcjach programu Excel, jeśli używasz programu Excel 2007 lub nowszego.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Najpierw sformatuj dane jako Courier New (lub inną czcionkę o stałej szerokości). Następnie zapisz jako .prn, a otrzymasz prawdziwą stałą szerokość.

Rozwijając odpowiedź Jeffa Atwooda, ponieważ nie pozwoliłbym jej tam skomentować:

Zmodyfikowałem jego makro, aby ustawić szerokość kolumny na najszerszą komórkę w tej kolumnie i aby każda kolumna miała własną szerokość. Jego makro znalazło tylko najszerszą komórkę w pierwszym rzędzie, a następnie ustawiło do niej szerokość wszystkich kolumn.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

To jest dla mnie zabójca. Ma również kilka opcji.

http://www.sensefulsolutions.com/2010/10/format-text-as-table.html

Działa z Access po wyjęciu z pudełka: https://support.office.com/en-ie/article/export-data-to-a-text-file-f72dfc38-a8a0-4c5b-8c2c-bf2950814140#bmsteps z tym sposób, w jaki zarządzałem, jest dość łatwy i szybki - lepszy niż w programie Excel. W moim przypadku była to konwersja tabeli.