Wygląda na to, że równania, z którymi masz do czynienia, są wielomianowe po usunięciu mianowników. To dobrze (funkcje transcendentalne są często nieco trudniejsze do algebraicznie). Nie jest to jednak gwarancją, że twoje równania mają rozwiązanie w formie zamkniętej. Jest to istotny punkt, którego wielu ludzi tak naprawdę „nie rozumie”, nawet jeśli znają to w teorii, więc trzeba to powtórzyć: istnieją dość proste układy równań wielomianowych, dla których nie ma możliwości podania rozwiązań w kategoriach (nth) root itp. Słynny przykład (w jednej zmiennej) to x5−x+1=0. Zobacz także tę stronę wikipedii .
To powiedziawszy, oczywiście istnieją również układy równań, które można rozwiązać, i warto sprawdzić, czy twój układ jest jednym z nich. I nawet jeśli twojego układu nie da się rozwiązać, nadal może być możliwe znalezienie formy układu równań, która jest w pewnym sensie prostsza. Na przykład znajdź jedno równanie obejmujące tylko pierwszą zmienną (nawet jeśli nie można go rozwiązać algebraicznie), a następnie drugie równanie obejmujące tylko pierwszą i drugą zmienną itp. Istnieje kilka konkurencyjnych teorii na temat znajdowania takich „normalnych form” układów wielomianowych; najbardziej znana jest teoria podstawowa Groebnera, a konkurencyjna to teoria regularnych łańcuchów.
W systemie algebry komputerowej Maple (pełne ujawnienie: pracuję dla nich) oba są zaimplementowane. Wydaje mi się, że to solvepolecenie zwykle wywołuje metodę Groebnera, co szybko zatrzymuje się na moim laptopie. Próbowałem uruchomić regularne obliczanie łańcuchów i trwa to dłużej niż mam cierpliwość, ale wydaje się, że nie jest tak kiepskie pod względem pamięci. Jeśli jesteś zainteresowany, strona pomocy dla polecenia, którego użyłem, jest tutaj , a oto kod, którego użyłem:
restart;
sys, vars := {theta*H - rho_p*sigma_p*
Cp*(Us/N) - rho_d*sigma_d*D*(Us/N)*rho_a*sigma_a*
Ca*(Us/N) = 0,
rho_p*sigma_p*Cp*(Us/N) + rho_d*sigma_d*
D*(Us/N)*rho_a*sigma_a*Ca*(Us/N) + theta*H = 0,
(1/omega)*Ua - alpha*Up - rho_p*psi_p*
Up*(H/N) - Mu_p*sigma_p*Up*(Cp/N) -
Mu_a*sigma_a*Up*(Ca/N) - Theta_p*
Up + Nu_up*(Theta_*M + Zeta_*D) = 0,
alpha*Up - (1/omega)*Ua - rho_a*psi_a*
Ua*(H/N) - Mu_p*sigma_p*Ua*(Cp/N) -
Mu_a*sigma_a*Ua*(Ca/N) - Theta_a*
Ua + Nu_ua*(Theta_*M + Zeta_*D) = 0,
(1/omega)*Ca + Gamma_*Phi_*D + rho_p*psi_p*
Up*(H/N) + Mu_p*sigma_p*Up*(Cp/N) +
Mu_a*sigma_a*Up*(Ca/N) - alpha*Cp - Kappa_*
Cp - Theta_p*Cp + Nu_cp*(Theta_*M + Zeta_*D) = 0,
alpha*Cp + Gamma_*(1 - Phi_)*D + rho_a*psi_a*
Ua*(H/N) + Mu_p*sigma_p*Ua*(Cp/N) +
Mu_a*sigma_a*Ua*(Ca/N) - (1/omega)*
Ca - Kappa_*Tau_*Ca - Theta_a*Ca +
Nu_ca*(Theta_*M + Zeta_*D) =
0, Kappa_*Cp + Kappa_*Tau_*Ca - Gamma_*Phi_*
D - Gamma_*(1 - Phi_)*D -
Zeta_*D + Nu_d*(Theta_*M + Zeta_*D) = 0,
Us + H + Up + Ua + Cp + Ca + D = 0,
Up + Ua + Cp + Ca + D = 0}, {Us, H, Up, Ua, Cp, Ca, D, N,
M}:
sys := subs(D = DD, sys):
vars := subs(D = DD, vars):
params := indets(sys, name) minus vars:
ineqs := [theta > 0 , rho_p > 0 , sigma_p >
0 , rho_d > 0 , sigma_d > 0 ,
rho_a > 0 , sigma_a > 0 ,
omega > 0 , alpha > 0 , psi_p > 0 , Mu_p > 0 ,
Mu_a > 0 , Theta_p > 0 , Nu_up > 0 , Theta_ >
0 , Zeta_ > 0 , psi_a > 0 ,
Theta_a > 0 , Nu_ua > 0 , Gamma_ > 0 , Phi_ >
0 , Kappa_ > 0 , Nu_cp > 0 ,
Tau_ > 0 , Nu_ca > 0]:
with(RegularChains):
R := PolynomialRing([vars[], params[]]):
sys2 := map(numer, map(lhs - rhs, normal([sys[]]))):
sol := LazyRealTriangularize(sys2,[],map(rhs, ineqs),[],R);
