Jak mogę przeprowadzić odwrotne wyszukiwanie ciągów znaków w programie Excel bez używania VBA?

Mam arkusz kalkulacyjny Excel zawierający listę ciągów. Każdy ciąg składa się z kilku słów, ale liczba słów w każdym z nich jest inna.

Korzystając z wbudowanych funkcji programu Excel (bez VBA), czy istnieje sposób na wyodrębnienie ostatniego słowa w każdym ciągu?

Przykłady:

  Czy jesteś sklasyfikowany jako człowiek? -> człowiek?
Negatywne, jestem popsicle z mięsa -> popsicle
                  Aziz! Lekki! -> Światło!

Ten jest przetestowany i działa (na podstawie oryginalnego postu Brada):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Jeśli oryginalne ciągi znaków mogą zawierać pionową kreskę „|” znak, a następnie zamień oba w powyższym na inny znak, który nie pojawi się w twoim źródle. (Podejrzewam, że oryginał Brada został uszkodzony, ponieważ z tłumaczenia usunięto niedrukowalny znak).

Bonus: Jak to działa (od prawej do lewej):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Liczba spacji w oryginalnym ciągu
SUBSTITUTE(A1," ","|", ... )- Zastępuje tylko ostatnią spację za |
FIND("|", ... )- Znajduje bezwzględną pozycję tego zastąpionego |(to była ostatnia spacja)
Right(A1,LEN(A1) - ... ))- Zwraca wszystkie znaki po tym|

EDYCJA: aby uwzględnić przypadek, w którym tekst źródłowy nie zawiera spacji, dodaj na początku wzoru:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

tworząc teraz całą formułę:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Lub możesz użyć =IF(COUNTIF(A1,"* *")składni drugiej wersji.

Jeśli oryginalny ciąg może zawierać spację na ostatniej pozycji, dodaj funkcję przycinającą, licząc wszystkie spacje: Wykonując funkcję następującą:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Oto technika, której użyłem z wielkim sukcesem:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Aby uzyskać pierwsze słowo w ciągu, po prostu zmień z RIGHT na LEFT

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Zastąp również A1 komórką zawierającą tekst.

Bardziej solidna wersja odpowiedzi Jerry'ego:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Działa to niezależnie od długości łańcucha, spacji początkowych lub końcowych, czy czegokolwiek innego i nadal jest dość krótkie i proste.

Znalazłem to w Google, przetestowałem w programie Excel 2003 i działa dla mnie:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[edytuj] Nie mam wystarczającej liczby powtórzeń, aby komentować, więc wydaje się, że to najlepsze miejsce ... Odpowiedź BradCa również nie działa ze spacjami lub pustymi komórkami ...
[2. edycja] właściwie, to nie działa dla pojedyncze słowa ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Jest to bardzo solidne - działa w przypadku zdań bez spacji, spacji wiodących / końcowych, wielu spacji, wielu spacji wiodących / końcowych ... i użyłem znaku (7) jako separatora zamiast pionowej kreski "|" na wypadek, gdyby był to pożądany element tekstowy.

Jest to bardzo czyste i kompaktowe i działa dobrze.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Nie ma pułapki na błędy bez spacji lub jednego słowa, ale łatwo to dodać.

Edycja:
obsługuje końcowe spacje, pojedyncze słowo i scenariusze pustych komórek. Nie znalazłem sposobu, żeby to złamać.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Aby dodać do odpowiedzi Jerry'ego i Joe, jeśli chcesz znaleźć tekst PRZED ostatnim słowem, którego możesz użyć:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Z „Mój mały kot” w A1 wynikałoby „Mój mały” (gdzie Joe i Jerry's daliby „kot”

W ten sam sposób, w jaki Jerry i Joe izolują ostatnie słowo, to po prostu pobiera wszystko na lewo od tego (a następnie przycina je z powrotem)

Wyobraź sobie, że struna może zostać odwrócona. Wtedy jest to naprawdę łatwe. Zamiast pracować na łańcuchu:

"My little cat" (1)

pracujesz z

"tac elttil yM" (2)

Z =LEFT(A1;FIND(" ";A1)-1)w A2 otrzymujesz "My"z (1) i "tac"z (2), co jest odwrócone "cat", ostatnie słowo w (1).

Istnieje kilka VBA do odwrócenia ciągu. Wolę publiczną funkcję VBA ReverseString.

Zainstaluj powyższe zgodnie z opisem. Następnie z ciągiem znaków w A1, np. "My little cat"I tą funkcją w A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

zobaczysz "cat"w A2.

Powyższa metoda zakłada, że ​​słowa są oddzielone spacjami. IFKlauzula komórek zawierających pojedyncze słowa = NO półwyrobów w komórce. Uwaga: TRIMi CLEANoryginalny łańcuch są przydatne również. W zasadzie odwraca cały ciąg z A1 i po prostu znajduje pierwszy odstęp w odwróconym ciągu, który znajduje się obok ostatniego (odwróconego) słowa (tj "tac ".). LEFTwybiera to słowo, a inny ciąg znaków odwraca oryginalną kolejność słowa ( " cat"). Na -1końcu FINDinstrukcji usuwa puste miejsce.

Chodzi o to, że łatwo jest wyodrębnić pierwsze (!) Słowo w łańcuchu, używając LEFTi FINDwpisując pierwszy odstęp. Jednak w przypadku ostatniego (!) Słowa RIGHTfunkcja jest złym wyborem, gdy próbujesz to zrobić, ponieważ niestety FIND nie ma flagi dla kierunku, w którym chcesz analizować łańcuch.

Dlatego cały ciąg jest po prostu odwrócony. LEFTi FINDdziała normalnie, ale wyodrębniony ciąg jest odwrócony. Ale to nic wielkiego, gdy wiesz, jak odwrócić ciąg. Pierwsza ReverseStringinstrukcja w formule spełnia to zadanie.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Skopiuj do kolumny, wybierz tę kolumnę i HOME> Edycja> Znajdź i wybierz, zamień:

Replace All.

Po gwiazdce jest spacja.

Przetłumaczyłem na PT-BR, bo tego też potrzebowałem.

(Zwróć uwagę, że zmieniłem spację na, \ponieważ potrzebowałem tylko nazwy pliku z ciągami ścieżek).

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Innym sposobem osiągnięcia tego jest poniżej

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Miałem też takie zadanie i kiedy skończyłem, używając powyższej metody, pojawiła się nowa metoda: Dlaczego nie zrobisz tego:

1. Odwróć ciąg („ciąg jeden” staje się „eno gnirts”).
2. Użyj starego dobrego narzędzia Find (który jest zakodowany na stałe od lewej do prawej).
3. Ponownie przekształć go w czytelny ciąg.

Jak to brzmi?