Używam git jako kopii zapasowej dla mojego systemu Windows, i było to niezwykle przydatne. W dolnej części postu pokazuję skrypty, których używam do konfiguracji w systemie Windows. Używanie git jako kopii zapasowej dla dowolnego systemu zapewnia 2 duże zalety:
- W przeciwieństwie do komercyjnych rozwiązań często używających własnego zastrzeżonego formatu, twoja kopia zapasowa jest w formacie open source, który jest szeroko obsługiwany i bardzo dobrze udokumentowany. Zapewnia to pełną kontrolę nad danymi. Bardzo łatwo jest sprawdzić, które pliki uległy zmianie i kiedy. Jeśli chcesz obciąć swoją historię, możesz to zrobić. Chcesz wymazać coś ze swojej historii? Nie ma problemu. Odzyskanie wersji pliku jest tak proste, jak każde polecenie git.
- Tyle kopii lustrzanych, ile chcesz, i wszystkie mogą mieć niestandardowe czasy tworzenia kopii zapasowych. Otrzymasz lokalne lustro, które nie jest obciążone powolnym ruchem internetowym, a tym samym daje (1) możliwość częstszych kopii zapasowych w ciągu dnia i (2) szybki czas przywracania. (Częste kopie zapasowe to ogromny plus, ponieważ uważam, że najwięcej czasu tracę dokument z powodu błędu użytkownika. Na przykład twoje dziecko przypadkowo nadpisuje dokument, nad którym pracował przez ostatnie 5 godzin.) zdalne lustro, które zapewnia ochronę danych w przypadku lokalnej katastrofy lub kradzieży. Przypuśćmy, że chcesz tworzyć kopie zapasowe zdalnego lustra w niestandardowym czasie, aby zaoszczędzić przepustowość Internetu? Nie ma problemu.
Konkluzja: Kopia zapasowa git zapewnia niewiarygodne możliwości kontrolowania sposobu tworzenia kopii zapasowych.
Skonfigurowałem to w moim systemie Windows. Pierwszym krokiem jest utworzenie lokalnego repozytorium git, w którym będziesz zatwierdzać wszystkie swoje lokalne dane. Zalecam użycie lokalnego drugiego dysku twardego, ale korzystanie z tego samego dysku twardego będzie działało (ale spodziewane jest, że wciśniesz go gdzieś zdalnie lub inaczej wkręcisz się, jeśli dysk twardy umrze).
Najpierw musisz zainstalować cygwin (z rsync), a także zainstalować git dla Windows: http://git-scm.com/download/win
Następnie utwórz lokalne repozytorium git (uruchom tylko raz):
init-repo.bat:
@echo off
REM SCRIPT PURPOSE: CREATE YOUR LOCAL GIT-REPO (RUN ONLY ONCE)
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM Create the backup git repo.
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
mkdir %GBKUP_LOCAL_MIRROR_HOME%
git %GIT_PARAMS% init
git %GIT_PARAMS% config core.autocrlf false
git %GIT_PARAMS% config core.ignorecase false
git %GIT_PARAMS% config core.fileMode false
git %GIT_PARAMS% config user.email backup@yourComputerName
git %GIT_PARAMS% config user.name backup
REM add a remote to the git repo. Make sure you have set myRemoteServer in ~/.ssh/config
REM The path on the remote server will vary. Our remote server is a Windows machine running cygwin+ssh.
REM For better security, you could install gitolite on the remote server, and forbid any non-fast-forward merges, and thus stop a malicious user from overwriting your backups.
git %GIT_PARAMS% remote add origin myRemoteServer:/cygdrive/c/backup/yourComputerName.git
REM treat all files as binary; so you don't have to worry about autocrlf changing your line endings
SET ATTRIBUTES_FILE=%GBKUP_LOCAL_MIRROR_HOME%\.git\info\attributes
echo.>> %ATTRIBUTES_FILE%
echo *.gbkuptest text>> %ATTRIBUTES_FILE%
echo * binary>> %ATTRIBUTES_FILE%
REM compression is often a waste of time with binary files
echo * -delta>> %ATTRIBUTES_FILE%
REM You may need to get rid of windows new lines. We use cygwin's tool
C:\cygwin64\bin\dos2unix %ATTRIBUTES_FILE%
Następnie mamy nasze opakowanie skryptu kopii zapasowej, które będzie regularnie wywoływane przez program planujący systemu Windows:
gbackup.vbs:
' A simple vbs wrapper to run your bat file in the background
Set oShell = CreateObject ("Wscript.Shell")
Dim strArgs
strArgs = "cmd /c C:\opt\gbackup\gbackup.bat"
oShell.Run strArgs, 0, false
Następnie mamy sam skrypt kopii zapasowej wywoływany przez opakowanie:
gbackup.bat:
@echo off
REM Set where the git repository will be stored
SET GBKUP_LOCAL_MIRROR_HOME=E:\backup\mirror
REM the user which runs the scheduler
SET GBKUP_RUN_AS_USER=yourWindowsUserName
REM exclude file
SET GBKUP_EXCLUDE_FILE=/cygdrive/c/opt/gbackup/exclude-from.txt
SET GBKUP_TMP_GIT_DIR_NAME=git-renamed
for /f "delims=" %%i in ('C:\cygwin64\bin\cygpath %GBKUP_LOCAL_MIRROR_HOME%') do set GBKUP_LOCAL_MIRROR_CYGWIN=%%i
REM rename any .git directories as they were (see below command)
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (%GBKUP_TMP_GIT_DIR_NAME%) do ren "%%i" ".git" 2> nul
SET RSYNC_CMD_BASE=C:\cygwin64\bin\rsync -ahv --progress --delete --exclude-from %GBKUP_EXCLUDE_FILE%
REM rsync all needed directories to local mirror
%RSYNC_CMD_BASE% /cygdrive/c/dev %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/asmith %GBKUP_LOCAL_MIRROR_CYGWIN%
%RSYNC_CMD_BASE% /cygdrive/c/Users/bsmith %GBKUP_LOCAL_MIRROR_CYGWIN%
cacls %GBKUP_LOCAL_MIRROR_HOME% /t /e /p %GBKUP_RUN_AS_USER%:f
REM rename any .git directories as git will ignore the entire directory, except the main one
for /r %GBKUP_LOCAL_MIRROR_HOME% %%i in (.git) do ren "%%i" "%GBKUP_TMP_GIT_DIR_NAME%" 2> nul
ren %GBKUP_LOCAL_MIRROR_HOME%\%GBKUP_TMP_GIT_DIR_NAME% .git
REM finally commit to git
SET GIT_PARAMS=--git-dir=%GBKUP_LOCAL_MIRROR_HOME%\.git --work-tree=%GBKUP_LOCAL_MIRROR_HOME%
SET BKUP_LOG_FILE=%TMP%\git-backup.log
SET TO_LOG=1^>^> %BKUP_LOG_FILE% 2^>^&1
echo ===========================BACKUP START=========================== %TO_LOG%
For /f "tokens=2-4 delims=/ " %%a in ('date /t') do (set mydate=%%c-%%a-%%b)
For /f "tokens=1-2 delims=/:" %%a in ('time /t') do (set mytime=%%a%%b)
echo %mydate%_%mytime% %TO_LOG%
echo updating git index, committing, and then pushing to remote %TO_LOG%
REM Caution: The --ignore-errors directive tells git to continue even if it can't access a file.
git %GIT_PARAMS% add -Av --ignore-errors %TO_LOG%
git %GIT_PARAMS% commit -m "backup" %TO_LOG%
git %GIT_PARAMS% push -vv --progress origin master %TO_LOG%
echo ===========================BACKUP END=========================== %TO_LOG%
Mamy plik exclude-from.txt, w którym wszystkie pliki ignorujemy:
exclude-from.txt:
target/
logs/
AppData/
Downloads/
trash/
temp/
.idea/
.m2/
.IntelliJIdea14/
OLD/
Searches/
Videos/
NTUSER.DAT*
ntuser.dat*
Musisz udać się na dowolne repozytorium i zrobić na nich „git init --bare”. Możesz przetestować skrypt, wykonując skrypt kopii zapasowej. Zakładając, że wszystko działa, przejdź do Windows Scheduler i wskaż cogodzinną kopię zapasową w kierunku pliku vbs. Następnie co godzinę będziesz mieć historię swojego komputera. Jest to niezwykle wygodne - każdy przypadkowo usuwa fragment tekstu i tęsknisz? Po prostu sprawdź swoje repozytorium git.