Vim: Tworzenie katalogów nadrzędnych przy zapisywaniu

Jeśli wywołam, vim foo/bar/somefileale foo/barjeszcze nie istnieje, Vim odmówi zapisania.

Wiem, że mógłbym przełączyć się na powłokę lub zrobić :!mkdir foo/bar z Vima, ale jestem leniwy :) Czy jest sposób, aby Vim robił to automatycznie, gdy zapisuje bufor?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Zwróć uwagę na warunki: expand("<afile>")!~#'^\w\+:/'uniemożliwi vimowi tworzenie katalogów dla plików takich jak ftp://*i !isdirectoryzapobiegnie kosztownym wywołaniom mkdir.

Aktualizacja : nieznacznie lepsze rozwiązanie, które również sprawdza niepusty typ buforu i używa mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

W oparciu o sugestie do mojego pytania, oto co otrzymałem:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

To definiuje :Wpolecenie. Idealnie, chciałbym mieć wszystko :w!, :wq, :wq!, :walletc działają tak samo, ale nie jestem pewien, czy jest to możliwe bez zasadzie reimplementing je wszystkie z funkcji niestandardowych.

Dodałem to do mojego ~ / .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Jeśli muszę utworzyć katalog, w :mk.którym się znajduję, wpisuję go i zastępuje go ciągiem „! Mkdir -p / ścieżka / do / mój / plik /” i umożliwia mi przejrzenie polecenia przed jego wywołaniem.

I made :saveas!utworzenia katalogu jeśli brakuje: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Ten kod poprosi Cię o utworzenie katalogu za pomocą :wlub po prostu zrób to za pomocą :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Myślę, że udało mi się to zrobić w trzech wierszach, łącząc to, co inni mówią o tej odpowiedzi.

Wydaje się, że to działa:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Próbuje utworzyć folder automatycznie podczas zapisywania buforu. Jeśli wydarzy się coś złego (np. Problemy z uprawnieniami), po prostu się zamknie i pozwoli na niepowodzenie zapisu pliku.

Jeśli ktoś zauważy oczywiste wady, napisz komentarz. Nie jestem biegły w skryptach vimscript.

EDYCJA: Uwagi dzięki ZyX

• To nie zadziała, jeśli twoje foldery mają na sobie spacje (najwyraźniej nie są one poprawnie wyłączone lub coś takiego)
• Lub jeśli robisz pseudo pliki.
• Lub jeśli pozyskujesz swój vimrc.
• Ale synu, to jest krótkie.