Wskazówki i triki Vim i Ctags [zamknięte]

Właśnie zainstalowałem Ctagi (aby pomóc w rozwoju C ++) z moim Vimem (a raczej gVimem) i chciałbym znaleźć twoje ulubione polecenia, makra, skróty, wskazówki, które się z tym zgadzają ...

Podziel się swoim najlepszym arsenałem. Jakie inne dodatki Vima poleciłbyś dla C ++ w rozwoju Vima?

EDYCJA Jakiego innego dodatku używałbyś w połączeniu z Ctags?

EDIT2 Jakiej wersji gVim używasz z tagami? Czy to robi różnicę?

EDIT3 Jak zwiększyć swoje doświadczenie programistyczne zarówno dla dużych, jak i małych projektów?

Ctrl+ ]- przejdź do definicji
Ctrl+ T- przeskocz z definicji.
Ctrl+ W Ctrl+ ]- Otwórz definicję w układzie poziomym

Dodaj te linie w vimrc
map <C-\> :tab split<CR>:exec("tag ".expand("<cword>"))<CR>
map <A-]> :vsp <CR>:exec("tag ".expand("<cword>"))<CR>

Ctrl+ \- Otwórz definicję w nowej karcie
Alt+ ]- Otwórz definicję w podziale pionowym

Po wygenerowaniu tagów. Możesz użyć następujących klawiszy, aby oznaczyć i wyłączyć funkcje:

Ctrl+ Left MouseClick- Przejdź do definicji
Ctrl+ Right MouseClick- Przejdź z definicji

Jedna linia, która zawsze idzie w moim .vimrc:

set tags=./tags;/

Spowoduje to wyszukanie w bieżącym katalogu „znaczników” i przesunie drzewo w kierunku katalogu głównego aż do znalezienia jednego z nich. IOW, możesz być w dowolnym miejscu w drzewie źródłowym zamiast tylko jego katalogu głównego.

Inną przydatną wtyczką do programowania w języku C jest cscope Podobnie jak Ctags pozwala przeskakiwać do definicji, Cscope przeskakuje do wywołania funkcji .

Jeśli masz cscope w katalogu ~ / bin /, dodaj do .vimrc i użyj g ^], aby przejść do funkcji wywołującej (patrz: help cscope).

if has("cscope")
    set csprg=~/bin/cscope
    set csto=0
    set cst
    set nocsverb
    " add any database in current directory
    if filereadable("cscope.out")
        cs add cscope.out
        " else add database pointed to by environment
    elseif $CSCOPE_DB != ""
        cs add $CSCOPE_DB
    endif
endif

Prawie zapomniałem ... Podobnie jak ctags - musisz wygenerować (i okresowo aktualizować) bazę danych. Używam następującego skryptu

select_files > cscope.files
ctags -L cscope.files
ctags -e -L cscope.files
cscope -ub -i cscope.files

Gdzie „select_files” to kolejny skrypt, który wyodrębnia listę plików C i plików nagłówkowych z Makefile. W ten sposób indeksuję tylko pliki faktycznie używane przez projekt.

Możesz dodawać katalogi do wyszukiwania ctags. Na przykład mam indeks ctags zbudowany dla Qt4 i mam go w moim .vimrc:

set tags+=/usr/local/share/ctags/qt4

Wszystkie powyższe i ...

code_complete: parametr funkcji zakończony, fragmenty kodu i wiele innych.

• http://www.vim.org/scripts/script.php?script_id=1764

taglist.vim: przeglądarka kodów źródłowych (obsługuje C / C ++, java, perl, python, tcl, sql, php itp.)

• http://www.vim.org/scripts/script.php?script_id=273

Używam ALT-left i ALT-right, aby pop / push z / do stosu znaczników.

" Alt-right/left to navigate forward/backward in the tags stack
map <M-Left> <C-T>
map <M-Right> <C-]>

Jeśli używasz hjklruchu, możesz odwzorować <M-h>i <M-l>zamiast tego.

Kilka definicji o tej samej nazwie

