jak uzyskać własny pid procesu z wiersza polecenia w systemie Windows

próbuję znaleźć sposób na uzyskanie własnego PID z wiersza polecenia (do późniejszego użycia w skryptach nietoperzy) do tej pory jedynym przydatnym sposobem, jaki znalazłem, było użycie getpids.exe tutaj: http://www.scheibli.com/ projects / getpids / index.html, ale szukam polecenia „wbudowanego” w Windows

edit: szukam "kuloodpornego" sposobu - nie zakładam, że mój proces jest jedynym cmd.exe lub czymkolwiek

Ponieważ żadne z pozostałych rozwiązań nie jest kuloodporne i wbudowane, pomyślałem, że zaoferuję następujące rozwiązanie, ale pamiętaj, że będziesz musiał jakoś przeanalizować / zapisać wyniki:

title mycmd
tasklist /v /fo csv | findstr /i "mycmd"

Uważam, że poniższe informacje są kuloodporne, pod warunkiem, że użytkownik ma dostęp do WMIC i TEMP wskazuje prawidłową ścieżkę, w której użytkownik ma uprawnienia do zapisu. Jest to wynik końcowy wspólnej pracy pod adresem http://www.dostips.com/forum/viewtopic.php?f=3&t=6133 .

@echo off

:getPID  [RtnVar]
::
:: Store the Process ID (PID) of the currently running script in environment variable RtnVar.
:: If called without any argument, then simply write the PID to stdout.
::
setlocal disableDelayedExpansion
:getLock
set "lock=%temp%\%~nx0.%time::=.%.lock"
set "uid=%lock:\=:b%"
set "uid=%uid:,=:c%"
set "uid=%uid:'=:q%"
set "uid=%uid:_=:u%"
setlocal enableDelayedExpansion
set "uid=!uid:%%=:p!"
endlocal & set "uid=%uid%"
2>nul ( 9>"%lock%" (
  for /f "skip=1" %%A in (
    'wmic process where "name='cmd.exe' and CommandLine like '%%<%uid%>%%'" get ParentProcessID'
  ) do for %%B in (%%A) do set "PID=%%B"
  (call )
))||goto :getLock
del "%lock%" 2>nul
endlocal & if "%~1" equ "" (echo(%PID%) else set "%~1=%PID%"
exit /b

Skrypt ustanawia wyłączną blokadę pliku tymczasowego, który uwzględnia aktualny czas w nazwie. Kolizja może nastąpić tylko wtedy, gdy dwa podobnie nazwane procesy wsadowe spróbują uzyskać PID w tym samym przedziale czasowym 0,01 sekundy, w którym to przypadku tylko jeden się powiedzie.

Każdy proces, który się nie powiedzie, będzie wielokrotnie zapętlać i próbować ponownie z nową ścieżką do pliku blokady, dopóki się nie powiedzie.

Pełna ścieżka do pliku blokady jest przekształcana w unikalny identyfikator, którego można użyć w zapytaniu WMIC. WMIC jest uruchamiany w poleceniu FOR / F, co oznacza, że ​​działa w potomnym procesie cmd.exe. Dlatego pobierany jest ParentProcessID procesu cmd.exe.

Rozwijając odpowiedź Tony'ego Rotha:

title uniqueTitle
for /f "tokens=2 USEBACKQ" %f IN (`tasklist /NH /FI "WINDOWTITLE eq uniqueTitle*"`) Do echo %f

Użycie filtra WINDOWTITLE pozwala uniknąć potoku, dzięki czemu można umieścić go w pętli for i przypisać do zmiennej za pomocą SET, jeśli chcesz:

title uniqueTitle
for /f "tokens=2 USEBACKQ" %f IN (`tasklist /NH /FI "WINDOWTITLE eq uniqueTitle*"`) Do set ourPID=%f

Usunięcie /vpowoduje, że jest szybszy, a /NHpozbywa się linii nagłówka. Potrzebny będzie symbol wieloznaczny po, "uniqueTitle"ponieważ tytuł okna faktycznie zawiera bieżące polecenie (a więc będzie się wyświetlać i włączać, jeśli spróbujesz go w pełni dopasować).

Korzystanie z PowerShell + WMI:

powershell (Get-WmiObject Win32_Process -Filter ProcessId=$PID).ParentProcessId

1. Menedżer zadań Windows, musisz przejść do Widok -> Wybierz kolumny .. i wybrać PID.
2. „tasklist / v”, aby uzyskać szczegółowe informacje o zadaniu w wierszu polecenia.
3. Process Explorer z live.sysinternals.com .

jeśli wiesz, że działa tylko jeden plik cmd.exe, możesz uzyskać PID w ten sposób:

for /F "tokens=1,2" %%i in ('tasklist /FI "IMAGENAME eq cmd.exe" /fo table /nh') do set pid=%%j

echo %pid%

To powinno załatwić sprawę:

tasklist / v

Jeśli chcesz znaleźć PID imagename „notepad.exe”, następujący kod będzie dla Ciebie działał:

for /F "tokens=1,2" %i in ('tasklist') do (
 if "%i" equ "notepad.exe" (set x=%j)
)
echo %x%

Jeśli masz zestaw Windows 2003 Resource Kit, przepchnij go przez qgrep, aby uzyskać żądaną linię. Następnie możesz wyodrębnić pid stąd (zakłada to, że masz tylko jeden cmd na raz),

tasklist /v | qgrep cmd

cmd.exe 2040 RDP-Tcp#447 0 1,804 K Running MACHINE\Administrator  0:00:00 Command Prompt

Spójrz na tę małą sztuczkę partii . Ustawia tytuł cmd na specjalną wartość, a następnie używa tasklist, aby go znaleźć. Wynalazczy

\\ Greg

TO KRÓTKI SPOSÓB UZYSKANIA ID PROCESU DLA OPEN CMD

tasklist /v /fi "imagename EQ cmd.exe" /FO LIST | FIND "PID:"

Ta odpowiedź da TYLKO identyfikator procesu i żadna z dodatkowych rzeczy, które zawiera najlepsza odpowiedź.

title mycmd
tasklist /v /fo csv | findstr /i "mycmd" > PIDinfo.txt

set /p PIDinfo=<PIDinfo.txt
set PID1=%PIDinfo:~11,5%
set PID2=%PIDinfo:~11,4%

if %PID2% gtr 8100 (
    set PID=%PID2%
) else (
    set PID=%PID1%
)

echo %PID%

Wyjaśnienie:

- nie będzie PID dla cmd.exe, który jest większy niż 18100, więc sprawdź, czy PID2 jest większy niż 8100, więc wiemy, czy jest to 4 lub 5 cyfr

przypadek 1: 5-cyfrowy PID jak 17504 ma PID1 val 17504 i PID2 val 1750, więc używamy PID1

przypadek 2: 4-cyfrowy PID jak 8205 ma wartość PID1 8205 "i wartość PID2 8205, więc używamy PID2

przypadek 3: 4-cyfrowy PID jak 4352 ma wartość PID1 4352 "i wartość PID2 4352, więc używamy PID2