Nazwa tabeli jako zmienna

Próbuję wykonać to zapytanie:

declare @tablename varchar(50)
set @tablename = 'test'
select * from @tablename

Powoduje to następujący błąd:

Msg 1087, poziom 16, stan 1, wiersz 5

Należy zadeklarować zmienną tabeli „@tablename”.

Jaki jest właściwy sposób dynamicznego wypełniania nazwy tabeli?

W przypadku zapytań statycznych, takich jak w pytaniu, nazwy tabel i nazwy kolumn muszą być statyczne.

W przypadku zapytań dynamicznych należy dynamicznie generować pełny kod SQL i wykonywać go przy użyciu sp_executesql.

Oto przykład skryptu używanego do porównywania danych między tymi samymi tabelami w różnych bazach danych:

zapytanie statyczne:

SELECT * FROM [DB_ONE].[dbo].[ACTY]
EXCEPT
SELECT * FROM [DB_TWO].[dbo].[ACTY]

ponieważ chcę łatwo zmienić nazwę tablei schemautworzyłem to dynamiczne zapytanie:

declare @schema varchar(50)
declare @table varchar(50)
declare @query nvarchar(500)

set @schema = 'dbo'
set @table = 'ACTY'

set @query = 'SELECT * FROM [DB_ONE].['+ @schema +'].[' + @table + '] EXCEPT SELECT * FROM [DB_TWO].['+ @schema +'].[' + @table + ']'

EXEC sp_executesql @query

Ponieważ zapytania dynamiczne mają wiele szczegółów, które należy wziąć pod uwagę i są trudne do opanowania, radzę przeczytać: Klątwa i błogosławieństwa dynamicznego SQL

Zmień swoje ostatnie oświadczenie na następujące:

EXEC('SELECT * FROM ' + @tablename)

Oto jak robię swoje w procedurze składowanej. Pierwszy blok zadeklaruje zmienną i ustawi nazwę tabeli na podstawie nazwy bieżącego roku i miesiąca, w tym przypadku TEST_2012OCTOBER. Następnie sprawdzam, czy istnieje już w bazie danych i usuwam, jeśli tak. Następnie następny blok użyje instrukcji SELECT INTO do utworzenia tabeli i wypełnienia jej rekordami z innej tabeli z parametrami.

--DECLARE TABLE NAME VARIABLE DYNAMICALLY
DECLARE @table_name varchar(max)
SET @table_name = 
    (SELECT 'TEST_'
            + DATENAME(YEAR,GETDATE())
            + UPPER(DATENAME(MONTH,GETDATE())) )

--DROP THE TABLE IF IT ALREADY EXISTS
IF EXISTS(SELECT name 
          FROM sysobjects 
          WHERE name = @table_name AND xtype = 'U')

BEGIN
    EXEC('drop table ' +  @table_name)
END

--CREATES TABLE FROM DYNAMIC VARIABLE AND INSERTS ROWS FROM ANOTHER TABLE
EXEC('SELECT * INTO ' + @table_name + ' FROM dbo.MASTER WHERE STATUS_CD = ''A''')

Trochę za późno na odpowiedź, ale powinien pomóc komuś innemu:

CREATE PROCEDURE [dbo].[GetByName]
    @TableName NVARCHAR(100)
    AS
BEGIN
    -- SET NOCOUNT ON added to prevent extra result sets from
    -- interfering with SELECT statements.
    SET NOCOUNT ON;
    DECLARE @sSQL nvarchar(500);

    SELECT @sSQL = N'SELECT * FROM' + QUOTENAME(@TableName);

    EXEC sp_executesql @sSQL



END

Nie możesz użyć nazwy tabeli dla zmiennej, zamiast tego musisz to zrobić:

DECLARE @sqlCommand varchar(1000)
SET @sqlCommand = 'SELECT * from yourtable'
EXEC (@sqlCommand)

Będziesz musiał dynamicznie generować sql:

declare @tablename varchar(50) 

set @tablename = 'test' 

declare @sql varchar(500)

set @sql = 'select * from ' + @tablename 

exec (@sql)

Służy sp_executesqldo wykonywania dowolnego kodu SQL, np

DECLARE @tbl    sysname,
        @sql    nvarchar(4000),
        @params nvarchar(4000),
        @count  int

DECLARE tblcur CURSOR STATIC LOCAL FOR
   SELECT object_name(id) FROM syscolumns WHERE name = 'LastUpdated'
   ORDER  BY 1
OPEN tblcur

WHILE 1 = 1
BEGIN
   FETCH tblcur INTO @tbl
   IF @@fetch_status <> 0
      BREAK

   SELECT @sql =
   N' SELECT @cnt = COUNT(*) FROM dbo.' + quotename(@tbl) +
   N' WHERE LastUpdated BETWEEN @fromdate AND ' +
   N'                           coalesce(@todate, ''99991231'')'
   SELECT @params = N'@fromdate datetime, ' +
                    N'@todate   datetime = NULL, ' +
                    N'@cnt      int      OUTPUT'
   EXEC sp_executesql @sql, @params, '20060101', @cnt = @count OUTPUT

   PRINT @tbl + ': ' + convert(varchar(10), @count) + ' modified rows.'
END

DEALLOCATE tblcur

Możesz również użyć tego ...

DECLARE @SeqID varchar(150);
DECLARE @TableName varchar(150);  
SET @TableName = (Select TableName from Table);
SET @SeqID = 'SELECT NEXT VALUE FOR '+ @TableName + '_Data'
exec (@SeqID)

Declare  @tablename varchar(50) 
set @tablename = 'Your table Name' 
EXEC('select * from ' + @tablename)

musisz użyć dynamicznego SQL Servera SQL

DECLARE @table     NVARCHAR(128),
        @sql       NVARCHAR(MAX);

SET @table = N'tableName';

SET @sql = N'SELECT * FROM ' + @table;

Użyj EXEC do wykonania dowolnego kodu SQL

EXEC (@sql)

Użyj EXEC sp_executesql, aby wykonać dowolny kod SQL

EXEC sp_executesql @sql;

Użyj EXECUTE sp_executesql, aby wykonać dowolny kod SQL

EXECUTE sp_executesql @sql

Declare @fs_e int, @C_Tables CURSOR, @Table varchar(50)

SET @C_Tables = CURSOR FOR
        select name from sysobjects where OBJECTPROPERTY(id, N'IsUserTable') = 1 AND name like 'TR_%'
OPEN @C_Tables
FETCH @C_Tables INTO @Table
    SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'

WHILE ( @fs_e <> -1)
    BEGIN
        exec('Select * from '+ @Table)
        FETCH @C_Tables INTO @Table
        SELECT @fs_e = sdec.fetch_Status FROM sys.dm_exec_cursors(0) as sdec where sdec.name = '@C_Tables'
    END