CMake: wydrukuj wszystkie dostępne zmienne w skrypcie

Zastanawiam się, czy istnieje sposób wydrukowania wszystkich dostępnych zmiennych w CMake. Nie interesują mnie zmienne CMake - jak w --help-variablesopcji. Mówię o moich zmiennych, które zdefiniowałem lub zmiennych zdefiniowanych przez dołączone skrypty.

Obecnie obejmuję:

INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)

Miałem nadzieję, że uda mi się po prostu wydrukować wszystkie zmienne, które tu są, zamiast przeglądać wszystkie pliki i czytać, co było dostępne - może się okazać, że niektóre zmienne, o których nie wiedziałem, mogą być przydatne. Dobrze byłoby pomóc w nauce i odkrywaniu. Służy wyłącznie do debugowania / programowania.

Jest to podobne do pytania w Drukuj wszystkie zmienne lokalne dostępne dla bieżącego zakresu w Lua , ale dla CMake!

Czy ktoś to zrobił?

Za pomocą get_cmake_propertyfunkcji następująca pętla wypisze wszystkie zdefiniowane zmienne CMake i ich wartości:

get_cmake_property(_variableNames VARIABLES)
list (SORT _variableNames)
foreach (_variableName ${_variableNames})
    message(STATUS "${_variableName}=${${_variableName}}")
endforeach()

Może to być również osadzone w funkcji wygody, która może opcjonalnie użyć wyrażenia regularnego, aby wydrukować tylko podzbiór zmiennych o pasujących nazwach

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)
            string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

Aby wydrukować zmienne środowiskowe, użyj trybu poleceń CMake :

execute_process(COMMAND "${CMAKE_COMMAND}" "-E" "environment")

Innym sposobem jest po prostu użycie:

cmake -LAH

Z strony podręcznika :

-L[A][H]

Wyświetla listę niewykorzystanych zmiennych buforowanych.

Lista zmiennych pamięci podręcznej uruchomi CMake i wyświetli listę wszystkich zmiennych z pamięci podręcznej CMake, które nie są oznaczone jako INTERNALlub ADVANCED. Skutecznie wyświetli bieżące ustawienia CMake [...].

Jeśli Ajest określony, wyświetli również zmienne zaawansowane.

Jeśli H jest określony, wyświetli również pomoc dla każdej zmiennej.

ccmakejest dobrą interaktywną opcją do interaktywnej kontroli buforowanych zmiennych ( option(lub set( CACHE:

sudo apt-get install cmake-curses-gui
mkdir build
cd build
cmake ..
ccmake ..