<C-w>g<C-]>otwórz definicję w podziale, ale również zrób to, :tjumpco albo przechodzi do definicji, albo, jeśli istnieje kilka definicji, przedstawia listę definicji do wyboru.

Polecenie, którego najczęściej używam, to C-], które przeskakuje do definicji funkcji pod kursorem. Możesz go używać częściej, aby śledzić więcej połączeń. Po tym, Co przeniesie cię z powrotem o jeden poziom, Ci znów idzie głębiej.

Uważam, że wtyczka taglist jest niezbędna. Zawiera listę wszystkich znaczników, o których wie (pliki, które otworzyłeś) w osobnym oknie i bardzo ułatwia nawigację po większych plikach.

Używam go głównie do programowania w języku Python, ale może być lepszy tylko w C / C ++.

Zamknąłem manipulację tagami w eksperymentalnej wtyczce mojej .

Jeśli chodzi o rozwój C ++ w vimie, już tam odpowiedziałem : używam własnego pakietu i kilku innych wtyczek.

Od dwóch lat dostosowuję wtyczki vim, aby obsługiwać wystarczająco duży projekt c ++. Możesz na nie spojrzeć.

Używają ctags i cscsope.

http://www.vim.org/scripts/script.php?script_id=1638
http://www.vim.org/scripts/script.php?script_id=2507

W moim pliku .gvimrc umieszczam następujące polecenie, które wyszukuje drzewo z dowolnego miejsca w poszukiwaniu pliku znaczników po uruchomieniu gvim:

function SetTags()
    let curdir = getcwd()

    while !filereadable("tags") && getcwd() != "/"
        cd ..
    endwhile

    if filereadable("tags")
        execute "set tags=" . getcwd() . "/tags"
    endif

    execute "cd " . curdir
endfunction

call SetTags()

Następnie okresowo generuję ponownie plik znaczników u góry drzewa źródłowego za pomocą skryptu, który wygląda następująco:

#!/bin/bash

find . -regex ".*\.\(c\|h\|hpp\|cc\|cpp\)" -print | ctags --totals --recurse --extra="+qf" --fields="+i" -L -

Używam vima w macos, a oryginalne ctagi nie działają dobrze, więc pobieram najnowsze i konfiguruję make make install. Instaluję ctgas w / usr / local / bin / ctags (aby zachować oryginalny)

"taglist
let Tlist_Ctags_Cmd = "/usr/local/bin/ctags"
let Tlist_WinWidth = 50
map <leader>ta :TlistToggle<cr>
map <leader>bta :!/usr/local/bin/ctags -R .<CR>
set tags=tags;/
map <M-j> <C-]>
map <M-k> <C-T>

Dostosowałem funkcję wyszukiwania SetTags () powyżej (która powinna zostać zastąpiona odpowiednikiem set tags+=./tags;/), aby działała dla cscope. Wydaje się działać!

"cscope file-searching alternative
function SetCscope()
    let curdir = getcwd()

    while !filereadable("cscope.out") && getcwd() != "/"
            cd ..
                endwhile

    if filereadable("cscope.out")
            execute "cs add " . getcwd() . "/cscope.out"
                endif

    execute "cd " . curdir
    endfunction

call SetCscope()

Kolejna iteracja powyższej funkcji SetCscope (). To ustawia ścieżkę wstępną cscope, aby uzyskać dopasowania bez znajdowania się w katalogu, w którym „cscope.out” to:

function s:FindFile(file)
    let curdir = getcwd()
    let found = curdir
    while !filereadable(a:file) && found != "/"
        cd ..
        let found = getcwd()
    endwhile
    execute "cd " . curdir
    return found
endfunction

if has('cscope')    
    let $CSCOPE_DIR=s:FindFile("cscope.out")
    let $CSCOPE_DB=$CSCOPE_DIR."/cscope.out"
    if filereadable($CSCOPE_DB)
        cscope add $CSCOPE_DB $CSCOPE_DIR
    endif

    command -nargs=0 Cscope !cscope -ub -R &
endif