Jak napisać skrypt, aby zainstalować mariadb?

Środowisko: centos7 + mariadb5.5.64.
Pokażę informacje o instalacji na ekranie, kiedy należy uruchomićmysql_secure_installation .

# mysql_secure_installation

NOTE: RUNNING ALL PARTS OF THIS SCRIPT IS RECOMMENDED FOR ALL MariaDB
      SERVERS IN PRODUCTION USE!  PLEASE READ EACH STEP CAREFULLY!

In order to log into MariaDB to secure it, we'll need the current
password for the root user.  If you've just installed MariaDB, and
you haven't set the root password yet, the password will be blank,
so you should just press enter here.

Enter current password for root (enter for none): 
OK, successfully used password, moving on...

Setting the root password ensures that nobody can log into the MariaDB
root user without the proper authorisation.

Set root password? [Y/n] y
New password: 
Re-enter new password: 
Password updated successfully!
Reloading privilege tables..
 ... Success!


By default, a MariaDB installation has an anonymous user, allowing anyone
to log into MariaDB without having to have a user account created for
them.  This is intended only for testing, and to make the installation
go a bit smoother.  You should remove them before moving into a
production environment.

Remove anonymous users? [Y/n] y
 ... Success!

Normally, root should only be allowed to connect from 'localhost'.  This
ensures that someone cannot guess at the root password from the network.

Disallow root login remotely? [Y/n] y
 ... Success!

By default, MariaDB comes with a database named 'test' that anyone can
access.  This is also intended only for testing, and should be removed
before moving into a production environment.

Remove test database and access to it? [Y/n] y
 - Dropping test database...
 ... Success!
 - Removing privileges on test database...
 ... Success!

Reloading the privilege tables will ensure that all changes made so far
will take effect immediately.

Reload privilege tables now? [Y/n] y
 ... Success!

Cleaning up...

All done!  If you've completed all of the above steps, your MariaDB
installation should now be secure.

Thanks for using MariaDB!

Piszę skrypt automatyzacji oczekujący na zainstalowanie mariadb.

  vim secure.exp
  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? [Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? [Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? [Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? [Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? [Y/n]" {send "y\r";exp_continue}
  }

Aby wykonać /usr/bin/expect secure.exp, napotkałem błąd:

spawn mysql_secure_installation
invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
          "Enter current password for root (enter for none): " {send "\r";exp_continue}
          "Set root password? [Y/n] " {send "y\r";exp..."
    (file "secure.exp" line 3)

Nie ma sensu pisać jak poniżej:

  set timeout 60
  spawn mysql_secure_installation
  expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_continue}
      "New password:" {send "123456\r";exp_continue}
      "Re-enter new password:" {send "123456\r";exp_continue}
      "Remove anonymous users? \\[Y/n]" {send "y\r";exp_continue}
      "Disallow root login remotely? \\[Y/n]" {send "y\r";exp_continue}
      "Remove test database and access to it? \\[Y/n]" {send "y\r";exp_continue}
      "Reload privilege tables now? \\[Y/n]" {send "y\r";exp_continue}
  }

Ten sam błąd:

invalid command name "Y/n"
    while executing
"Y/n"
    invoked from within
"expect {
      "Enter current password for root (enter for none): " {send "\r";exp_continue}
      "Set root password? \\[Y/n] " {send "y\r";exp_conti..."
    (file "secure.exp" line 3)

Jak naprawić mój skrypt exp?

Skrypty te czekają na opcjonalne wyjście ( timeout -1oznacza „brak limitu czasu”) i potrafią rozróżniać różne odpowiedzi, zgodnie z wymaganiami yum installi mysql_secure_installation. Za pomocą #!/bin/expect -fshebang skrypty można wykonywać, gdy są ustawione na chmod +x.

A) Na początek mariadb_yum.exp(wymaga sulub sudo):

#!/bin/expect -f
set timeout 30
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_yum.exp \[linux sudo password\]\n"
    exit 1
}
set USERNAME "[exec whoami]"
set PASSWORD [lindex $argv 0];

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/$USERNAME/mariadb_install.log"

spawn sudo yum -y install MariaDB-server
set yum_spawn_id $spawn_id

# On GCE it will never ask for a sudo password:
expect -ex "\[sudo\] password for $USERNAME: " {
   exp_send "$PASSWORD\r"
}

expect {
    # when the package was already installed
    -ex "Nothing to do" {
        send_user "package was already installed\n"
    }
    # when the package had been installed
    -ex "Complete!" {
        send_user "package had been installed\n"
    }
}

expect eof
close $yum_spawn_id
exit 0

B) A następnie mariadb_sec.exp(nie wymaga sudo):

#!/bin/expect -f
set timeout 1
if {[llength $argv] == 0} {
    send_user "Usage: mariadb_sec.exp \[mysql root password\]\n"
    exit 1
}
set PASSWORD [lindex $argv 0];

