Terraform - Użyj zagnieżdżonych pętli z liczbą

Próbuję użyć zagnieżdżonej pętli w terraformie. Mam dwie zmienne listy list_of_allowed_accountsi list_of_images, i szukam iteracji po liście, list_of_imagesa następnie iteracji po liście list_of_allowed_accounts.

Oto mój kod terraform.

variable "list_of_allowed_accounts" {
  type    = "list"
  default = ["111111111", "2222222"]
}

variable "list_of_images" {
  type    = "list"
  default = ["alpine", "java", "jenkins"]
}

data "template_file" "ecr_policy_allowed_accounts" {
  template = "${file("${path.module}/ecr_policy.tpl")}"

  vars {
    count = "${length(var.list_of_allowed_accounts)}"
    account_id = "${element(var.list_of_allowed_accounts, count.index)}"
  }
}

resource "aws_ecr_repository_policy" "repo_policy_allowed_accounts" {
  count = "${length(var.list_of_images)}"
  repository = "${element(aws_ecr_repository.images.*.id, count.index)}"
  count = "${length(var.list_of_allowed_accounts)}"
  policy = "${data.template_file.ecr_policy_allowed_accounts.rendered}"
}

To jest odpowiednik tego, co próbuję zrobić.

for image in alpine java jenkins
do 
  for account_id in 111111111 2222222
  do 
    // call template here using variable 'account_id' and 'image'
  done
done

Terraform nie ma bezpośredniego wsparcia dla tego rodzaju zagnieżdżonej iteracji, ale możemy ją sfałszować za pomocą pewnej arytmetyki.

variable "list_of_allowed_accounts" {
  type = "list"
  default = ["1111", "2222"]
}

variable "list_of_images" {
  type = "list"
  default = ["alpine", "java", "jenkins"]
}

data "template_file" "ecr_policy_allowed_accounts" {
  count = "${length(var.list_of_allowed_accounts) * length(var.list_of_images)}"

  template = "${file("${path.module}/ecr_policy.tpl")}"

  vars {
    account_id = "${var.list_of_allowed_accounts[count.index / length(var.list_of_images)]}"
    image      = "${var.list_of_images[count.index % length(var.list_of_images)]}"
  }
}

resource "aws_ecr_repository_policy" "repo_policy_allowed_accounts" {
  count = "${data.template_file.ecr_policy_allowed_accounts.count}"

  repository = "${var.list_of_images[count.index % length(var.list_of_images)]}"
  policy = "${data.template_file.ecr_policy_allowed_accounts.*.rendered[count.index]}"
}

Ponieważ chcemy, aby utworzyć szablon zasad dla każdej kombinacji rozliczeniowej i obrazu, countw template_filebloku danych jest dwa zwielokrotniony razem. Następnie możemy użyć operacji dzielenia i modulo, aby wrócić count.indexdo osobnych indeksów na każdej liście.

Ponieważ nie miałem kopii twojego szablonu polisy, właśnie użyłem zastępczego; ta konfiguracja dała następujący plan:

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.0
    policy:     "policy allowing 1111 to access alpine"
    repository: "alpine"

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.1
    policy:     "policy allowing 1111 to access java"
    repository: "java"

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.2
    policy:     "policy allowing 1111 to access jenkins"
    repository: "jenkins"

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.3
    policy:     "policy allowing 2222 to access alpine"
    repository: "alpine"

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.4
    policy:     "policy allowing 2222 to access java"
    repository: "java"

+ aws_ecr_respository_policy.repo_policy_allowed_accounts.5
    policy:     "policy allowing 2222 to access jenkins"
    repository: "jenkins"

Każda instancja zasad dotyczy innej pary identyfikatora konta i obrazu, obejmujących wszystkie kombinacje.

Odpowiedzi tutaj działają (początkowo ich użyłem), ale myślę, że mam lepsze rozwiązanie, korzystając z funkcji setproduct firmy Terraform . Nie widziałem wielu przykładów tego użytych w interwebach, ale setproduct bierze dwa zestawy (a co ważniejsze, dwie listy) i tworzy listę zestawów przy każdej permutacji danych wejściowych. W moim przypadku tworzę parametry SSM:

variable "list1" {
  type    = "list"
  default = ["outer1", "outer2"]
}

variable "list2" {
  type    = "list"
  default = ["inner1", "inner2", "inner3"]
}

locals {
  product = "${setproduct(var.list1, var.list2)}"
}

resource "aws_ssm_parameter" "params" {
  count     = "${length(var.list1) * length(var.list2)}"
  name      = "/${element(local.product, count.index)[0]}/${element(local.product, count.index)[1]}"
  type      = "String"
  value     = "somevalue"
  overwrite = false
  lifecycle { ignore_changes = ["value"] }
}

To tworzy parametry SSM o nazwie:

/outer1/inner1
/outer1/inner2
/outer1/inner3
/outer2/inner1
/outer2/inner2
/outer2/inner3

Mój wątły mózg może przeanalizować to trochę łatwiej niż magia modulo w innych odpowiedziach!

Do Twojej wiadomości, jeśli ktoś przyjdzie tutaj z Google, jeśli używasz terraformu 0.12, będziesz musiał użyć funkcji floor w dowolnym miejscu, w którym się podzielisz, w przeciwnym razie pojawi się błąd dotyczący indeksów częściowych.

account_id = var.list_of_allowed_accounts [ floor (count.index / length (var.list_of_images))]

Zasadniczo problem tkwi w danych „file_file”, identyfikator_konta nie może być ustawiony tak, jak myślisz, ponieważ będzie to kolejna zmienna, która nigdy nie zostanie zwiększona / zmieniona. Tylko mówię, skoro tęsknię za tym, aby dokładnie zobaczyć, jakie jest twoje pytanie.

Nie mam wystarczającej liczby punktów reputacji, aby dodać komentarz do odpowiedzi udzielonej przez @ Martina Atkinsa , więc zamieszczam jego odpowiedź z niewielką modyfikacją, która działa wokół numeru Terraform 20567

variable "list_of_allowed_accounts" {
  type = "list"
  default = ["1111", "2222"]
}

variable "list_of_images" {
  type = "list"
  default = ["alpine", "java", "jenkins"]
}

# workaround for TF issue https://github.com/hashicorp/terraform/issues/20567
locals {
  policy_count = "${length(var.list_of_allowed_accounts) * length(var.list_of_images)}"
}

data "template_file" "ecr_policy_allowed_accounts" {
  count = "${local.policy_count}"

  template = "${file("${path.module}/ecr_policy.tpl")}"

  vars {
    account_id = "${var.list_of_allowed_accounts[count.index / length(var.list_of_images)]}"
    image      = "${var.list_of_images[count.index % length(var.list_of_images)]}"
  }
}

resource "aws_ecr_repository_policy" "repo_policy_allowed_accounts" {
  count = "${local.policy_count}"

  repository = "${var.list_of_images[count.index % length(var.list_of_images)]}"
  policy = "${data.template_file.ecr_policy_allowed_accounts.*.rendered[count.index]}"
}