TSQL - Jak używać GO wewnątrz bloku BEGIN .. END?

Generuję skrypt do automatycznej migracji zmian z wielu programistycznych baz danych do przemieszczania / produkcji. Zasadniczo wymaga kilku skryptów zmian i łączy je w jeden skrypt, opakowując każdy skrypt w IF whatever BEGIN ... ENDinstrukcję.

Jednak niektóre skrypty wymagają GOinstrukcji, aby na przykład parser SQL wiedział o nowej kolumnie po jej utworzeniu.

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Jednak kiedy zawinąłem to w IFblok:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Nie udaje się, ponieważ wysyłam BEGINbez dopasowania END. Jeśli jednak usunę GOto znowu narzeka na nieznaną kolumnę.

Czy istnieje sposób na utworzenie i zaktualizowanie tej samej kolumny w jednym IFbloku?

Miałem ten sam problem iw końcu udało mi się go rozwiązać za pomocą SET NOEXEC .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO to nie jest SQL - to po prostu separator wsadowy używany w niektórych narzędziach MS SQL.

Jeśli tego nie używasz, musisz upewnić się, że instrukcje są wykonywane osobno - w różnych partiach lub przy użyciu dynamicznego SQL dla populacji (dzięki @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Możesz spróbować podzielić sp_executesqlzawartość między każdą GOinstrukcją na oddzielny ciąg do wykonania, jak pokazano w poniższym przykładzie. Istnieje również zmienna @statementNo do śledzenia, która instrukcja jest wykonywana, aby ułatwić debugowanie, w którym wystąpił wyjątek. Numery wierszy będą podane względem początku odpowiedniego numeru instrukcji, który spowodował błąd.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Możesz również łatwo wykonywać instrukcje wielowierszowe, jak pokazano w powyższym przykładzie, po prostu zawijając je w pojedyncze cudzysłowy ( '). ''Podczas generowania skryptów nie zapomnij o zastąpieniu pojedynczych cudzysłowów zawartych w ciągu znaków za pomocą podwójnego apostrofu ( ).

Ostatecznie udało mi się go uruchomić, zastępując każdą instancję GOna własnej linii przez

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Jest to znacznie lepsze niż zawijanie każdej grupy instrukcji w łańcuch, ale nadal jest dalekie od ideału. Jeśli ktoś znajdzie lepsze rozwiązanie, opublikuj je, a ja je zaakceptuję.

Możesz ująć instrukcje w BEGIN i END zamiast GO pomiędzy

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Testowane w bazie danych Northwind)

Edycja: (prawdopodobnie przetestowane na SQL2012)

Możesz wypróbować to rozwiązanie:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Używałem tego RAISERRORw przeszłości

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Możesz dołączyć instrukcje a GOTOi LABEL, aby pominąć kod, pozostawiając w ten sposób GOsłowa kluczowe nietknięte.