spawn mysql_secure_installation
set mysql_spawn_id $spawn_id

# optionally, redirect output to log file (silent install)
# log_user 0
# log_file -a "/home/[exec whoami]/mariadb_install.log"

# when there is no password set, this probably should be "\r"
expect -ex "Enter current password for root (enter for none): "
exp_send "$PASSWORD\r"

expect {
    # await an eventual error message
    -ex "ERROR 1045" {
        send_user "\nMariaDB > An invalid root password had been provided.\n"
        close $mysql_spawn_id
        exit 1
    }
    # when there is a root password set
    -ex "Change the root password? \[Y/n\] " {
        exp_send "n\r"
    }
    # when there is no root password set (could not test this branch).
    -ex "Set root password? \[Y/n\] " {
        exp_send "Y\r"
        expect -ex "New password: "
        exp_send "$PASSWORD\r"
        expect -ex "Re-enter new password: "
        exp_send "$PASSWORD\r"
    }
}
expect -ex "Remove anonymous users? \[Y/n\] "
exp_send "Y\r"
expect -ex "Disallow root login remotely? \[Y/n\] "
exp_send "Y\r"
expect -ex "Remove test database and access to it? \[Y/n\] "
exp_send "Y\r"
expect -ex "Reload privilege tables now? \[Y/n\] "
exp_send "Y\r"

expect eof
close $mysql_spawn_id
exit 0

W celu debugowania - lub w celu potwierdzenia odpowiedzi, można uruchomić na expectpoziomie dziennika strace 4. Jest to prawdopodobnie tak renomowane, jak źródło, jeśli chodzi o pisanie expectskryptów, ponieważ ładnie pokazuje, co się dzieje i, co najważniejsze, w jakiej kolejności rzeczy się dzieją:

expect -c "strace 4" ./mariadb_yum.exp [linux sudo password]
expect -c "strace 4" ./mariadb_sec.exp [mysql root password]

set exp_internal 1Można użyć instrukcji, aby uzyskać dane wyjściowe dla dopasowania wyrażenia regularnego.

Możliwym źródłem nieporozumień może być odradzanie procesów - ponieważ można spawnować kilka procesów na różnych hostach, np. sshlokalnie, a następnie yumi mysql_secure_installationzdalnie. Dodano $spawn_iddo skryptu; dolne closewywołanie może być zbędne, ponieważ jest już EOF(tylko w celu pokazania, jak spawni jak closeprzetwarzać):

Thanks for using MariaDB!
 1  close $mysql_spawn_id
 1  exit 0
 2  rename _close.pre_expect close

Wniosek: mariadb_sec.expskrypt można prawdopodobnie ulepszyć, np. gdy najpierw nie wysyłasz hasła i nie widzisz, co się dzieje - a następnie wysyłasz hasło ERROR 1045(jeśli hasło zostało już ustawione wcześniej). Można zapisać, aby założyć, że hasło należy ustawić dopiero po zainstalowaniu serwera (z wyjątkiem tego, że yum reinstalldaje ten sam wynik). Po prostu nie miałem pustego kontenera CentOS do przetestowania wszystkich przypadków. Chyba że działa wroot powłoce, przekazanie obu rodzajów haseł do jednego skryptu byłoby wymagane do zautomatyzowania tego od instalacji do późniejszej instalacji.

Prawdopodobnie warto zauważyć, że na GCE sudonie pytałby o hasło; istnieją niewielkie różnice w zależności od środowiska, ponieważ te obrazy kontenerów CentOS zachowują się inaczej. W takim przypadku (ponieważ nie ma suwykrycia lub wykrycia obrazu kontenera) mariadb_yum.expskrypt może utknąć na 30kilka sekund, a następnie kontynuować.

Najbardziej renomowanymi źródłami, jakie mogę zaoferować, są expectpodręcznik napisany przez Don Libes @ NIST i podręcznik TCL / TK dla expect, a także jego projekt SourceForge, zwany przypadkowo expect.

Nawiasy kwadratowe służą nie tylko do zastępowania poleceń, ale są również specjalne dla wzorców globu .

Możesz użyć -exactprzełącznika, unikając nawiasów kwadratowych w cudzysłowie:

spawn mysql_secure_installation
expect {
    ...
    -exact "Set root password? \[Y/n\] " {send "y\r";exp_continue}
    ...
}

Lub użyj nawiasów klamrowych zamiast cudzysłowów:

spawn mysql_secure_installation
expect {
    ...
    {Set root password? \[Y/n\] } {send "y\r";exp_continue}
    ...
}

Do Twojej wiadomości możesz wygenerować oczekiwany skrypt za pomocą autoexpect:

autoexpect ./mysql_secure_installation

Spowoduje to wygenerowanie skryptu expect wywołanego script.expw bieżącym katalogu roboczym.