Jak sprawdzić, czy plik wykonywalny istnieje w% PATH% z pliku wsadowego systemu Windows?

Szukam prostego sposobu na sprawdzenie, czy plik wykonywalny istnieje w zmiennej środowiskowej PATH z pliku wsadowego systemu Windows.

Korzystanie z narzędzi zewnętrznych, które nie są dostarczane przez system operacyjny, jest niedozwolone. Minimalna wymagana wersja systemu Windows to Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Jeśli potrzebujesz tego dla różnych rozszerzeń, po prostu powtórz PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Możliwe, że whereistnieje już w starszych wersjach systemu Windows, ale nie mam dostępu do jednej, więc nie mogę powiedzieć. Na moim komputerze działa również:

where myExecutable

i zwraca z niezerowym kodem zakończenia, jeśli nie można go znaleźć. Jednak w przypadku wsadu prawdopodobnie chcesz również przekierować dane wyjściowe do NUL.

Pamiętać

Parsowanie w .batplikach batch ( ) iw wierszu poleceń różni się (ponieważ pliki wsadowe mają %0- %9), więc musisz podwoić to %. W linii poleceń nie jest to konieczne, więc dla zmiennych są po prostu %X.

System Windows Vista i nowsze wersje są dostarczane z programem o nazwie, where.exektóry wyszukuje programy w ścieżce. Działa to tak:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Do użycia w pliku wsadowym możesz użyć /qprzełącznika, który po prostu ustawia ERRORLEVELi nie generuje żadnych wyników.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Lub prostą (ale mniej czytelną) skróconą wersję, która drukuje wiadomość i zamyka aplikację:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Oto proste rozwiązanie, które próbuje uruchomić aplikację i obsługuje później każdy błąd .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Kod błędu 9009 zwykle oznacza, że ​​nie znaleziono pliku.

Jedynym minusem jest to, że file.exejest faktycznie wykonywany, jeśli zostanie znaleziony (co w niektórych przypadkach nie jest pożądane).

Można to osiągnąć poprzez podstawianie parametrów.

%~$PATH:1

Zwraca pełną ścieżkę do nazwy pliku wykonywalnego w% 1, w przeciwnym razie pusty ciąg.

Nie działa to ze zmiennymi zdefiniowanymi przez użytkownika. Więc jeśli nazwa pliku wykonywalnego nie jest parametrem twojego skryptu, potrzebujesz podprogramu. Na przykład:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Zobacz http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Czasami działa to proste rozwiązanie, w którym sprawdzasz, czy dane wyjściowe są zgodne z oczekiwaniami. Pierwsza linia uruchamia polecenie i przechwytuje ostatni wiersz standardowego wyjścia.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Jeśli szukasz czegoś takiego jak ja w folderze startowym, powinieneś przejść do folderu. Na przykład wyszukuję exe w folderze startowym i używam tego kodu jak

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Użyj polecenia: powershell Test-Path „exe, którego szukasz”

Zwróci True, jeśli jest obecny, w przeciwnym razie False.

Dla tych, którzy szukają opcji PowerShell. Możesz użyć polecenia Get-Commandcmdlet przekazującego dwa elementy. Najpierw podaj aktualną lokalizację katalogu z .\prefiksem, a następnie podaj tylko nazwę exe.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

To zwróci prawdę, jeśli zostanie znalezione lokalnie lub w ścieżkach całego systemu.